git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   use Application
   7
   8   import Cachex.Spec
   9
  10   alias Pleroma.Config
  11
  12   require Logger
  13
  14   @name Mix.Project.config()[:name]
  15   @version Mix.Project.config()[:version]
  16   @repository Mix.Project.config()[:source_url]
  17   @mix_env Mix.env()
  18
  19   def name, do: @name
  20   def version, do: @version
  21   def named_version, do: @name <> " " <> @version
  22   def repository, do: @repository
  23
  24   def user_agent do
  25     if Process.whereis(Pleroma.Web.Endpoint) do
  26       case Config.get([:http, :user_agent], :default) do
  27         :default ->
  28           info = "#{Pleroma.Web.Endpoint.url()} <#{Config.get([:instance, :email], "")}>"
  29           named_version() <> "; " <> info
  30
  31         custom ->
  32           custom
  33       end
  34     else
  35       # fallback, if endpoint is not started yet
  36       "Pleroma Data Loader"
  37     end
  38   end
  39
  40   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  41   # for more information on OTP Applications
  42   def start(_type, _args) do
  43     # Scrubbers are compiled at runtime and therefore will cause a conflict
  44     # every time the application is restarted, so we disable module
  45     # conflicts at runtime
  46     Code.compiler_options(ignore_module_conflict: true)
  47     # Disable warnings_as_errors at runtime, it breaks Phoenix live reload
  48     # due to protocol consolidation warnings
  49     Code.compiler_options(warnings_as_errors: false)
  50     Pleroma.Telemetry.Logger.attach()
  51     Config.Holder.save_default()
  52     Pleroma.HTML.compile_scrubbers()
  53     Pleroma.Config.Oban.warn()
  54     Config.DeprecationWarnings.warn()
  55     Pleroma.Web.Plugs.HTTPSecurityPlug.warn_if_disabled()
  56     Pleroma.ApplicationRequirements.verify!()
  57     setup_instrumenters()
  58     load_custom_modules()
  59     Pleroma.Docs.JSON.compile()
  60     limiters_setup()
  61
  62     Logger.info("Starting Finch")
  63     Finch.start_link(name: MyFinch)
  64
  65     # Define workers and child supervisors to be supervised
  66     children =
  67       [
  68         Pleroma.Repo,
  69         Config.TransferTask,
  70         Pleroma.Emoji,
  71         Pleroma.Web.Plugs.RateLimiter.Supervisor
  72       ] ++
  73         cachex_children() ++
  74         [
  75           Pleroma.Stats,
  76           Pleroma.JobQueueMonitor,
  77           {Majic.Pool, [name: Pleroma.MajicPool, pool_size: Config.get([:majic_pool, :size], 2)]},
  78           {Oban, Config.get(Oban)},
  79           Pleroma.Web.Endpoint
  80         ] ++
  81         elasticsearch_children() ++
  82         task_children(@mix_env) ++
  83         dont_run_in_test(@mix_env) ++
  84         shout_child(shout_enabled?())
  85
  86     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  87     # for other strategies and supported options
  88     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  89     result = Supervisor.start_link(children, opts)
  90
  91     set_postgres_server_version()
  92
  93     result
  94   end
  95
  96   defp set_postgres_server_version do
  97     version =
  98       with %{rows: [[version]]} <- Ecto.Adapters.SQL.query!(Pleroma.Repo, "show server_version"),
  99            {num, _} <- Float.parse(version) do
 100         num
 101       else
 102         e ->
 103           Logger.warn(
 104             "Could not get the postgres version: #{inspect(e)}.\nSetting the default value of 9.6"
 105           )
 106
 107           9.6
 108       end
 109
 110     :persistent_term.put({Pleroma.Repo, :postgres_version}, version)
 111   end
 112
 113   def load_custom_modules do
 114     dir = Config.get([:modules, :runtime_dir])
 115
 116     if dir && File.exists?(dir) do
 117       dir
 118       |> Pleroma.Utils.compile_dir()
 119       |> case do
 120         {:error, _errors, _warnings} ->
 121           raise "Invalid custom modules"
 122
 123         {:ok, modules, _warnings} ->
 124           if @mix_env != :test do
 125             Enum.each(modules, fn mod ->
 126               Logger.info("Custom module loaded: #{inspect(mod)}")
 127             end)
 128           end
 129
 130           :ok
 131       end
 132     end
 133   end
 134
 135   defp setup_instrumenters do
 136     require Prometheus.Registry
 137
 138     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
 139       :ok =
 140         :telemetry.attach(
 141           "prometheus-ecto",
 142           [:pleroma, :repo, :query],
 143           &Pleroma.Repo.Instrumenter.handle_event/4,
 144           %{}
 145         )
 146
 147       Pleroma.Repo.Instrumenter.setup()
 148     end
 149
 150     Pleroma.Web.Endpoint.MetricsExporter.setup()
 151     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
 152
 153     # Note: disabled until prometheus-phx is integrated into prometheus-phoenix:
 154     # Pleroma.Web.Endpoint.Instrumenter.setup()
 155     PrometheusPhx.setup()
 156   end
 157
 158   defp cachex_children do
 159     [
 160       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 161       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 162       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 163       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 164       build_cachex("scrubber", limit: 2500),
 165       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 166       build_cachex("web_resp", limit: 2500),
 167       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 168       build_cachex("failed_proxy_url", limit: 2500),
 169       build_cachex("banned_urls", default_ttl: :timer.hours(24 * 30), limit: 5_000),
 170       build_cachex("chat_message_id_idempotency_key",
 171         expiration: chat_message_id_idempotency_key_expiration(),
 172         limit: 500_000
 173       )
 174     ]
 175   end
 176
 177   defp emoji_packs_expiration,
 178     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 179
 180   defp idempotency_expiration,
 181     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 182
 183   defp chat_message_id_idempotency_key_expiration,
 184     do: expiration(default: :timer.minutes(2), interval: :timer.seconds(60))
 185
 186   defp seconds_valid_interval,
 187     do: :timer.seconds(Config.get!([Pleroma.Captcha, :seconds_valid]))
 188
 189   @spec build_cachex(String.t(), keyword()) :: map()
 190   def build_cachex(type, opts),
 191     do: %{
 192       id: String.to_atom("cachex_" <> type),
 193       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 194       type: :worker
 195     }
 196
 197   defp shout_enabled?, do: Config.get([:shout, :enabled])
 198
 199   defp dont_run_in_test(env) when env in [:test, :benchmark], do: []
 200
 201   defp dont_run_in_test(_) do
 202     [
 203       {Registry,
 204        [
 205          name: Pleroma.Web.Streamer.registry(),
 206          keys: :duplicate,
 207          partitions: System.schedulers_online()
 208        ]}
 209     ] ++ background_migrators()
 210   end
 211
 212   defp background_migrators do
 213     [
 214       Pleroma.Migrators.HashtagsTableMigrator
 215     ]
 216   end
 217
 218   defp shout_child(true) do
 219     [
 220       Pleroma.Web.ShoutChannel.ShoutChannelState,
 221       {Phoenix.PubSub, [name: Pleroma.PubSub, adapter: Phoenix.PubSub.PG2]}
 222     ]
 223   end
 224
 225   defp shout_child(_), do: []
 226
 227   defp task_children(:test) do
 228     [
 229       %{
 230         id: :web_push_init,
 231         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 232         restart: :temporary
 233       }
 234     ]
 235   end
 236
 237   defp task_children(_) do
 238     [
 239       %{
 240         id: :web_push_init,
 241         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 242         restart: :temporary
 243       },
 244       %{
 245         id: :internal_fetch_init,
 246         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 247         restart: :temporary
 248       }
 249     ]
 250   end
 251
 252   def elasticsearch_children do
 253     config = Config.get([Pleroma.Search, :module])
 254
 255     if config == Pleroma.Search.Elasticsearch do
 256       [Pleroma.Search.Elasticsearch.Cluster]
 257     else
 258       []
 259     end
 260   end
 261
 262   @spec limiters_setup() :: :ok
 263   def limiters_setup do
 264     config = Config.get(ConcurrentLimiter, [])
 265
 266     [
 267       Pleroma.Web.RichMedia.Helpers,
 268       Pleroma.Web.ActivityPub.MRF.MediaProxyWarmingPolicy,
 269       Pleroma.Search
 270     ]
 271     |> Enum.each(fn module ->
 272       mod_config = Keyword.get(config, module, [])
 273
 274       max_running = Keyword.get(mod_config, :max_running, 5)
 275       max_waiting = Keyword.get(mod_config, :max_waiting, 5)
 276
 277       ConcurrentLimiter.new(module, max_running, max_waiting)
 278     end)
 279   end
 280 end