git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   use Application
   7
   8   import Cachex.Spec
   9
  10   alias Pleroma.Config
  11
  12   require Logger
  13
  14   @name Mix.Project.config()[:name]
  15   @version Mix.Project.config()[:version]
  16   @repository Mix.Project.config()[:source_url]
  17   @mix_env Mix.env()
  18
  19   def name, do: @name
  20   def version, do: @version
  21   def named_version, do: @name <> " " <> @version
  22   def repository, do: @repository
  23
  24   def user_agent do
  25     if Process.whereis(Pleroma.Web.Endpoint) do
  26       case Config.get([:http, :user_agent], :default) do
  27         :default ->
  28           info = "#{Pleroma.Web.base_url()} <#{Config.get([:instance, :email], "")}>"
  29           named_version() <> "; " <> info
  30
  31         custom ->
  32           custom
  33       end
  34     else
  35       # fallback, if endpoint is not started yet
  36       "Pleroma Data Loader"
  37     end
  38   end
  39
  40   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  41   # for more information on OTP Applications
  42   def start(_type, _args) do
  43     # Scrubbers are compiled at runtime and therefore will cause a conflict
  44     # every time the application is restarted, so we disable module
  45     # conflicts at runtime
  46     Code.compiler_options(ignore_module_conflict: true)
  47     # Disable warnings_as_errors at runtime, it breaks Phoenix live reload
  48     # due to protocol consolidation warnings
  49     Code.compiler_options(warnings_as_errors: false)
  50     Pleroma.Telemetry.Logger.attach()
  51     Config.Holder.save_default()
  52     Pleroma.HTML.compile_scrubbers()
  53     Pleroma.Config.Oban.warn()
  54     Config.DeprecationWarnings.warn()
  55     Pleroma.Web.Plugs.HTTPSecurityPlug.warn_if_disabled()
  56     Pleroma.ApplicationRequirements.verify!()
  57     setup_instrumenters()
  58     load_custom_modules()
  59     Pleroma.Docs.JSON.compile()
  60     limiters_setup()
  61
  62     adapter = Application.get_env(:tesla, :adapter)
  63
  64     if adapter == Tesla.Adapter.Gun do
  65       if version = Pleroma.OTPVersion.version() do
  66         [major, minor] =
  67           version
  68           |> String.split(".")
  69           |> Enum.map(&String.to_integer/1)
  70           |> Enum.take(2)
  71
  72         if (major == 22 and minor < 2) or major < 22 do
  73           raise "
  74             !!!OTP VERSION WARNING!!!
  75             You are using gun adapter with OTP version #{version}, which doesn't support correct handling of unordered certificates chains. Please update your Erlang/OTP to at least 22.2.
  76             "
  77         end
  78       else
  79         raise "
  80           !!!OTP VERSION WARNING!!!
  81           To support correct handling of unordered certificates chains - OTP version must be > 22.2.
  82           "
  83       end
  84     end
  85
  86     # Define workers and child supervisors to be supervised
  87     children =
  88       [
  89         Pleroma.Repo,
  90         Config.TransferTask,
  91         Pleroma.Emoji,
  92         Pleroma.Web.Plugs.RateLimiter.Supervisor
  93       ] ++
  94         cachex_children() ++
  95         http_children(adapter, @mix_env) ++
  96         [
  97           Pleroma.Stats,
  98           Pleroma.JobQueueMonitor,
  99           {Majic.Pool, [name: Pleroma.MajicPool, pool_size: Config.get([:majic_pool, :size], 2)]},
 100           {Oban, Config.get(Oban)},
 101           Pleroma.Web.Endpoint
 102         ] ++
 103         task_children(@mix_env) ++
 104         dont_run_in_test(@mix_env) ++
 105         chat_child(chat_enabled?()) ++
 106         [
 107           Pleroma.Migrators.HashtagsTableMigrator,
 108           Pleroma.Gopher.Server
 109         ]
 110
 111     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
 112     # for other strategies and supported options
 113     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
 114     result = Supervisor.start_link(children, opts)
 115
 116     set_postgres_server_version()
 117
 118     result
 119   end
 120
 121   defp set_postgres_server_version do
 122     version =
 123       with %{rows: [[version]]} <- Ecto.Adapters.SQL.query!(Pleroma.Repo, "show server_version"),
 124            {num, _} <- Float.parse(version) do
 125         num
 126       else
 127         e ->
 128           Logger.warn(
 129             "Could not get the postgres version: #{inspect(e)}.\nSetting the default value of 9.6"
 130           )
 131
 132           9.6
 133       end
 134
 135     :persistent_term.put({Pleroma.Repo, :postgres_version}, version)
 136   end
 137
 138   def load_custom_modules do
 139     dir = Config.get([:modules, :runtime_dir])
 140
 141     if dir && File.exists?(dir) do
 142       dir
 143       |> Pleroma.Utils.compile_dir()
 144       |> case do
 145         {:error, _errors, _warnings} ->
 146           raise "Invalid custom modules"
 147
 148         {:ok, modules, _warnings} ->
 149           if @mix_env != :test do
 150             Enum.each(modules, fn mod ->
 151               Logger.info("Custom module loaded: #{inspect(mod)}")
 152             end)
 153           end
 154
 155           :ok
 156       end
 157     end
 158   end
 159
 160   defp setup_instrumenters do
 161     require Prometheus.Registry
 162
 163     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
 164       :ok =
 165         :telemetry.attach(
 166           "prometheus-ecto",
 167           [:pleroma, :repo, :query],
 168           &Pleroma.Repo.Instrumenter.handle_event/4,
 169           %{}
 170         )
 171
 172       Pleroma.Repo.Instrumenter.setup()
 173     end
 174
 175     Pleroma.Web.Endpoint.MetricsExporter.setup()
 176     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
 177
 178     # Note: disabled until prometheus-phx is integrated into prometheus-phoenix:
 179     # Pleroma.Web.Endpoint.Instrumenter.setup()
 180     PrometheusPhx.setup()
 181   end
 182
 183   defp cachex_children do
 184     [
 185       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 186       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 187       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 188       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 189       build_cachex("scrubber", limit: 2500),
 190       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 191       build_cachex("web_resp", limit: 2500),
 192       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 193       build_cachex("failed_proxy_url", limit: 2500),
 194       build_cachex("banned_urls", default_ttl: :timer.hours(24 * 30), limit: 5_000),
 195       build_cachex("chat_message_id_idempotency_key",
 196         expiration: chat_message_id_idempotency_key_expiration(),
 197         limit: 500_000
 198       )
 199     ]
 200   end
 201
 202   defp emoji_packs_expiration,
 203     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 204
 205   defp idempotency_expiration,
 206     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 207
 208   defp chat_message_id_idempotency_key_expiration,
 209     do: expiration(default: :timer.minutes(2), interval: :timer.seconds(60))
 210
 211   defp seconds_valid_interval,
 212     do: :timer.seconds(Config.get!([Pleroma.Captcha, :seconds_valid]))
 213
 214   @spec build_cachex(String.t(), keyword()) :: map()
 215   def build_cachex(type, opts),
 216     do: %{
 217       id: String.to_atom("cachex_" <> type),
 218       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 219       type: :worker
 220     }
 221
 222   defp chat_enabled?, do: Config.get([:chat, :enabled])
 223
 224   defp dont_run_in_test(env) when env in [:test, :benchmark], do: []
 225
 226   defp dont_run_in_test(_) do
 227     [
 228       {Registry,
 229        [
 230          name: Pleroma.Web.Streamer.registry(),
 231          keys: :duplicate,
 232          partitions: System.schedulers_online()
 233        ]}
 234     ]
 235   end
 236
 237   defp chat_child(true) do
 238     [
 239       Pleroma.Web.ChatChannel.ChatChannelState,
 240       {Phoenix.PubSub, [name: Pleroma.PubSub, adapter: Phoenix.PubSub.PG2]}
 241     ]
 242   end
 243
 244   defp chat_child(_), do: []
 245
 246   defp task_children(:test) do
 247     [
 248       %{
 249         id: :web_push_init,
 250         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 251         restart: :temporary
 252       }
 253     ]
 254   end
 255
 256   defp task_children(_) do
 257     [
 258       %{
 259         id: :web_push_init,
 260         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 261         restart: :temporary
 262       },
 263       %{
 264         id: :internal_fetch_init,
 265         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 266         restart: :temporary
 267       }
 268     ]
 269   end
 270
 271   # start hackney and gun pools in tests
 272   defp http_children(_, :test) do
 273     http_children(Tesla.Adapter.Hackney, nil) ++ http_children(Tesla.Adapter.Gun, nil)
 274   end
 275
 276   defp http_children(Tesla.Adapter.Hackney, _) do
 277     pools = [:federation, :media]
 278
 279     pools =
 280       if Config.get([Pleroma.Upload, :proxy_remote]) do
 281         [:upload | pools]
 282       else
 283         pools
 284       end
 285
 286     for pool <- pools do
 287       options = Config.get([:hackney_pools, pool])
 288       :hackney_pool.child_spec(pool, options)
 289     end
 290   end
 291
 292   defp http_children(Tesla.Adapter.Gun, _) do
 293     Pleroma.Gun.ConnectionPool.children() ++
 294       [{Task, &Pleroma.HTTP.AdapterHelper.Gun.limiter_setup/0}]
 295   end
 296
 297   defp http_children(_, _), do: []
 298
 299   @spec limiters_setup() :: :ok
 300   def limiters_setup do
 301     config = Config.get(ConcurrentLimiter, [])
 302
 303     [Pleroma.Web.RichMedia.Helpers, Pleroma.Web.ActivityPub.MRF.MediaProxyWarmingPolicy]
 304     |> Enum.each(fn module ->
 305       mod_config = Keyword.get(config, module, [])
 306
 307       max_running = Keyword.get(mod_config, :max_running, 5)
 308       max_waiting = Keyword.get(mod_config, :max_waiting, 5)
 309
 310       ConcurrentLimiter.new(module, max_running, max_waiting)
 311     end)
 312   end
 313 end