git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   import Cachex.Spec
   7   use Application
   8
   9   @name Mix.Project.config()[:name]
  10   @version Mix.Project.config()[:version]
  11   @repository Mix.Project.config()[:source_url]
  12   @env Mix.env()
  13
  14   def name, do: @name
  15   def version, do: @version
  16   def named_version, do: @name <> " " <> @version
  17   def repository, do: @repository
  18
  19   def user_agent do
  20     info = "#{Pleroma.Web.base_url()} <#{Pleroma.Config.get([:instance, :email], "")}>"
  21     named_version() <> "; " <> info
  22   end
  23
  24   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  25   # for more information on OTP Applications
  26   def start(_type, _args) do
  27     Pleroma.Config.DeprecationWarnings.warn()
  28     setup_instrumenters()
  29
  30     # Define workers and child supervisors to be supervised
  31     children =
  32       [
  33         Pleroma.Repo,
  34         Pleroma.Config.TransferTask,
  35         Pleroma.Emoji,
  36         Pleroma.Captcha,
  37         Pleroma.FlakeId,
  38         Pleroma.ScheduledActivityWorker,
  39         Pleroma.ActivityExpirationWorker
  40       ] ++
  41         cachex_children() ++
  42         hackney_pool_children() ++
  43         [
  44           Pleroma.Web.Federator.RetryQueue,
  45           Pleroma.Stats
  46         ] ++
  47         task_children(@env) ++
  48         oauth_cleanup_child(oauth_cleanup_enabled?()) ++
  49         streamer_child(@env) ++
  50         chat_child(@env, chat_enabled?()) ++
  51         [
  52           Pleroma.Web.Endpoint,
  53           Pleroma.Gopher.Server
  54         ]
  55
  56     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  57     # for other strategies and supported options
  58     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  59     result = Supervisor.start_link(children, opts)
  60     :ok = after_supervisor_start()
  61     result
  62   end
  63
  64   defp setup_instrumenters do
  65     require Prometheus.Registry
  66
  67     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
  68       :ok =
  69         :telemetry.attach(
  70           "prometheus-ecto",
  71           [:pleroma, :repo, :query],
  72           &Pleroma.Repo.Instrumenter.handle_event/4,
  73           %{}
  74         )
  75
  76       Pleroma.Repo.Instrumenter.setup()
  77     end
  78
  79     Pleroma.Web.Endpoint.MetricsExporter.setup()
  80     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
  81     Pleroma.Web.Endpoint.Instrumenter.setup()
  82   end
  83
  84   def enabled_hackney_pools do
  85     [:media] ++
  86       if Application.get_env(:tesla, :adapter) == Tesla.Adapter.Hackney do
  87         [:federation]
  88       else
  89         []
  90       end ++
  91       if Pleroma.Config.get([Pleroma.Upload, :proxy_remote]) do
  92         [:upload]
  93       else
  94         []
  95       end
  96   end
  97
  98   defp cachex_children do
  99     [
 100       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 101       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 102       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 103       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 104       build_cachex("scrubber", limit: 2500),
 105       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 106       build_cachex("web_resp", limit: 2500)
 107     ]
 108   end
 109
 110   defp idempotency_expiration,
 111     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 112
 113   defp seconds_valid_interval,
 114     do: :timer.seconds(Pleroma.Config.get!([Pleroma.Captcha, :seconds_valid]))
 115
 116   defp build_cachex(type, opts),
 117     do: %{
 118       id: String.to_atom("cachex_" <> type),
 119       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 120       type: :worker
 121     }
 122
 123   defp chat_enabled?, do: Pleroma.Config.get([:chat, :enabled])
 124
 125   defp oauth_cleanup_enabled?,
 126     do: Pleroma.Config.get([:oauth2, :clean_expired_tokens], false)
 127
 128   defp streamer_child(:test), do: []
 129
 130   defp streamer_child(_) do
 131     [Pleroma.Web.Streamer.supervisor()]
 132   end
 133
 134   defp oauth_cleanup_child(true),
 135     do: [Pleroma.Web.OAuth.Token.CleanWorker]
 136
 137   defp oauth_cleanup_child(_), do: []
 138
 139   defp chat_child(:test, _), do: []
 140
 141   defp chat_child(_env, true) do
 142     [Pleroma.Web.ChatChannel.ChatChannelState]
 143   end
 144
 145   defp chat_child(_, _), do: []
 146
 147   defp hackney_pool_children do
 148     for pool <- enabled_hackney_pools() do
 149       options = Pleroma.Config.get([:hackney_pools, pool])
 150       :hackney_pool.child_spec(pool, options)
 151     end
 152   end
 153
 154   defp task_children(:test) do
 155     [
 156       %{
 157         id: :web_push_init,
 158         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 159         restart: :temporary
 160       },
 161       %{
 162         id: :federator_init,
 163         start: {Task, :start_link, [&Pleroma.Web.Federator.init/0]},
 164         restart: :temporary
 165       }
 166     ]
 167   end
 168
 169   defp task_children(_) do
 170     [
 171       %{
 172         id: :web_push_init,
 173         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 174         restart: :temporary
 175       },
 176       %{
 177         id: :federator_init,
 178         start: {Task, :start_link, [&Pleroma.Web.Federator.init/0]},
 179         restart: :temporary
 180       },
 181       %{
 182         id: :internal_fetch_init,
 183         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 184         restart: :temporary
 185       }
 186     ]
 187   end
 188 end