git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   import Cachex.Spec
   7   use Application
   8
   9   @name Mix.Project.config()[:name]
  10   @version Mix.Project.config()[:version]
  11   @repository Mix.Project.config()[:source_url]
  12   @env Mix.env()
  13
  14   def name, do: @name
  15   def version, do: @version
  16   def named_version, do: @name <> " " <> @version
  17   def repository, do: @repository
  18
  19   def user_agent do
  20     info = "#{Pleroma.Web.base_url()} <#{Pleroma.Config.get([:instance, :email], "")}>"
  21     named_version() <> "; " <> info
  22   end
  23
  24   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  25   # for more information on OTP Applications
  26   def start(_type, _args) do
  27     Pleroma.Config.DeprecationWarnings.warn()
  28     setup_instrumenters()
  29
  30     # Define workers and child supervisors to be supervised
  31     children =
  32       [
  33         Pleroma.Repo,
  34         Pleroma.Config.TransferTask,
  35         Pleroma.Emoji,
  36         Pleroma.Captcha,
  37         Pleroma.ScheduledActivityWorker,
  38         Pleroma.ActivityExpirationWorker
  39       ] ++
  40         cachex_children() ++
  41         hackney_pool_children() ++
  42         [
  43           Pleroma.Web.Federator.RetryQueue,
  44           Pleroma.Stats
  45         ] ++
  46         task_children(@env) ++
  47         oauth_cleanup_child(oauth_cleanup_enabled?()) ++
  48         streamer_child(@env) ++
  49         chat_child(@env, chat_enabled?()) ++
  50         [
  51           Pleroma.Web.Endpoint,
  52           Pleroma.Gopher.Server
  53         ]
  54
  55     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  56     # for other strategies and supported options
  57     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  58     Supervisor.start_link(children, opts)
  59   end
  60
  61   defp setup_instrumenters do
  62     require Prometheus.Registry
  63
  64     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
  65       :ok =
  66         :telemetry.attach(
  67           "prometheus-ecto",
  68           [:pleroma, :repo, :query],
  69           &Pleroma.Repo.Instrumenter.handle_event/4,
  70           %{}
  71         )
  72
  73       Pleroma.Repo.Instrumenter.setup()
  74     end
  75
  76     Pleroma.Web.Endpoint.MetricsExporter.setup()
  77     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
  78     Pleroma.Web.Endpoint.Instrumenter.setup()
  79   end
  80
  81   def enabled_hackney_pools do
  82     [:media] ++
  83       if Application.get_env(:tesla, :adapter) == Tesla.Adapter.Hackney do
  84         [:federation]
  85       else
  86         []
  87       end ++
  88       if Pleroma.Config.get([Pleroma.Upload, :proxy_remote]) do
  89         [:upload]
  90       else
  91         []
  92       end
  93   end
  94
  95   defp cachex_children do
  96     [
  97       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
  98       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
  99       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 100       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 101       build_cachex("scrubber", limit: 2500),
 102       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 103       build_cachex("web_resp", limit: 2500),
 104       build_cachex("failed_proxy_url", limit: 2500)
 105     ]
 106   end
 107
 108   defp idempotency_expiration,
 109     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 110
 111   defp seconds_valid_interval,
 112     do: :timer.seconds(Pleroma.Config.get!([Pleroma.Captcha, :seconds_valid]))
 113
 114   defp build_cachex(type, opts),
 115     do: %{
 116       id: String.to_atom("cachex_" <> type),
 117       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 118       type: :worker
 119     }
 120
 121   defp chat_enabled?, do: Pleroma.Config.get([:chat, :enabled])
 122
 123   defp oauth_cleanup_enabled?,
 124     do: Pleroma.Config.get([:oauth2, :clean_expired_tokens], false)
 125
 126   defp streamer_child(:test), do: []
 127
 128   defp streamer_child(_) do
 129     [Pleroma.Web.Streamer.supervisor()]
 130   end
 131
 132   defp oauth_cleanup_child(true),
 133     do: [Pleroma.Web.OAuth.Token.CleanWorker]
 134
 135   defp oauth_cleanup_child(_), do: []
 136
 137   defp chat_child(:test, _), do: []
 138
 139   defp chat_child(_env, true) do
 140     [Pleroma.Web.ChatChannel.ChatChannelState]
 141   end
 142
 143   defp chat_child(_, _), do: []
 144
 145   defp hackney_pool_children do
 146     for pool <- enabled_hackney_pools() do
 147       options = Pleroma.Config.get([:hackney_pools, pool])
 148       :hackney_pool.child_spec(pool, options)
 149     end
 150   end
 151
 152   defp task_children(:test) do
 153     [
 154       %{
 155         id: :web_push_init,
 156         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 157         restart: :temporary
 158       },
 159       %{
 160         id: :federator_init,
 161         start: {Task, :start_link, [&Pleroma.Web.Federator.init/0]},
 162         restart: :temporary
 163       }
 164     ]
 165   end
 166
 167   defp task_children(_) do
 168     [
 169       %{
 170         id: :web_push_init,
 171         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 172         restart: :temporary
 173       },
 174       %{
 175         id: :federator_init,
 176         start: {Task, :start_link, [&Pleroma.Web.Federator.init/0]},
 177         restart: :temporary
 178       },
 179       %{
 180         id: :internal_fetch_init,
 181         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 182         restart: :temporary
 183       }
 184     ]
 185   end
 186 end