git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   use Application
   7
   8   import Cachex.Spec
   9
  10   alias Pleroma.Config
  11
  12   require Logger
  13
  14   @name Mix.Project.config()[:name]
  15   @version Mix.Project.config()[:version]
  16   @repository Mix.Project.config()[:source_url]
  17   @mix_env Mix.env()
  18
  19   def name, do: @name
  20   def version, do: @version
  21   def named_version, do: @name <> " " <> @version
  22   def repository, do: @repository
  23
  24   def user_agent do
  25     if Process.whereis(Pleroma.Web.Endpoint) do
  26       case Config.get([:http, :user_agent], :default) do
  27         :default ->
  28           info = "#{Pleroma.Web.Endpoint.url()} <#{Config.get([:instance, :email], "")}>"
  29           named_version() <> "; " <> info
  30
  31         custom ->
  32           custom
  33       end
  34     else
  35       # fallback, if endpoint is not started yet
  36       "Pleroma Data Loader"
  37     end
  38   end
  39
  40   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  41   # for more information on OTP Applications
  42   def start(_type, _args) do
  43     # Scrubbers are compiled at runtime and therefore will cause a conflict
  44     # every time the application is restarted, so we disable module
  45     # conflicts at runtime
  46     Code.compiler_options(ignore_module_conflict: true)
  47     # Disable warnings_as_errors at runtime, it breaks Phoenix live reload
  48     # due to protocol consolidation warnings
  49     Code.compiler_options(warnings_as_errors: false)
  50     Config.Holder.save_default()
  51     Pleroma.HTML.compile_scrubbers()
  52     Pleroma.Config.Oban.warn()
  53     Config.DeprecationWarnings.warn()
  54     Pleroma.Web.Plugs.HTTPSecurityPlug.warn_if_disabled()
  55     Pleroma.ApplicationRequirements.verify!()
  56     load_custom_modules()
  57     Pleroma.Docs.JSON.compile()
  58     limiters_setup()
  59
  60     # Define workers and child supervisors to be supervised
  61     children =
  62       [
  63         Pleroma.Repo,
  64         Config.TransferTask,
  65         Pleroma.Emoji,
  66         Pleroma.Web.Plugs.RateLimiter.Supervisor,
  67         {Task.Supervisor, name: Pleroma.TaskSupervisor}
  68       ] ++
  69         cachex_children() ++
  70         http_children() ++
  71         [
  72           Pleroma.Stats,
  73           Pleroma.JobQueueMonitor,
  74           {Majic.Pool, [name: Pleroma.MajicPool, pool_size: Config.get([:majic_pool, :size], 2)]},
  75           {Oban, Config.get(Oban)},
  76           Pleroma.Web.Endpoint
  77         ] ++
  78         elasticsearch_children() ++
  79         task_children(@mix_env) ++
  80         dont_run_in_test(@mix_env)
  81
  82     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  83     # for other strategies and supported options
  84     # If we have a lot of caches, default max_restarts can cause test
  85     # resets to fail.
  86     # Go for the default 3 unless we're in test
  87     max_restarts =
  88       if @mix_env == :test do
  89         100
  90       else
  91         3
  92       end
  93
  94     opts = [strategy: :one_for_one, name: Pleroma.Supervisor, max_restarts: max_restarts]
  95
  96     with {:ok, data} <- Supervisor.start_link(children, opts) do
  97       set_postgres_server_version()
  98       {:ok, data}
  99     else
 100       e ->
 101         Logger.error("Failed to start!")
 102         Logger.error("#{inspect(e)}")
 103         e
 104     end
 105   end
 106
 107   defp set_postgres_server_version do
 108     version =
 109       with %{rows: [[version]]} <- Ecto.Adapters.SQL.query!(Pleroma.Repo, "show server_version"),
 110            {num, _} <- Float.parse(version) do
 111         num
 112       else
 113         e ->
 114           Logger.warn(
 115             "Could not get the postgres version: #{inspect(e)}.\nSetting the default value of 9.6"
 116           )
 117
 118           9.6
 119       end
 120
 121     :persistent_term.put({Pleroma.Repo, :postgres_version}, version)
 122   end
 123
 124   def load_custom_modules do
 125     dir = Config.get([:modules, :runtime_dir])
 126
 127     if dir && File.exists?(dir) do
 128       dir
 129       |> Pleroma.Utils.compile_dir()
 130       |> case do
 131         {:error, _errors, _warnings} ->
 132           raise "Invalid custom modules"
 133
 134         {:ok, modules, _warnings} ->
 135           if @mix_env != :test do
 136             Enum.each(modules, fn mod ->
 137               Logger.info("Custom module loaded: #{inspect(mod)}")
 138             end)
 139           end
 140
 141           :ok
 142       end
 143     end
 144   end
 145
 146   defp cachex_children do
 147     [
 148       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 149       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 150       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 151       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 152       build_cachex("scrubber", limit: 2500),
 153       build_cachex("scrubber_management", limit: 2500),
 154       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 155       build_cachex("web_resp", limit: 2500),
 156       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 157       build_cachex("failed_proxy_url", limit: 2500),
 158       build_cachex("banned_urls", default_ttl: :timer.hours(24 * 30), limit: 5_000),
 159       build_cachex("translations", default_ttl: :timer.hours(24 * 30), limit: 2500),
 160       build_cachex("instances", default_ttl: :timer.hours(24), ttl_interval: 1000, limit: 2500)
 161     ]
 162   end
 163
 164   defp emoji_packs_expiration,
 165     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 166
 167   defp idempotency_expiration,
 168     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 169
 170   defp seconds_valid_interval,
 171     do: :timer.seconds(Config.get!([Pleroma.Captcha, :seconds_valid]))
 172
 173   @spec build_cachex(String.t(), keyword()) :: map()
 174   def build_cachex(type, opts),
 175     do: %{
 176       id: String.to_atom("cachex_" <> type),
 177       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 178       type: :worker
 179     }
 180
 181   defp dont_run_in_test(env) when env in [:test, :benchmark], do: []
 182
 183   defp dont_run_in_test(_) do
 184     [
 185       {Registry,
 186        [
 187          name: Pleroma.Web.Streamer.registry(),
 188          keys: :duplicate,
 189          partitions: System.schedulers_online()
 190        ]}
 191     ] ++ background_migrators()
 192   end
 193
 194   defp background_migrators do
 195     [
 196       Pleroma.Migrators.HashtagsTableMigrator
 197     ]
 198   end
 199
 200   defp task_children(:test) do
 201     [
 202       %{
 203         id: :web_push_init,
 204         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 205         restart: :temporary
 206       }
 207     ]
 208   end
 209
 210   defp task_children(_) do
 211     [
 212       %{
 213         id: :web_push_init,
 214         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 215         restart: :temporary
 216       },
 217       %{
 218         id: :internal_fetch_init,
 219         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 220         restart: :temporary
 221       }
 222     ]
 223   end
 224
 225   def elasticsearch_children do
 226     config = Config.get([Pleroma.Search, :module])
 227
 228     if config == Pleroma.Search.Elasticsearch do
 229       [Pleroma.Search.Elasticsearch.Cluster]
 230     else
 231       []
 232     end
 233   end
 234
 235   @spec limiters_setup() :: :ok
 236   def limiters_setup do
 237     config = Config.get(ConcurrentLimiter, [])
 238
 239     [
 240       Pleroma.Web.RichMedia.Helpers,
 241       Pleroma.Web.ActivityPub.MRF.MediaProxyWarmingPolicy,
 242       Pleroma.Search
 243     ]
 244     |> Enum.each(fn module ->
 245       mod_config = Keyword.get(config, module, [])
 246
 247       max_running = Keyword.get(mod_config, :max_running, 5)
 248       max_waiting = Keyword.get(mod_config, :max_waiting, 5)
 249
 250       ConcurrentLimiter.new(module, max_running, max_waiting)
 251     end)
 252   end
 253
 254   defp http_children do
 255     proxy_url = Config.get([:http, :proxy_url])
 256     proxy = Pleroma.HTTP.AdapterHelper.format_proxy(proxy_url)
 257
 258     config =
 259       [:http, :adapter]
 260       |> Config.get([])
 261       |> Pleroma.HTTP.AdapterHelper.maybe_add_proxy_pool(proxy)
 262       |> Keyword.put(:name, MyFinch)
 263
 264     [{Finch, config}]
 265   end
 266 end