git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   use Application
   7
   8   import Cachex.Spec
   9
  10   alias Pleroma.Config
  11
  12   require Logger
  13
  14   @name Mix.Project.config()[:name]
  15   @version Mix.Project.config()[:version]
  16   @repository Mix.Project.config()[:source_url]
  17   @env Mix.env()
  18
  19   def name, do: @name
  20   def version, do: @version
  21   def named_version, do: @name <> " " <> @version
  22   def repository, do: @repository
  23
  24   def user_agent do
  25     if Process.whereis(Pleroma.Web.Endpoint) do
  26       case Config.get([:http, :user_agent], :default) do
  27         :default ->
  28           info = "#{Pleroma.Web.base_url()} <#{Config.get([:instance, :email], "")}>"
  29           named_version() <> "; " <> info
  30
  31         custom ->
  32           custom
  33       end
  34     else
  35       # fallback, if endpoint is not started yet
  36       "Pleroma Data Loader"
  37     end
  38   end
  39
  40   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  41   # for more information on OTP Applications
  42   def start(_type, _args) do
  43     # Scrubbers are compiled at runtime and therefore will cause a conflict
  44     # every time the application is restarted, so we disable module
  45     # conflicts at runtime
  46     Code.compiler_options(ignore_module_conflict: true)
  47     # Disable warnings_as_errors at runtime, it breaks Phoenix live reload
  48     # due to protocol consolidation warnings
  49     Code.compiler_options(warnings_as_errors: false)
  50     Pleroma.Telemetry.Logger.attach()
  51     Config.Holder.save_default()
  52     Pleroma.HTML.compile_scrubbers()
  53     Pleroma.Config.Oban.warn()
  54     Config.DeprecationWarnings.warn()
  55     Pleroma.Web.Plugs.HTTPSecurityPlug.warn_if_disabled()
  56     Pleroma.ApplicationRequirements.verify!()
  57     setup_instrumenters()
  58     load_custom_modules()
  59     Pleroma.Docs.JSON.compile()
  60     limiters_setup()
  61
  62     adapter = Application.get_env(:tesla, :adapter)
  63
  64     if adapter == Tesla.Adapter.Gun do
  65       if version = Pleroma.OTPVersion.version() do
  66         [major, minor] =
  67           version
  68           |> String.split(".")
  69           |> Enum.map(&String.to_integer/1)
  70           |> Enum.take(2)
  71
  72         if (major == 22 and minor < 2) or major < 22 do
  73           raise "
  74             !!!OTP VERSION WARNING!!!
  75             You are using gun adapter with OTP version #{version}, which doesn't support correct handling of unordered certificates chains. Please update your Erlang/OTP to at least 22.2.
  76             "
  77         end
  78       else
  79         raise "
  80           !!!OTP VERSION WARNING!!!
  81           To support correct handling of unordered certificates chains - OTP version must be > 22.2.
  82           "
  83       end
  84     end
  85
  86     # Define workers and child supervisors to be supervised
  87     children =
  88       [
  89         Pleroma.Repo,
  90         Config.TransferTask,
  91         Pleroma.Emoji,
  92         Pleroma.Web.Plugs.RateLimiter.Supervisor
  93       ] ++
  94         cachex_children() ++
  95         http_children(adapter, @env) ++
  96         [
  97           Pleroma.Stats,
  98           Pleroma.JobQueueMonitor,
  99           {Majic.Pool, [name: Pleroma.MajicPool, pool_size: Config.get([:majic_pool, :size], 2)]},
 100           {Oban, Config.get(Oban)}
 101         ] ++
 102         task_children(@env) ++
 103         dont_run_in_test(@env) ++
 104         chat_child(chat_enabled?()) ++
 105         [
 106           Pleroma.Web.Endpoint,
 107           Pleroma.Gopher.Server
 108         ]
 109
 110     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
 111     # for other strategies and supported options
 112     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
 113     result = Supervisor.start_link(children, opts)
 114
 115     set_postgres_server_version()
 116
 117     # Requires Config.TransferTask so ConfigDB values are loaded
 118     steal_emoji_policy_setup()
 119
 120     result
 121   end
 122
 123   defp set_postgres_server_version do
 124     version =
 125       with %{rows: [[version]]} <- Ecto.Adapters.SQL.query!(Pleroma.Repo, "show server_version"),
 126            {num, _} <- Float.parse(version) do
 127         num
 128       else
 129         e ->
 130           Logger.warn(
 131             "Could not get the postgres version: #{inspect(e)}.\nSetting the default value of 9.6"
 132           )
 133
 134           9.6
 135       end
 136
 137     :persistent_term.put({Pleroma.Repo, :postgres_version}, version)
 138   end
 139
 140   def load_custom_modules do
 141     dir = Config.get([:modules, :runtime_dir])
 142
 143     if dir && File.exists?(dir) do
 144       dir
 145       |> Pleroma.Utils.compile_dir()
 146       |> case do
 147         {:error, _errors, _warnings} ->
 148           raise "Invalid custom modules"
 149
 150         {:ok, modules, _warnings} ->
 151           if @env != :test do
 152             Enum.each(modules, fn mod ->
 153               Logger.info("Custom module loaded: #{inspect(mod)}")
 154             end)
 155           end
 156
 157           :ok
 158       end
 159     end
 160   end
 161
 162   defp setup_instrumenters do
 163     require Prometheus.Registry
 164
 165     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
 166       :ok =
 167         :telemetry.attach(
 168           "prometheus-ecto",
 169           [:pleroma, :repo, :query],
 170           &Pleroma.Repo.Instrumenter.handle_event/4,
 171           %{}
 172         )
 173
 174       Pleroma.Repo.Instrumenter.setup()
 175     end
 176
 177     Pleroma.Web.Endpoint.MetricsExporter.setup()
 178     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
 179
 180     # Note: disabled until prometheus-phx is integrated into prometheus-phoenix:
 181     # Pleroma.Web.Endpoint.Instrumenter.setup()
 182     PrometheusPhx.setup()
 183   end
 184
 185   defp cachex_children do
 186     [
 187       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 188       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 189       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 190       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 191       build_cachex("scrubber", limit: 2500),
 192       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 193       build_cachex("web_resp", limit: 2500),
 194       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 195       build_cachex("failed_proxy_url", limit: 2500),
 196       build_cachex("banned_urls", default_ttl: :timer.hours(24 * 30), limit: 5_000),
 197       build_cachex("chat_message_id_idempotency_key",
 198         expiration: chat_message_id_idempotency_key_expiration(),
 199         limit: 500_000
 200       )
 201     ]
 202   end
 203
 204   defp emoji_packs_expiration,
 205     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 206
 207   defp idempotency_expiration,
 208     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 209
 210   defp chat_message_id_idempotency_key_expiration,
 211     do: expiration(default: :timer.minutes(2), interval: :timer.seconds(60))
 212
 213   defp seconds_valid_interval,
 214     do: :timer.seconds(Config.get!([Pleroma.Captcha, :seconds_valid]))
 215
 216   @spec build_cachex(String.t(), keyword()) :: map()
 217   def build_cachex(type, opts),
 218     do: %{
 219       id: String.to_atom("cachex_" <> type),
 220       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 221       type: :worker
 222     }
 223
 224   defp chat_enabled?, do: Config.get([:chat, :enabled])
 225
 226   defp dont_run_in_test(env) when env in [:test, :benchmark], do: []
 227
 228   defp dont_run_in_test(_) do
 229     [
 230       {Registry,
 231        [
 232          name: Pleroma.Web.Streamer.registry(),
 233          keys: :duplicate,
 234          partitions: System.schedulers_online()
 235        ]}
 236     ]
 237   end
 238
 239   defp chat_child(true) do
 240     [
 241       Pleroma.Web.ChatChannel.ChatChannelState,
 242       {Phoenix.PubSub, [name: Pleroma.PubSub, adapter: Phoenix.PubSub.PG2]}
 243     ]
 244   end
 245
 246   defp chat_child(_), do: []
 247
 248   defp task_children(:test) do
 249     [
 250       %{
 251         id: :web_push_init,
 252         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 253         restart: :temporary
 254       }
 255     ]
 256   end
 257
 258   defp task_children(_) do
 259     [
 260       %{
 261         id: :web_push_init,
 262         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 263         restart: :temporary
 264       },
 265       %{
 266         id: :internal_fetch_init,
 267         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 268         restart: :temporary
 269       }
 270     ]
 271   end
 272
 273   # start hackney and gun pools in tests
 274   defp http_children(_, :test) do
 275     http_children(Tesla.Adapter.Hackney, nil) ++ http_children(Tesla.Adapter.Gun, nil)
 276   end
 277
 278   defp http_children(Tesla.Adapter.Hackney, _) do
 279     pools = [:federation, :media]
 280
 281     pools =
 282       if Config.get([Pleroma.Upload, :proxy_remote]) do
 283         [:upload | pools]
 284       else
 285         pools
 286       end
 287
 288     for pool <- pools do
 289       options = Config.get([:hackney_pools, pool])
 290       :hackney_pool.child_spec(pool, options)
 291     end
 292   end
 293
 294   defp http_children(Tesla.Adapter.Gun, _) do
 295     Pleroma.Gun.ConnectionPool.children() ++
 296       [{Task, &Pleroma.HTTP.AdapterHelper.Gun.limiter_setup/0}]
 297   end
 298
 299   defp http_children(_, _), do: []
 300
 301   @spec limiters_setup() :: :ok
 302   def limiters_setup do
 303     [Pleroma.Web.RichMedia.Helpers, Pleroma.Web.MediaProxy]
 304     |> Enum.each(&ConcurrentLimiter.new(&1, 1, 0))
 305   end
 306
 307   @spec steal_emoji_policy_setup() :: :ok
 308   def steal_emoji_policy_setup() do
 309     with true <-
 310            Pleroma.Web.ActivityPub.MRF.StealEmojiPolicy in Config.get!([:mrf, :policies]) do
 311       path =
 312         [:instance, :static_dir]
 313         |> Config.get!()
 314         |> Path.join("emoji/steal")
 315
 316       if !File.exists?(path), do: File.mkdir_p!(path)
 317     else
 318       _ ->
 319         :ok
 320     end
 321   end
 322 end