git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   use Application
   7
   8   import Cachex.Spec
   9
  10   alias Pleroma.Config
  11
  12   require Logger
  13
  14   @name Mix.Project.config()[:name]
  15   @version Mix.Project.config()[:version]
  16   @repository Mix.Project.config()[:source_url]
  17   @env Mix.env()
  18
  19   def name, do: @name
  20   def version, do: @version
  21   def named_version, do: @name <> " " <> @version
  22   def repository, do: @repository
  23
  24   def user_agent do
  25     if Process.whereis(Pleroma.Web.Endpoint) do
  26       case Config.get([:http, :user_agent], :default) do
  27         :default ->
  28           info = "#{Pleroma.Web.base_url()} <#{Config.get([:instance, :email], "")}>"
  29           named_version() <> "; " <> info
  30
  31         custom ->
  32           custom
  33       end
  34     else
  35       # fallback, if endpoint is not started yet
  36       "Pleroma Data Loader"
  37     end
  38   end
  39
  40   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  41   # for more information on OTP Applications
  42   def start(_type, _args) do
  43     # Scrubbers are compiled at runtime and therefore will cause a conflict
  44     # every time the application is restarted, so we disable module
  45     # conflicts at runtime
  46     Code.compiler_options(ignore_module_conflict: true)
  47     # Disable warnings_as_errors at runtime, it breaks Phoenix live reload
  48     # due to protocol consolidation warnings
  49     Code.compiler_options(warnings_as_errors: false)
  50     Pleroma.Telemetry.Logger.attach()
  51     Config.Holder.save_default()
  52     Pleroma.HTML.compile_scrubbers()
  53     Pleroma.Config.Oban.warn()
  54     Config.DeprecationWarnings.warn()
  55     Pleroma.Web.Plugs.HTTPSecurityPlug.warn_if_disabled()
  56     Pleroma.ApplicationRequirements.verify!()
  57     setup_instrumenters()
  58     load_custom_modules()
  59     Pleroma.Docs.JSON.compile()
  60
  61     adapter = Application.get_env(:tesla, :adapter)
  62
  63     if adapter == Tesla.Adapter.Gun do
  64       if version = Pleroma.OTPVersion.version() do
  65         [major, minor] =
  66           version
  67           |> String.split(".")
  68           |> Enum.map(&String.to_integer/1)
  69           |> Enum.take(2)
  70
  71         if (major == 22 and minor < 2) or major < 22 do
  72           raise "
  73             !!!OTP VERSION WARNING!!!
  74             You are using gun adapter with OTP version #{version}, which doesn't support correct handling of unordered certificates chains. Please update your Erlang/OTP to at least 22.2.
  75             "
  76         end
  77       else
  78         raise "
  79           !!!OTP VERSION WARNING!!!
  80           To support correct handling of unordered certificates chains - OTP version must be > 22.2.
  81           "
  82       end
  83     end
  84
  85     # Define workers and child supervisors to be supervised
  86     children =
  87       [
  88         Pleroma.Repo,
  89         Config.TransferTask,
  90         Pleroma.Emoji,
  91         Pleroma.Web.Plugs.RateLimiter.Supervisor
  92       ] ++
  93         cachex_children() ++
  94         http_children(adapter, @env) ++
  95         [
  96           Pleroma.Stats,
  97           Pleroma.JobQueueMonitor,
  98           {Majic.Pool, [name: Pleroma.MajicPool, pool_size: Config.get([:majic_pool, :size], 2)]},
  99           {Oban, Config.get(Oban)}
 100         ] ++
 101         task_children(@env) ++
 102         dont_run_in_test(@env) ++
 103         chat_child(chat_enabled?()) ++
 104         [
 105           Pleroma.Web.Endpoint,
 106           Pleroma.Gopher.Server
 107         ]
 108
 109     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
 110     # for other strategies and supported options
 111     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
 112     Supervisor.start_link(children, opts)
 113   end
 114
 115   def load_custom_modules do
 116     dir = Config.get([:modules, :runtime_dir])
 117
 118     if dir && File.exists?(dir) do
 119       dir
 120       |> Pleroma.Utils.compile_dir()
 121       |> case do
 122         {:error, _errors, _warnings} ->
 123           raise "Invalid custom modules"
 124
 125         {:ok, modules, _warnings} ->
 126           if @env != :test do
 127             Enum.each(modules, fn mod ->
 128               Logger.info("Custom module loaded: #{inspect(mod)}")
 129             end)
 130           end
 131
 132           :ok
 133       end
 134     end
 135   end
 136
 137   defp setup_instrumenters do
 138     require Prometheus.Registry
 139
 140     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
 141       :ok =
 142         :telemetry.attach(
 143           "prometheus-ecto",
 144           [:pleroma, :repo, :query],
 145           &Pleroma.Repo.Instrumenter.handle_event/4,
 146           %{}
 147         )
 148
 149       Pleroma.Repo.Instrumenter.setup()
 150     end
 151
 152     Pleroma.Web.Endpoint.MetricsExporter.setup()
 153     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
 154
 155     # Note: disabled until prometheus-phx is integrated into prometheus-phoenix:
 156     # Pleroma.Web.Endpoint.Instrumenter.setup()
 157     PrometheusPhx.setup()
 158   end
 159
 160   defp cachex_children do
 161     [
 162       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 163       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 164       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 165       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 166       build_cachex("scrubber", limit: 2500),
 167       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 168       build_cachex("web_resp", limit: 2500),
 169       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 170       build_cachex("failed_proxy_url", limit: 2500),
 171       build_cachex("banned_urls", default_ttl: :timer.hours(24 * 30), limit: 5_000),
 172       build_cachex("chat_message_id_idempotency_key",
 173         expiration: chat_message_id_idempotency_key_expiration(),
 174         limit: 500_000
 175       )
 176     ]
 177   end
 178
 179   defp emoji_packs_expiration,
 180     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 181
 182   defp idempotency_expiration,
 183     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 184
 185   defp chat_message_id_idempotency_key_expiration,
 186     do: expiration(default: :timer.minutes(2), interval: :timer.seconds(60))
 187
 188   defp seconds_valid_interval,
 189     do: :timer.seconds(Config.get!([Pleroma.Captcha, :seconds_valid]))
 190
 191   @spec build_cachex(String.t(), keyword()) :: map()
 192   def build_cachex(type, opts),
 193     do: %{
 194       id: String.to_atom("cachex_" <> type),
 195       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 196       type: :worker
 197     }
 198
 199   defp chat_enabled?, do: Config.get([:chat, :enabled])
 200
 201   defp dont_run_in_test(env) when env in [:test, :benchmark], do: []
 202
 203   defp dont_run_in_test(_) do
 204     [
 205       {Registry,
 206        [
 207          name: Pleroma.Web.Streamer.registry(),
 208          keys: :duplicate,
 209          partitions: System.schedulers_online()
 210        ]},
 211       Pleroma.Web.FedSockets.Supervisor
 212     ]
 213   end
 214
 215   defp chat_child(true) do
 216     [
 217       Pleroma.Web.ChatChannel.ChatChannelState,
 218       {Phoenix.PubSub, [name: Pleroma.PubSub, adapter: Phoenix.PubSub.PG2]}
 219     ]
 220   end
 221
 222   defp chat_child(_), do: []
 223
 224   defp task_children(:test) do
 225     [
 226       %{
 227         id: :web_push_init,
 228         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 229         restart: :temporary
 230       }
 231     ]
 232   end
 233
 234   defp task_children(_) do
 235     [
 236       %{
 237         id: :web_push_init,
 238         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 239         restart: :temporary
 240       },
 241       %{
 242         id: :internal_fetch_init,
 243         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 244         restart: :temporary
 245       }
 246     ]
 247   end
 248
 249   # start hackney and gun pools in tests
 250   defp http_children(_, :test) do
 251     http_children(Tesla.Adapter.Hackney, nil) ++ http_children(Tesla.Adapter.Gun, nil)
 252   end
 253
 254   defp http_children(Tesla.Adapter.Hackney, _) do
 255     pools = [:federation, :media]
 256
 257     pools =
 258       if Config.get([Pleroma.Upload, :proxy_remote]) do
 259         [:upload | pools]
 260       else
 261         pools
 262       end
 263
 264     for pool <- pools do
 265       options = Config.get([:hackney_pools, pool])
 266       :hackney_pool.child_spec(pool, options)
 267     end
 268   end
 269
 270   defp http_children(Tesla.Adapter.Gun, _) do
 271     Pleroma.Gun.ConnectionPool.children() ++
 272       [{Task, &Pleroma.HTTP.AdapterHelper.Gun.limiter_setup/0}]
 273   end
 274
 275   defp http_children(_, _), do: []
 276 end