git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   use Application
   7
   8   import Cachex.Spec
   9
  10   alias Pleroma.Config
  11
  12   require Logger
  13
  14   @name Mix.Project.config()[:name]
  15   @version Mix.Project.config()[:version]
  16   @repository Mix.Project.config()[:source_url]
  17   @env Mix.env()
  18
  19   def name, do: @name
  20   def version, do: @version
  21   def named_version, do: @name <> " " <> @version
  22   def repository, do: @repository
  23
  24   def user_agent do
  25     case Config.get([:http, :user_agent], :default) do
  26       :default ->
  27         info = "#{Pleroma.Web.base_url()} <#{Config.get([:instance, :email], "")}>"
  28         named_version() <> "; " <> info
  29
  30       custom ->
  31         custom
  32     end
  33   end
  34
  35   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  36   # for more information on OTP Applications
  37   def start(_type, _args) do
  38     Pleroma.HTML.compile_scrubbers()
  39     Config.DeprecationWarnings.warn()
  40     Pleroma.Plugs.HTTPSecurityPlug.warn_if_disabled()
  41     Pleroma.Repo.check_migrations_applied!()
  42     setup_instrumenters()
  43     load_custom_modules()
  44
  45     if adapter() == Tesla.Adapter.Gun do
  46       if version = Pleroma.OTPVersion.version() do
  47         [major, minor] =
  48           version
  49           |> String.split(".")
  50           |> Enum.map(&String.to_integer/1)
  51           |> Enum.take(2)
  52
  53         if (major == 22 and minor < 2) or major < 22 do
  54           raise "
  55             !!!OTP VERSION WARNING!!!
  56             You are using gun adapter with OTP version #{version}, which doesn't support correct handling of unordered certificates chains.
  57             "
  58         end
  59       else
  60         raise "
  61           !!!OTP VERSION WARNING!!!
  62           To support correct handling of unordered certificates chains - OTP version must be > 22.2.
  63           "
  64       end
  65     end
  66
  67     # Define workers and child supervisors to be supervised
  68     children =
  69       [
  70         Pleroma.Repo,
  71         Config.TransferTask,
  72         Pleroma.Emoji,
  73         Pleroma.Captcha,
  74         Pleroma.Plugs.RateLimiter.Supervisor
  75       ] ++
  76         cachex_children() ++
  77         http_pools_children(Config.get(:env)) ++
  78         [
  79           Pleroma.Stats,
  80           Pleroma.JobQueueMonitor,
  81           {Oban, Config.get(Oban)}
  82         ] ++
  83         task_children(@env) ++
  84         streamer_child(@env) ++
  85         chat_child(@env, chat_enabled?()) ++
  86         [
  87           Pleroma.Web.Endpoint,
  88           Pleroma.Gopher.Server
  89         ]
  90
  91     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  92     # for other strategies and supported options
  93     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  94     Supervisor.start_link(children, opts)
  95   end
  96
  97   def load_custom_modules do
  98     dir = Config.get([:modules, :runtime_dir])
  99
 100     if dir && File.exists?(dir) do
 101       dir
 102       |> Pleroma.Utils.compile_dir()
 103       |> case do
 104         {:error, _errors, _warnings} ->
 105           raise "Invalid custom modules"
 106
 107         {:ok, modules, _warnings} ->
 108           if @env != :test do
 109             Enum.each(modules, fn mod ->
 110               Logger.info("Custom module loaded: #{inspect(mod)}")
 111             end)
 112           end
 113
 114           :ok
 115       end
 116     end
 117   end
 118
 119   defp setup_instrumenters do
 120     require Prometheus.Registry
 121
 122     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
 123       :ok =
 124         :telemetry.attach(
 125           "prometheus-ecto",
 126           [:pleroma, :repo, :query],
 127           &Pleroma.Repo.Instrumenter.handle_event/4,
 128           %{}
 129         )
 130
 131       Pleroma.Repo.Instrumenter.setup()
 132     end
 133
 134     Pleroma.Web.Endpoint.MetricsExporter.setup()
 135     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
 136     Pleroma.Web.Endpoint.Instrumenter.setup()
 137   end
 138
 139   defp cachex_children do
 140     [
 141       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 142       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 143       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 144       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 145       build_cachex("scrubber", limit: 2500),
 146       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 147       build_cachex("web_resp", limit: 2500),
 148       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 149       build_cachex("failed_proxy_url", limit: 2500)
 150     ]
 151   end
 152
 153   defp emoji_packs_expiration,
 154     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 155
 156   defp idempotency_expiration,
 157     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 158
 159   defp seconds_valid_interval,
 160     do: :timer.seconds(Config.get!([Pleroma.Captcha, :seconds_valid]))
 161
 162   defp build_cachex(type, opts),
 163     do: %{
 164       id: String.to_atom("cachex_" <> type),
 165       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 166       type: :worker
 167     }
 168
 169   defp chat_enabled?, do: Config.get([:chat, :enabled])
 170
 171   defp streamer_child(:test), do: []
 172
 173   defp streamer_child(_) do
 174     [Pleroma.Web.Streamer.supervisor()]
 175   end
 176
 177   defp chat_child(_env, true) do
 178     [Pleroma.Web.ChatChannel.ChatChannelState]
 179   end
 180
 181   defp chat_child(_, _), do: []
 182
 183   defp task_children(:test) do
 184     [
 185       %{
 186         id: :web_push_init,
 187         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 188         restart: :temporary
 189       }
 190     ]
 191   end
 192
 193   defp task_children(_) do
 194     [
 195       %{
 196         id: :web_push_init,
 197         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 198         restart: :temporary
 199       },
 200       %{
 201         id: :internal_fetch_init,
 202         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 203         restart: :temporary
 204       }
 205     ]
 206   end
 207
 208   # start hackney and gun pools in tests
 209   defp http_pools_children(:test) do
 210     hackney_options = Config.get([:hackney_pools, :federation])
 211     hackney_pool = :hackney_pool.child_spec(:federation, hackney_options)
 212     [hackney_pool, Pleroma.Pool.Supervisor]
 213   end
 214
 215   defp http_pools_children(_), do: http_pools(adapter())
 216
 217   defp http_pools(Tesla.Adapter.Hackney) do
 218     pools = [:federation, :media]
 219
 220     pools =
 221       if Config.get([Pleroma.Upload, :proxy_remote]) do
 222         [:upload | pools]
 223       else
 224         pools
 225       end
 226
 227     for pool <- pools do
 228       options = Config.get([:hackney_pools, pool])
 229       :hackney_pool.child_spec(pool, options)
 230     end
 231   end
 232
 233   defp http_pools(Tesla.Adapter.Gun), do: [Pleroma.Pool.Supervisor]
 234
 235   defp http_pools(_), do: []
 236
 237   defp adapter, do: Application.get_env(:tesla, :adapter)
 238 end