git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   import Cachex.Spec
   7   use Application
   8
   9   @name Mix.Project.config()[:name]
  10   @version Mix.Project.config()[:version]
  11   @repository Mix.Project.config()[:source_url]
  12   @env Mix.env()
  13
  14   def name, do: @name
  15   def version, do: @version
  16   def named_version, do: @name <> " " <> @version
  17   def repository, do: @repository
  18
  19   def user_agent do
  20     info = "#{Pleroma.Web.base_url()} <#{Pleroma.Config.get([:instance, :email], "")}>"
  21     named_version() <> "; " <> info
  22   end
  23
  24   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  25   # for more information on OTP Applications
  26   def start(_type, _args) do
  27     Pleroma.Config.DeprecationWarnings.warn()
  28     setup_instrumenters()
  29
  30     # Define workers and child supervisors to be supervised
  31     children =
  32       [
  33         Pleroma.Repo,
  34         Pleroma.Scheduler,
  35         Pleroma.Config.TransferTask,
  36         Pleroma.Emoji,
  37         Pleroma.Captcha,
  38         Pleroma.Plugs.RateLimiter.Supervisor
  39       ] ++
  40         cachex_children() ++
  41         hackney_pool_children() ++
  42         [
  43           Pleroma.Stats,
  44           Pleroma.JobQueueMonitor,
  45           {Oban, Pleroma.Config.get(Oban)}
  46         ] ++
  47         task_children(@env) ++
  48         streamer_child(@env) ++
  49         chat_child(@env, chat_enabled?()) ++
  50         [
  51           Pleroma.Web.Endpoint,
  52           Pleroma.Gopher.Server
  53         ]
  54
  55     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
  56     # for other strategies and supported options
  57     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
  58     Supervisor.start_link(children, opts)
  59   end
  60
  61   defp setup_instrumenters do
  62     require Prometheus.Registry
  63
  64     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
  65       :ok =
  66         :telemetry.attach(
  67           "prometheus-ecto",
  68           [:pleroma, :repo, :query],
  69           &Pleroma.Repo.Instrumenter.handle_event/4,
  70           %{}
  71         )
  72
  73       Pleroma.Repo.Instrumenter.setup()
  74     end
  75
  76     Pleroma.Web.Endpoint.MetricsExporter.setup()
  77     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
  78     Pleroma.Web.Endpoint.Instrumenter.setup()
  79   end
  80
  81   def enabled_hackney_pools do
  82     [:media] ++
  83       if Application.get_env(:tesla, :adapter) == Tesla.Adapter.Hackney do
  84         [:federation]
  85       else
  86         []
  87       end ++
  88       if Pleroma.Config.get([Pleroma.Upload, :proxy_remote]) do
  89         [:upload]
  90       else
  91         []
  92       end
  93   end
  94
  95   defp cachex_children do
  96     [
  97       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
  98       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
  99       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 100       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 101       build_cachex("scrubber", limit: 2500),
 102       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 103       build_cachex("web_resp", limit: 2500),
 104       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 105       build_cachex("failed_proxy_url", limit: 2500)
 106     ]
 107   end
 108
 109   defp emoji_packs_expiration,
 110     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 111
 112   defp idempotency_expiration,
 113     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 114
 115   defp seconds_valid_interval,
 116     do: :timer.seconds(Pleroma.Config.get!([Pleroma.Captcha, :seconds_valid]))
 117
 118   defp build_cachex(type, opts),
 119     do: %{
 120       id: String.to_atom("cachex_" <> type),
 121       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 122       type: :worker
 123     }
 124
 125   defp chat_enabled?, do: Pleroma.Config.get([:chat, :enabled])
 126
 127   defp streamer_child(:test), do: []
 128
 129   defp streamer_child(_) do
 130     [Pleroma.Web.Streamer.supervisor()]
 131   end
 132
 133   defp chat_child(:test, _), do: []
 134
 135   defp chat_child(_env, true) do
 136     [Pleroma.Web.ChatChannel.ChatChannelState]
 137   end
 138
 139   defp chat_child(_, _), do: []
 140
 141   defp hackney_pool_children do
 142     for pool <- enabled_hackney_pools() do
 143       options = Pleroma.Config.get([:hackney_pools, pool])
 144       :hackney_pool.child_spec(pool, options)
 145     end
 146   end
 147
 148   defp task_children(:test) do
 149     [
 150       %{
 151         id: :web_push_init,
 152         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 153         restart: :temporary
 154       }
 155     ]
 156   end
 157
 158   defp task_children(_) do
 159     [
 160       %{
 161         id: :web_push_init,
 162         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 163         restart: :temporary
 164       },
 165       %{
 166         id: :internal_fetch_init,
 167         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 168         restart: :temporary
 169       }
 170     ]
 171   end
 172 end