git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   use Application
   7
   8   import Cachex.Spec
   9
  10   alias Pleroma.Config
  11
  12   require Logger
  13
  14   @name Mix.Project.config()[:name]
  15   @version Mix.Project.config()[:version]
  16   @repository Mix.Project.config()[:source_url]
  17   @env Mix.env()
  18
  19   def name, do: @name
  20   def version, do: @version
  21   def named_version, do: @name <> " " <> @version
  22   def repository, do: @repository
  23
  24   def user_agent do
  25     case Config.get([:http, :user_agent], :default) do
  26       :default ->
  27         info = "#{Pleroma.Web.base_url()} <#{Config.get([:instance, :email], "")}>"
  28         named_version() <> "; " <> info
  29
  30       custom ->
  31         custom
  32     end
  33   end
  34
  35   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  36   # for more information on OTP Applications
  37   def start(_type, _args) do
  38     Pleroma.HTML.compile_scrubbers()
  39     Config.DeprecationWarnings.warn()
  40     Pleroma.Plugs.HTTPSecurityPlug.warn_if_disabled()
  41     Pleroma.Repo.check_migrations_applied!()
  42     setup_instrumenters()
  43     load_custom_modules()
  44
  45     # Define workers and child supervisors to be supervised
  46     children =
  47       [
  48         Pleroma.Repo,
  49         Config.TransferTask,
  50         Pleroma.Emoji,
  51         Pleroma.Captcha,
  52         Pleroma.Plugs.RateLimiter.Supervisor
  53       ] ++
  54         cachex_children() ++
  55         http_pools_children(Config.get(:env)) ++
  56         [
  57           Pleroma.Stats,
  58           Pleroma.JobQueueMonitor,
  59           {Oban, Config.get(Oban)}
  60         ] ++
  61         task_children(@env) ++
  62         streamer_child(@env) ++
  63         chat_child(@env, chat_enabled?()) ++
  64         [
  65           Pleroma.Web.Endpoint,
  66           Pleroma.Gopher.Server
  67         ]
  68
  69     if adapter() == Tesla.Adapter.Gun do
  70       case Pleroma.OTPVersion.check() do
  71         :ok ->
  72           :ok
  73
  74         {:error, version} ->
  75           raise "
  76             !!!OTP VERSION WARNING!!!
  77             You are using gun adapter with OTP version #{version}, which doesn't support correct handling of unordered certificates chains.
  78             "
  79
  80         :undefined ->
  81           raise "
  82             !!!OTP VERSION WARNING!!!
  83             To support correct handling of unordered certificates chains - OTP version must be > 22.2.
  84             "
  85       end
  86     end
  87
  88     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  89     # for other strategies and supported options
  90     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  91     Supervisor.start_link(children, opts)
  92   end
  93
  94   def load_custom_modules do
  95     dir = Config.get([:modules, :runtime_dir])
  96
  97     if dir && File.exists?(dir) do
  98       dir
  99       |> Pleroma.Utils.compile_dir()
 100       |> case do
 101         {:error, _errors, _warnings} ->
 102           raise "Invalid custom modules"
 103
 104         {:ok, modules, _warnings} ->
 105           if @env != :test do
 106             Enum.each(modules, fn mod ->
 107               Logger.info("Custom module loaded: #{inspect(mod)}")
 108             end)
 109           end
 110
 111           :ok
 112       end
 113     end
 114   end
 115
 116   defp setup_instrumenters do
 117     require Prometheus.Registry
 118
 119     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
 120       :ok =
 121         :telemetry.attach(
 122           "prometheus-ecto",
 123           [:pleroma, :repo, :query],
 124           &Pleroma.Repo.Instrumenter.handle_event/4,
 125           %{}
 126         )
 127
 128       Pleroma.Repo.Instrumenter.setup()
 129     end
 130
 131     Pleroma.Web.Endpoint.MetricsExporter.setup()
 132     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
 133     Pleroma.Web.Endpoint.Instrumenter.setup()
 134   end
 135
 136   defp cachex_children do
 137     [
 138       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 139       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 140       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 141       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 142       build_cachex("scrubber", limit: 2500),
 143       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 144       build_cachex("web_resp", limit: 2500),
 145       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 146       build_cachex("failed_proxy_url", limit: 2500)
 147     ]
 148   end
 149
 150   defp emoji_packs_expiration,
 151     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 152
 153   defp idempotency_expiration,
 154     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 155
 156   defp seconds_valid_interval,
 157     do: :timer.seconds(Config.get!([Pleroma.Captcha, :seconds_valid]))
 158
 159   defp build_cachex(type, opts),
 160     do: %{
 161       id: String.to_atom("cachex_" <> type),
 162       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 163       type: :worker
 164     }
 165
 166   defp chat_enabled?, do: Config.get([:chat, :enabled])
 167
 168   defp streamer_child(:test), do: []
 169
 170   defp streamer_child(_) do
 171     [Pleroma.Web.Streamer.supervisor()]
 172   end
 173
 174   defp chat_child(_env, true) do
 175     [Pleroma.Web.ChatChannel.ChatChannelState]
 176   end
 177
 178   defp chat_child(_, _), do: []
 179
 180   defp task_children(:test) do
 181     [
 182       %{
 183         id: :web_push_init,
 184         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 185         restart: :temporary
 186       }
 187     ]
 188   end
 189
 190   defp task_children(_) do
 191     [
 192       %{
 193         id: :web_push_init,
 194         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 195         restart: :temporary
 196       },
 197       %{
 198         id: :internal_fetch_init,
 199         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 200         restart: :temporary
 201       }
 202     ]
 203   end
 204
 205   # start hackney and gun pools in tests
 206   defp http_pools_children(:test) do
 207     hackney_options = Config.get([:hackney_pools, :federation])
 208     hackney_pool = :hackney_pool.child_spec(:federation, hackney_options)
 209     [hackney_pool, Pleroma.Pool.Supervisor]
 210   end
 211
 212   defp http_pools_children(_), do: http_pools(adapter())
 213
 214   defp http_pools(Tesla.Adapter.Hackney) do
 215     pools = [:federation, :media]
 216
 217     pools =
 218       if Config.get([Pleroma.Upload, :proxy_remote]) do
 219         [:upload | pools]
 220       else
 221         pools
 222       end
 223
 224     for pool <- pools do
 225       options = Config.get([:hackney_pools, pool])
 226       :hackney_pool.child_spec(pool, options)
 227     end
 228   end
 229
 230   defp http_pools(Tesla.Adapter.Gun), do: [Pleroma.Pool.Supervisor]
 231
 232   defp http_pools(_), do: []
 233
 234   defp adapter, do: Application.get_env(:tesla, :adapter)
 235 end