git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   use Application
   7
   8   import Cachex.Spec
   9
  10   alias Pleroma.Config
  11
  12   require Logger
  13
  14   @name Mix.Project.config()[:name]
  15   @version Mix.Project.config()[:version]
  16   @repository Mix.Project.config()[:source_url]
  17   @env Mix.env()
  18
  19   def name, do: @name
  20   def version, do: @version
  21   def named_version, do: @name <> " " <> @version
  22   def repository, do: @repository
  23
  24   def user_agent do
  25     case Config.get([:http, :user_agent], :default) do
  26       :default ->
  27         info = "#{Pleroma.Web.base_url()} <#{Config.get([:instance, :email], "")}>"
  28         named_version() <> "; " <> info
  29
  30       custom ->
  31         custom
  32     end
  33   end
  34
  35   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  36   # for more information on OTP Applications
  37   def start(_type, _args) do
  38     # Scrubbers are compiled at runtime and therefore will cause a conflict
  39     # every time the application is restarted, so we disable module
  40     # conflicts at runtime
  41     Code.compiler_options(ignore_module_conflict: true)
  42     Config.Holder.save_default()
  43     Pleroma.HTML.compile_scrubbers()
  44     Config.DeprecationWarnings.warn()
  45     Pleroma.Plugs.HTTPSecurityPlug.warn_if_disabled()
  46     Pleroma.ApplicationRequirements.verify!()
  47     setup_instrumenters()
  48     load_custom_modules()
  49     Pleroma.Docs.JSON.compile()
  50
  51     adapter = Application.get_env(:tesla, :adapter)
  52
  53     if adapter == Tesla.Adapter.Gun do
  54       if version = Pleroma.OTPVersion.version() do
  55         [major, minor] =
  56           version
  57           |> String.split(".")
  58           |> Enum.map(&String.to_integer/1)
  59           |> Enum.take(2)
  60
  61         if (major == 22 and minor < 2) or major < 22 do
  62           raise "
  63             !!!OTP VERSION WARNING!!!
  64             You are using gun adapter with OTP version #{version}, which doesn't support correct handling of unordered certificates chains. Please update your Erlang/OTP to at least 22.2.
  65             "
  66         end
  67       else
  68         raise "
  69           !!!OTP VERSION WARNING!!!
  70           To support correct handling of unordered certificates chains - OTP version must be > 22.2.
  71           "
  72       end
  73     end
  74
  75     # Define workers and child supervisors to be supervised
  76     children =
  77       [
  78         Pleroma.Repo,
  79         Config.TransferTask,
  80         Pleroma.Emoji,
  81         Pleroma.Plugs.RateLimiter.Supervisor
  82       ] ++
  83         cachex_children() ++
  84         http_children(adapter, @env) ++
  85         [
  86           Pleroma.Stats,
  87           Pleroma.JobQueueMonitor,
  88           {Oban, Config.get(Oban)}
  89         ] ++
  90         task_children(@env) ++
  91         streamer_child(@env) ++
  92         chat_child(@env, chat_enabled?()) ++
  93         [
  94           Pleroma.Web.Endpoint,
  95           Pleroma.Gopher.Server
  96         ]
  97
  98     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  99     # for other strategies and supported options
 100     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
 101     Supervisor.start_link(children, opts)
 102   end
 103
 104   def load_custom_modules do
 105     dir = Config.get([:modules, :runtime_dir])
 106
 107     if dir && File.exists?(dir) do
 108       dir
 109       |> Pleroma.Utils.compile_dir()
 110       |> case do
 111         {:error, _errors, _warnings} ->
 112           raise "Invalid custom modules"
 113
 114         {:ok, modules, _warnings} ->
 115           if @env != :test do
 116             Enum.each(modules, fn mod ->
 117               Logger.info("Custom module loaded: #{inspect(mod)}")
 118             end)
 119           end
 120
 121           :ok
 122       end
 123     end
 124   end
 125
 126   defp setup_instrumenters do
 127     require Prometheus.Registry
 128
 129     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
 130       :ok =
 131         :telemetry.attach(
 132           "prometheus-ecto",
 133           [:pleroma, :repo, :query],
 134           &Pleroma.Repo.Instrumenter.handle_event/4,
 135           %{}
 136         )
 137
 138       Pleroma.Repo.Instrumenter.setup()
 139     end
 140
 141     Pleroma.Web.Endpoint.MetricsExporter.setup()
 142     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
 143     Pleroma.Web.Endpoint.Instrumenter.setup()
 144   end
 145
 146   defp cachex_children do
 147     [
 148       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 149       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 150       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 151       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 152       build_cachex("scrubber", limit: 2500),
 153       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 154       build_cachex("web_resp", limit: 2500),
 155       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 156       build_cachex("failed_proxy_url", limit: 2500),
 157       build_cachex("banned_urls", default_ttl: :timer.hours(24 * 30), limit: 5_000)
 158     ]
 159   end
 160
 161   defp emoji_packs_expiration,
 162     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 163
 164   defp idempotency_expiration,
 165     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 166
 167   defp seconds_valid_interval,
 168     do: :timer.seconds(Config.get!([Pleroma.Captcha, :seconds_valid]))
 169
 170   @spec build_cachex(String.t(), keyword()) :: map()
 171   def build_cachex(type, opts),
 172     do: %{
 173       id: String.to_atom("cachex_" <> type),
 174       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 175       type: :worker
 176     }
 177
 178   defp chat_enabled?, do: Config.get([:chat, :enabled])
 179
 180   defp streamer_child(env) when env in [:test, :benchmark], do: []
 181
 182   defp streamer_child(_) do
 183     [
 184       {Registry,
 185        [
 186          name: Pleroma.Web.Streamer.registry(),
 187          keys: :duplicate,
 188          partitions: System.schedulers_online()
 189        ]}
 190     ]
 191   end
 192
 193   defp chat_child(_env, true) do
 194     [Pleroma.Web.ChatChannel.ChatChannelState]
 195   end
 196
 197   defp chat_child(_, _), do: []
 198
 199   defp task_children(:test) do
 200     [
 201       %{
 202         id: :web_push_init,
 203         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 204         restart: :temporary
 205       }
 206     ]
 207   end
 208
 209   defp task_children(_) do
 210     [
 211       %{
 212         id: :web_push_init,
 213         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 214         restart: :temporary
 215       },
 216       %{
 217         id: :internal_fetch_init,
 218         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 219         restart: :temporary
 220       }
 221     ]
 222   end
 223
 224   # start hackney and gun pools in tests
 225   defp http_children(_, :test) do
 226     hackney_options = Config.get([:hackney_pools, :federation])
 227     hackney_pool = :hackney_pool.child_spec(:federation, hackney_options)
 228     [hackney_pool, Pleroma.Pool.Supervisor]
 229   end
 230
 231   defp http_children(Tesla.Adapter.Hackney, _) do
 232     pools = [:federation, :media]
 233
 234     pools =
 235       if Config.get([Pleroma.Upload, :proxy_remote]) do
 236         [:upload | pools]
 237       else
 238         pools
 239       end
 240
 241     for pool <- pools do
 242       options = Config.get([:hackney_pools, pool])
 243       :hackney_pool.child_spec(pool, options)
 244     end
 245   end
 246
 247   defp http_children(Tesla.Adapter.Gun, _), do: [Pleroma.Pool.Supervisor]
 248
 249   defp http_children(_, _), do: []
 250 end