git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   use Application
   7
   8   import Cachex.Spec
   9
  10   alias Pleroma.Config
  11
  12   require Logger
  13
  14   @name Mix.Project.config()[:name]
  15   @version Mix.Project.config()[:version]
  16   @repository Mix.Project.config()[:source_url]
  17   @env Mix.env()
  18
  19   def name, do: @name
  20   def version, do: @version
  21   def named_version, do: @name <> " " <> @version
  22   def repository, do: @repository
  23
  24   def user_agent do
  25     case Config.get([:http, :user_agent], :default) do
  26       :default ->
  27         info = "#{Pleroma.Web.base_url()} <#{Config.get([:instance, :email], "")}>"
  28         named_version() <> "; " <> info
  29
  30       custom ->
  31         custom
  32     end
  33   end
  34
  35   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  36   # for more information on OTP Applications
  37   def start(_type, _args) do
  38     Pleroma.HTML.compile_scrubbers()
  39     Config.DeprecationWarnings.warn()
  40     Pleroma.Plugs.HTTPSecurityPlug.warn_if_disabled()
  41     Pleroma.Repo.check_migrations_applied!()
  42     setup_instrumenters()
  43     load_custom_modules()
  44
  45     if adapter() == Tesla.Adapter.Gun do
  46       Pleroma.OTPVersion.check!()
  47     end
  48
  49     # Define workers and child supervisors to be supervised
  50     children =
  51       [
  52         Pleroma.Repo,
  53         Config.TransferTask,
  54         Pleroma.Emoji,
  55         Pleroma.Captcha,
  56         Pleroma.Plugs.RateLimiter.Supervisor
  57       ] ++
  58         cachex_children() ++
  59         http_pools_children(Config.get(:env)) ++
  60         [
  61           Pleroma.Stats,
  62           Pleroma.JobQueueMonitor,
  63           {Oban, Config.get(Oban)}
  64         ] ++
  65         task_children(@env) ++
  66         streamer_child(@env) ++
  67         chat_child(@env, chat_enabled?()) ++
  68         [
  69           Pleroma.Web.Endpoint,
  70           Pleroma.Gopher.Server
  71         ]
  72
  73     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  74     # for other strategies and supported options
  75     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  76     Supervisor.start_link(children, opts)
  77   end
  78
  79   def load_custom_modules do
  80     dir = Config.get([:modules, :runtime_dir])
  81
  82     if dir && File.exists?(dir) do
  83       dir
  84       |> Pleroma.Utils.compile_dir()
  85       |> case do
  86         {:error, _errors, _warnings} ->
  87           raise "Invalid custom modules"
  88
  89         {:ok, modules, _warnings} ->
  90           if @env != :test do
  91             Enum.each(modules, fn mod ->
  92               Logger.info("Custom module loaded: #{inspect(mod)}")
  93             end)
  94           end
  95
  96           :ok
  97       end
  98     end
  99   end
 100
 101   defp setup_instrumenters do
 102     require Prometheus.Registry
 103
 104     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
 105       :ok =
 106         :telemetry.attach(
 107           "prometheus-ecto",
 108           [:pleroma, :repo, :query],
 109           &Pleroma.Repo.Instrumenter.handle_event/4,
 110           %{}
 111         )
 112
 113       Pleroma.Repo.Instrumenter.setup()
 114     end
 115
 116     Pleroma.Web.Endpoint.MetricsExporter.setup()
 117     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
 118     Pleroma.Web.Endpoint.Instrumenter.setup()
 119   end
 120
 121   defp cachex_children do
 122     [
 123       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 124       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 125       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 126       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 127       build_cachex("scrubber", limit: 2500),
 128       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 129       build_cachex("web_resp", limit: 2500),
 130       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 131       build_cachex("failed_proxy_url", limit: 2500)
 132     ]
 133   end
 134
 135   defp emoji_packs_expiration,
 136     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 137
 138   defp idempotency_expiration,
 139     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 140
 141   defp seconds_valid_interval,
 142     do: :timer.seconds(Config.get!([Pleroma.Captcha, :seconds_valid]))
 143
 144   defp build_cachex(type, opts),
 145     do: %{
 146       id: String.to_atom("cachex_" <> type),
 147       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 148       type: :worker
 149     }
 150
 151   defp chat_enabled?, do: Config.get([:chat, :enabled])
 152
 153   defp streamer_child(:test), do: []
 154
 155   defp streamer_child(_) do
 156     [Pleroma.Web.Streamer.supervisor()]
 157   end
 158
 159   defp chat_child(_env, true) do
 160     [Pleroma.Web.ChatChannel.ChatChannelState]
 161   end
 162
 163   defp chat_child(_, _), do: []
 164
 165   defp task_children(:test) do
 166     [
 167       %{
 168         id: :web_push_init,
 169         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 170         restart: :temporary
 171       }
 172     ]
 173   end
 174
 175   defp task_children(_) do
 176     [
 177       %{
 178         id: :web_push_init,
 179         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 180         restart: :temporary
 181       },
 182       %{
 183         id: :internal_fetch_init,
 184         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 185         restart: :temporary
 186       }
 187     ]
 188   end
 189
 190   # start hackney and gun pools in tests
 191   defp http_pools_children(:test) do
 192     hackney_options = Config.get([:hackney_pools, :federation])
 193     hackney_pool = :hackney_pool.child_spec(:federation, hackney_options)
 194     [hackney_pool, Pleroma.Pool.Supervisor]
 195   end
 196
 197   defp http_pools_children(_), do: http_pools(adapter())
 198
 199   defp http_pools(Tesla.Adapter.Hackney) do
 200     pools = [:federation, :media]
 201
 202     pools =
 203       if Config.get([Pleroma.Upload, :proxy_remote]) do
 204         [:upload | pools]
 205       else
 206         pools
 207       end
 208
 209     for pool <- pools do
 210       options = Config.get([:hackney_pools, pool])
 211       :hackney_pool.child_spec(pool, options)
 212     end
 213   end
 214
 215   defp http_pools(Tesla.Adapter.Gun), do: [Pleroma.Pool.Supervisor]
 216
 217   defp http_pools(_), do: []
 218
 219   defp adapter, do: Application.get_env(:tesla, :adapter)
 220 end