git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   use Application
   7
   8   import Cachex.Spec
   9
  10   alias Pleroma.Config
  11
  12   require Logger
  13
  14   @name Mix.Project.config()[:name]
  15   @version Mix.Project.config()[:version]
  16   @repository Mix.Project.config()[:source_url]
  17   @mix_env Mix.env()
  18
  19   def name, do: @name
  20   def version, do: @version
  21   def named_version, do: @name <> " " <> @version
  22   def repository, do: @repository
  23
  24   def user_agent do
  25     if Process.whereis(Pleroma.Web.Endpoint) do
  26       case Config.get([:http, :user_agent], :default) do
  27         :default ->
  28           info = "#{Pleroma.Web.Endpoint.url()} <#{Config.get([:instance, :email], "")}>"
  29           named_version() <> "; " <> info
  30
  31         custom ->
  32           custom
  33       end
  34     else
  35       # fallback, if endpoint is not started yet
  36       "Pleroma Data Loader"
  37     end
  38   end
  39
  40   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  41   # for more information on OTP Applications
  42   def start(_type, _args) do
  43     # Scrubbers are compiled at runtime and therefore will cause a conflict
  44     # every time the application is restarted, so we disable module
  45     # conflicts at runtime
  46     Code.compiler_options(ignore_module_conflict: true)
  47     # Disable warnings_as_errors at runtime, it breaks Phoenix live reload
  48     # due to protocol consolidation warnings
  49     Code.compiler_options(warnings_as_errors: false)
  50     Config.Holder.save_default()
  51     Pleroma.HTML.compile_scrubbers()
  52     Pleroma.Config.Oban.warn()
  53     Config.DeprecationWarnings.warn()
  54     Pleroma.Web.Plugs.HTTPSecurityPlug.warn_if_disabled()
  55     Pleroma.ApplicationRequirements.verify!()
  56     load_custom_modules()
  57     Pleroma.Docs.JSON.compile()
  58     limiters_setup()
  59
  60     # Define workers and child supervisors to be supervised
  61     children =
  62       [
  63         Pleroma.Repo,
  64         Config.TransferTask,
  65         Pleroma.Emoji,
  66         Pleroma.Web.Plugs.RateLimiter.Supervisor
  67       ] ++
  68         cachex_children() ++
  69         http_children() ++
  70         [
  71           Pleroma.Stats,
  72           Pleroma.JobQueueMonitor,
  73           {Majic.Pool, [name: Pleroma.MajicPool, pool_size: Config.get([:majic_pool, :size], 2)]},
  74           {Oban, Config.get(Oban)},
  75           Pleroma.Web.Endpoint
  76         ] ++
  77         elasticsearch_children() ++
  78         task_children(@mix_env) ++
  79         dont_run_in_test(@mix_env)
  80
  81     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  82     # for other strategies and supported options
  83     # If we have a lot of caches, default max_restarts can cause test
  84     # resets to fail.
  85     # Go for the default 3 unless we're in test
  86     max_restarts =
  87       if @mix_env == :test do
  88         100
  89       else
  90         3
  91       end
  92
  93     opts = [strategy: :one_for_one, name: Pleroma.Supervisor, max_restarts: max_restarts]
  94
  95     with {:ok, data} <- Supervisor.start_link(children, opts) do
  96       set_postgres_server_version()
  97       {:ok, data}
  98     else
  99       e ->
 100         Logger.error("Failed to start!")
 101         Logger.error("#{inspect(e)}")
 102         e
 103     end
 104   end
 105
 106   defp set_postgres_server_version do
 107     version =
 108       with %{rows: [[version]]} <- Ecto.Adapters.SQL.query!(Pleroma.Repo, "show server_version"),
 109            {num, _} <- Float.parse(version) do
 110         num
 111       else
 112         e ->
 113           Logger.warn(
 114             "Could not get the postgres version: #{inspect(e)}.\nSetting the default value of 9.6"
 115           )
 116
 117           9.6
 118       end
 119
 120     :persistent_term.put({Pleroma.Repo, :postgres_version}, version)
 121   end
 122
 123   def load_custom_modules do
 124     dir = Config.get([:modules, :runtime_dir])
 125
 126     if dir && File.exists?(dir) do
 127       dir
 128       |> Pleroma.Utils.compile_dir()
 129       |> case do
 130         {:error, _errors, _warnings} ->
 131           raise "Invalid custom modules"
 132
 133         {:ok, modules, _warnings} ->
 134           if @mix_env != :test do
 135             Enum.each(modules, fn mod ->
 136               Logger.info("Custom module loaded: #{inspect(mod)}")
 137             end)
 138           end
 139
 140           :ok
 141       end
 142     end
 143   end
 144
 145   defp cachex_children do
 146     [
 147       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 148       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 149       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 150       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 151       build_cachex("scrubber", limit: 2500),
 152       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 153       build_cachex("web_resp", limit: 2500),
 154       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 155       build_cachex("failed_proxy_url", limit: 2500),
 156       build_cachex("banned_urls", default_ttl: :timer.hours(24 * 30), limit: 5_000)
 157     ]
 158   end
 159
 160   defp emoji_packs_expiration,
 161     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 162
 163   defp idempotency_expiration,
 164     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 165
 166   defp seconds_valid_interval,
 167     do: :timer.seconds(Config.get!([Pleroma.Captcha, :seconds_valid]))
 168
 169   @spec build_cachex(String.t(), keyword()) :: map()
 170   def build_cachex(type, opts),
 171     do: %{
 172       id: String.to_atom("cachex_" <> type),
 173       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 174       type: :worker
 175     }
 176
 177   defp dont_run_in_test(env) when env in [:test, :benchmark], do: []
 178
 179   defp dont_run_in_test(_) do
 180     [
 181       {Registry,
 182        [
 183          name: Pleroma.Web.Streamer.registry(),
 184          keys: :duplicate,
 185          partitions: System.schedulers_online()
 186        ]}
 187     ] ++ background_migrators()
 188   end
 189
 190   defp background_migrators do
 191     [
 192       Pleroma.Migrators.HashtagsTableMigrator
 193     ]
 194   end
 195
 196   defp task_children(:test) do
 197     [
 198       %{
 199         id: :web_push_init,
 200         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 201         restart: :temporary
 202       }
 203     ]
 204   end
 205
 206   defp task_children(_) do
 207     [
 208       %{
 209         id: :web_push_init,
 210         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 211         restart: :temporary
 212       },
 213       %{
 214         id: :internal_fetch_init,
 215         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 216         restart: :temporary
 217       }
 218     ]
 219   end
 220
 221   def elasticsearch_children do
 222     config = Config.get([Pleroma.Search, :module])
 223
 224     if config == Pleroma.Search.Elasticsearch do
 225       [Pleroma.Search.Elasticsearch.Cluster]
 226     else
 227       []
 228     end
 229   end
 230
 231   @spec limiters_setup() :: :ok
 232   def limiters_setup do
 233     config = Config.get(ConcurrentLimiter, [])
 234
 235     [
 236       Pleroma.Web.RichMedia.Helpers,
 237       Pleroma.Web.ActivityPub.MRF.MediaProxyWarmingPolicy,
 238       Pleroma.Search
 239     ]
 240     |> Enum.each(fn module ->
 241       mod_config = Keyword.get(config, module, [])
 242
 243       max_running = Keyword.get(mod_config, :max_running, 5)
 244       max_waiting = Keyword.get(mod_config, :max_waiting, 5)
 245
 246       ConcurrentLimiter.new(module, max_running, max_waiting)
 247     end)
 248   end
 249
 250   defp http_children do
 251     config =
 252       [:http, :adapter]
 253       |> Config.get([])
 254       |> Keyword.put(:name, MyFinch)
 255
 256     [{Finch, config}]
 257   end
 258 end