git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   import Cachex.Spec
   7   use Application
   8
   9   @name Mix.Project.config()[:name]
  10   @version Mix.Project.config()[:version]
  11   @repository Mix.Project.config()[:source_url]
  12   @env Mix.env()
  13
  14   def name, do: @name
  15   def version, do: @version
  16   def named_version, do: @name <> " " <> @version
  17   def repository, do: @repository
  18
  19   def user_agent do
  20     case Pleroma.Config.get([:http, :user_agent], :default) do
  21       :default ->
  22         info = "#{Pleroma.Web.base_url()} <#{Pleroma.Config.get([:instance, :email], "")}>"
  23         named_version() <> "; " <> info
  24
  25       custom ->
  26         custom
  27     end
  28   end
  29
  30   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  31   # for more information on OTP Applications
  32   def start(_type, _args) do
  33     Pleroma.HTML.compile_scrubbers()
  34     Pleroma.Config.DeprecationWarnings.warn()
  35     setup_instrumenters()
  36
  37     # Define workers and child supervisors to be supervised
  38     children =
  39       [
  40         Pleroma.Repo,
  41         Pleroma.Config.TransferTask,
  42         Pleroma.Emoji,
  43         Pleroma.Captcha,
  44         Pleroma.Plugs.RateLimiter.Supervisor
  45       ] ++
  46         cachex_children() ++
  47         hackney_pool_children() ++
  48         [
  49           Pleroma.Stats,
  50           Pleroma.JobQueueMonitor,
  51           {Oban, Pleroma.Config.get(Oban)}
  52         ] ++
  53         task_children(@env) ++
  54         streamer_child(@env) ++
  55         chat_child(@env, chat_enabled?()) ++
  56         [
  57           Pleroma.Web.Endpoint,
  58           Pleroma.Gopher.Server
  59         ]
  60
  61     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  62     # for other strategies and supported options
  63     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  64     Supervisor.start_link(children, opts)
  65   end
  66
  67   defp setup_instrumenters do
  68     require Prometheus.Registry
  69
  70     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
  71       :ok =
  72         :telemetry.attach(
  73           "prometheus-ecto",
  74           [:pleroma, :repo, :query],
  75           &Pleroma.Repo.Instrumenter.handle_event/4,
  76           %{}
  77         )
  78
  79       Pleroma.Repo.Instrumenter.setup()
  80     end
  81
  82     Pleroma.Web.Endpoint.MetricsExporter.setup()
  83     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
  84     Pleroma.Web.Endpoint.Instrumenter.setup()
  85   end
  86
  87   def enabled_hackney_pools do
  88     [:media] ++
  89       if Application.get_env(:tesla, :adapter) == Tesla.Adapter.Hackney do
  90         [:federation]
  91       else
  92         []
  93       end ++
  94       if Pleroma.Config.get([Pleroma.Upload, :proxy_remote]) do
  95         [:upload]
  96       else
  97         []
  98       end
  99   end
 100
 101   defp cachex_children do
 102     [
 103       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 104       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 105       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 106       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 107       build_cachex("scrubber", limit: 2500),
 108       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 109       build_cachex("web_resp", limit: 2500),
 110       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 111       build_cachex("failed_proxy_url", limit: 2500)
 112     ]
 113   end
 114
 115   defp emoji_packs_expiration,
 116     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 117
 118   defp idempotency_expiration,
 119     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 120
 121   defp seconds_valid_interval,
 122     do: :timer.seconds(Pleroma.Config.get!([Pleroma.Captcha, :seconds_valid]))
 123
 124   defp build_cachex(type, opts),
 125     do: %{
 126       id: String.to_atom("cachex_" <> type),
 127       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 128       type: :worker
 129     }
 130
 131   defp chat_enabled?, do: Pleroma.Config.get([:chat, :enabled])
 132
 133   defp streamer_child(:test), do: []
 134
 135   defp streamer_child(_) do
 136     [Pleroma.Web.Streamer.supervisor()]
 137   end
 138
 139   defp chat_child(_env, true) do
 140     [Pleroma.Web.ChatChannel.ChatChannelState]
 141   end
 142
 143   defp chat_child(_, _), do: []
 144
 145   defp hackney_pool_children do
 146     for pool <- enabled_hackney_pools() do
 147       options = Pleroma.Config.get([:hackney_pools, pool])
 148       :hackney_pool.child_spec(pool, options)
 149     end
 150   end
 151
 152   defp task_children(:test) do
 153     [
 154       %{
 155         id: :web_push_init,
 156         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 157         restart: :temporary
 158       }
 159     ]
 160   end
 161
 162   defp task_children(_) do
 163     [
 164       %{
 165         id: :web_push_init,
 166         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 167         restart: :temporary
 168       },
 169       %{
 170         id: :internal_fetch_init,
 171         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 172         restart: :temporary
 173       }
 174     ]
 175   end
 176 end