git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   use Application
   7
   8   import Cachex.Spec
   9
  10   alias Pleroma.Config
  11
  12   require Logger
  13
  14   @name Mix.Project.config()[:name]
  15   @version Mix.Project.config()[:version]
  16   @repository Mix.Project.config()[:source_url]
  17   @env Mix.env()
  18
  19   def name, do: @name
  20   def version, do: @version
  21   def named_version, do: @name <> " " <> @version
  22   def repository, do: @repository
  23
  24   def user_agent do
  25     case Config.get([:http, :user_agent], :default) do
  26       :default ->
  27         info = "#{Pleroma.Web.base_url()} <#{Config.get([:instance, :email], "")}>"
  28         named_version() <> "; " <> info
  29
  30       custom ->
  31         custom
  32     end
  33   end
  34
  35   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  36   # for more information on OTP Applications
  37   def start(_type, _args) do
  38     Pleroma.Config.Holder.save_default()
  39     Pleroma.HTML.compile_scrubbers()
  40     Config.DeprecationWarnings.warn()
  41     Pleroma.Plugs.HTTPSecurityPlug.warn_if_disabled()
  42     Pleroma.ApplicationRequirements.verify!()
  43     setup_instrumenters()
  44     load_custom_modules()
  45
  46     adapter = Application.get_env(:tesla, :adapter)
  47
  48     if adapter == Tesla.Adapter.Gun do
  49       if version = Pleroma.OTPVersion.version() do
  50         [major, minor] =
  51           version
  52           |> String.split(".")
  53           |> Enum.map(&String.to_integer/1)
  54           |> Enum.take(2)
  55
  56         if (major == 22 and minor < 2) or major < 22 do
  57           raise "
  58             !!!OTP VERSION WARNING!!!
  59             You are using gun adapter with OTP version #{version}, which doesn't support correct handling of unordered certificates chains. Please update your Erlang/OTP to at least 22.2.
  60             "
  61         end
  62       else
  63         raise "
  64           !!!OTP VERSION WARNING!!!
  65           To support correct handling of unordered certificates chains - OTP version must be > 22.2.
  66           "
  67       end
  68     end
  69
  70     # Define workers and child supervisors to be supervised
  71     children =
  72       [
  73         Pleroma.Repo,
  74         Config.TransferTask,
  75         Pleroma.Emoji,
  76         Pleroma.Plugs.RateLimiter.Supervisor
  77       ] ++
  78         cachex_children() ++
  79         http_children(adapter, @env) ++
  80         [
  81           Pleroma.Stats,
  82           Pleroma.JobQueueMonitor,
  83           {Oban, Config.get(Oban)}
  84         ] ++
  85         task_children(@env) ++
  86         streamer_child(@env) ++
  87         chat_child(@env, chat_enabled?()) ++
  88         [
  89           Pleroma.Web.Endpoint,
  90           Pleroma.Gopher.Server
  91         ]
  92
  93     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  94     # for other strategies and supported options
  95     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  96     Supervisor.start_link(children, opts)
  97   end
  98
  99   def load_custom_modules do
 100     dir = Config.get([:modules, :runtime_dir])
 101
 102     if dir && File.exists?(dir) do
 103       dir
 104       |> Pleroma.Utils.compile_dir()
 105       |> case do
 106         {:error, _errors, _warnings} ->
 107           raise "Invalid custom modules"
 108
 109         {:ok, modules, _warnings} ->
 110           if @env != :test do
 111             Enum.each(modules, fn mod ->
 112               Logger.info("Custom module loaded: #{inspect(mod)}")
 113             end)
 114           end
 115
 116           :ok
 117       end
 118     end
 119   end
 120
 121   defp setup_instrumenters do
 122     require Prometheus.Registry
 123
 124     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
 125       :ok =
 126         :telemetry.attach(
 127           "prometheus-ecto",
 128           [:pleroma, :repo, :query],
 129           &Pleroma.Repo.Instrumenter.handle_event/4,
 130           %{}
 131         )
 132
 133       Pleroma.Repo.Instrumenter.setup()
 134     end
 135
 136     Pleroma.Web.Endpoint.MetricsExporter.setup()
 137     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
 138     Pleroma.Web.Endpoint.Instrumenter.setup()
 139   end
 140
 141   defp cachex_children do
 142     [
 143       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 144       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 145       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 146       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 147       build_cachex("scrubber", limit: 2500),
 148       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 149       build_cachex("web_resp", limit: 2500),
 150       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 151       build_cachex("failed_proxy_url", limit: 2500),
 152       build_cachex("banned_urls", default_ttl: :timer.hours(24 * 30), limit: 5_000)
 153     ]
 154   end
 155
 156   defp emoji_packs_expiration,
 157     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 158
 159   defp idempotency_expiration,
 160     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 161
 162   defp seconds_valid_interval,
 163     do: :timer.seconds(Config.get!([Pleroma.Captcha, :seconds_valid]))
 164
 165   defp build_cachex(type, opts),
 166     do: %{
 167       id: String.to_atom("cachex_" <> type),
 168       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 169       type: :worker
 170     }
 171
 172   defp chat_enabled?, do: Config.get([:chat, :enabled])
 173
 174   defp streamer_child(env) when env in [:test, :benchmark], do: []
 175
 176   defp streamer_child(_) do
 177     [
 178       {Registry,
 179        [
 180          name: Pleroma.Web.Streamer.registry(),
 181          keys: :duplicate,
 182          partitions: System.schedulers_online()
 183        ]}
 184     ]
 185   end
 186
 187   defp chat_child(_env, true) do
 188     [Pleroma.Web.ChatChannel.ChatChannelState]
 189   end
 190
 191   defp chat_child(_, _), do: []
 192
 193   defp task_children(:test) do
 194     [
 195       %{
 196         id: :web_push_init,
 197         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 198         restart: :temporary
 199       }
 200     ]
 201   end
 202
 203   defp task_children(_) do
 204     [
 205       %{
 206         id: :web_push_init,
 207         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 208         restart: :temporary
 209       },
 210       %{
 211         id: :internal_fetch_init,
 212         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 213         restart: :temporary
 214       }
 215     ]
 216   end
 217
 218   # start hackney and gun pools in tests
 219   defp http_children(_, :test) do
 220     hackney_options = Config.get([:hackney_pools, :federation])
 221     hackney_pool = :hackney_pool.child_spec(:federation, hackney_options)
 222     [hackney_pool, Pleroma.Pool.Supervisor]
 223   end
 224
 225   defp http_children(Tesla.Adapter.Hackney, _) do
 226     pools = [:federation, :media]
 227
 228     pools =
 229       if Config.get([Pleroma.Upload, :proxy_remote]) do
 230         [:upload | pools]
 231       else
 232         pools
 233       end
 234
 235     for pool <- pools do
 236       options = Config.get([:hackney_pools, pool])
 237       :hackney_pool.child_spec(pool, options)
 238     end
 239   end
 240
 241   defp http_children(Tesla.Adapter.Gun, _), do: [Pleroma.Pool.Supervisor]
 242
 243   defp http_children(_, _), do: []
 244 end