git.squeep.com Git - akkoma/blob - lib/pleroma/application.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Application do
   6   use Application
   7
   8   import Cachex.Spec
   9
  10   alias Pleroma.Config
  11
  12   require Logger
  13
  14   @name Mix.Project.config()[:name]
  15   @version Mix.Project.config()[:version]
  16   @repository Mix.Project.config()[:source_url]
  17   @env Mix.env()
  18
  19   def name, do: @name
  20   def version, do: @version
  21   def named_version, do: @name <> " " <> @version
  22   def repository, do: @repository
  23
  24   def user_agent do
  25     case Config.get([:http, :user_agent], :default) do
  26       :default ->
  27         info = "#{Pleroma.Web.base_url()} <#{Config.get([:instance, :email], "")}>"
  28         named_version() <> "; " <> info
  29
  30       custom ->
  31         custom
  32     end
  33   end
  34
  35   # See http://elixir-lang.org/docs/stable/elixir/Application.html
  36   # for more information on OTP Applications
  37   def start(_type, _args) do
  38     # Scrubbers are compiled at runtime and therefore will cause a conflict
  39     # every time the application is restarted, so we disable module
  40     # conflicts at runtime
  41     Code.compiler_options(ignore_module_conflict: true)
  42     # Disable warnings_as_errors at runtime, it breaks Phoenix live reload
  43     # due to protocol consolidation warnings
  44     Code.compiler_options(warnings_as_errors: false)
  45     Pleroma.Telemetry.Logger.attach()
  46     Config.Holder.save_default()
  47     Pleroma.HTML.compile_scrubbers()
  48     Config.DeprecationWarnings.warn()
  49     Pleroma.Plugs.HTTPSecurityPlug.warn_if_disabled()
  50     Pleroma.ApplicationRequirements.verify!()
  51     setup_instrumenters()
  52     load_custom_modules()
  53     check_system_commands()
  54     Pleroma.Docs.JSON.compile()
  55
  56     adapter = Application.get_env(:tesla, :adapter)
  57
  58     if adapter == Tesla.Adapter.Gun do
  59       if version = Pleroma.OTPVersion.version() do
  60         [major, minor] =
  61           version
  62           |> String.split(".")
  63           |> Enum.map(&String.to_integer/1)
  64           |> Enum.take(2)
  65
  66         if (major == 22 and minor < 2) or major < 22 do
  67           raise "
  68             !!!OTP VERSION WARNING!!!
  69             You are using gun adapter with OTP version #{version}, which doesn't support correct handling of unordered certificates chains. Please update your Erlang/OTP to at least 22.2.
  70             "
  71         end
  72       else
  73         raise "
  74           !!!OTP VERSION WARNING!!!
  75           To support correct handling of unordered certificates chains - OTP version must be > 22.2.
  76           "
  77       end
  78     end
  79
  80     # Define workers and child supervisors to be supervised
  81     children =
  82       [
  83         Pleroma.Repo,
  84         Config.TransferTask,
  85         Pleroma.Emoji,
  86         Pleroma.Plugs.RateLimiter.Supervisor
  87       ] ++
  88         cachex_children() ++
  89         http_children(adapter, @env) ++
  90         [
  91           Pleroma.Stats,
  92           Pleroma.JobQueueMonitor,
  93           {Oban, Config.get(Oban)}
  94         ] ++
  95         task_children(@env) ++
  96         streamer_child(@env) ++
  97         chat_child(@env, chat_enabled?()) ++
  98         [
  99           Pleroma.Web.Endpoint,
 100           Pleroma.Gopher.Server
 101         ]
 102
 103     # See http://elixir-lang.org/docs/stable/elixir/Supervisor.html
 104     # for other strategies and supported options
 105     opts = [strategy: :one_for_one, name: Pleroma.Supervisor]
 106     Supervisor.start_link(children, opts)
 107   end
 108
 109   def load_custom_modules do
 110     dir = Config.get([:modules, :runtime_dir])
 111
 112     if dir && File.exists?(dir) do
 113       dir
 114       |> Pleroma.Utils.compile_dir()
 115       |> case do
 116         {:error, _errors, _warnings} ->
 117           raise "Invalid custom modules"
 118
 119         {:ok, modules, _warnings} ->
 120           if @env != :test do
 121             Enum.each(modules, fn mod ->
 122               Logger.info("Custom module loaded: #{inspect(mod)}")
 123             end)
 124           end
 125
 126           :ok
 127       end
 128     end
 129   end
 130
 131   defp setup_instrumenters do
 132     require Prometheus.Registry
 133
 134     if Application.get_env(:prometheus, Pleroma.Repo.Instrumenter) do
 135       :ok =
 136         :telemetry.attach(
 137           "prometheus-ecto",
 138           [:pleroma, :repo, :query],
 139           &Pleroma.Repo.Instrumenter.handle_event/4,
 140           %{}
 141         )
 142
 143       Pleroma.Repo.Instrumenter.setup()
 144     end
 145
 146     Pleroma.Web.Endpoint.MetricsExporter.setup()
 147     Pleroma.Web.Endpoint.PipelineInstrumenter.setup()
 148     Pleroma.Web.Endpoint.Instrumenter.setup()
 149   end
 150
 151   defp cachex_children do
 152     [
 153       build_cachex("used_captcha", ttl_interval: seconds_valid_interval()),
 154       build_cachex("user", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 155       build_cachex("object", default_ttl: 25_000, ttl_interval: 1000, limit: 2500),
 156       build_cachex("rich_media", default_ttl: :timer.minutes(120), limit: 5000),
 157       build_cachex("scrubber", limit: 2500),
 158       build_cachex("idempotency", expiration: idempotency_expiration(), limit: 2500),
 159       build_cachex("web_resp", limit: 2500),
 160       build_cachex("emoji_packs", expiration: emoji_packs_expiration(), limit: 10),
 161       build_cachex("failed_proxy_url", limit: 2500),
 162       build_cachex("banned_urls", default_ttl: :timer.hours(24 * 30), limit: 5_000)
 163     ]
 164   end
 165
 166   defp emoji_packs_expiration,
 167     do: expiration(default: :timer.seconds(5 * 60), interval: :timer.seconds(60))
 168
 169   defp idempotency_expiration,
 170     do: expiration(default: :timer.seconds(6 * 60 * 60), interval: :timer.seconds(60))
 171
 172   defp seconds_valid_interval,
 173     do: :timer.seconds(Config.get!([Pleroma.Captcha, :seconds_valid]))
 174
 175   @spec build_cachex(String.t(), keyword()) :: map()
 176   def build_cachex(type, opts),
 177     do: %{
 178       id: String.to_atom("cachex_" <> type),
 179       start: {Cachex, :start_link, [String.to_atom(type <> "_cache"), opts]},
 180       type: :worker
 181     }
 182
 183   defp chat_enabled?, do: Config.get([:chat, :enabled])
 184
 185   defp streamer_child(env) when env in [:test, :benchmark], do: []
 186
 187   defp streamer_child(_) do
 188     [
 189       {Registry,
 190        [
 191          name: Pleroma.Web.Streamer.registry(),
 192          keys: :duplicate,
 193          partitions: System.schedulers_online()
 194        ]}
 195     ]
 196   end
 197
 198   defp chat_child(_env, true) do
 199     [Pleroma.Web.ChatChannel.ChatChannelState]
 200   end
 201
 202   defp chat_child(_, _), do: []
 203
 204   defp task_children(:test) do
 205     [
 206       %{
 207         id: :web_push_init,
 208         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 209         restart: :temporary
 210       }
 211     ]
 212   end
 213
 214   defp task_children(_) do
 215     [
 216       %{
 217         id: :web_push_init,
 218         start: {Task, :start_link, [&Pleroma.Web.Push.init/0]},
 219         restart: :temporary
 220       },
 221       %{
 222         id: :internal_fetch_init,
 223         start: {Task, :start_link, [&Pleroma.Web.ActivityPub.InternalFetchActor.init/0]},
 224         restart: :temporary
 225       }
 226     ]
 227   end
 228
 229   # start hackney and gun pools in tests
 230   defp http_children(_, :test) do
 231     http_children(Tesla.Adapter.Hackney, nil) ++ http_children(Tesla.Adapter.Gun, nil)
 232   end
 233
 234   defp http_children(Tesla.Adapter.Hackney, _) do
 235     pools = [:federation, :media]
 236
 237     pools =
 238       if Config.get([Pleroma.Upload, :proxy_remote]) do
 239         [:upload | pools]
 240       else
 241         pools
 242       end
 243
 244     for pool <- pools do
 245       options = Config.get([:hackney_pools, pool])
 246       :hackney_pool.child_spec(pool, options)
 247     end
 248   end
 249
 250   defp http_children(Tesla.Adapter.Gun, _) do
 251     Pleroma.Gun.ConnectionPool.children() ++
 252       [{Task, &Pleroma.HTTP.AdapterHelper.Gun.limiter_setup/0}]
 253   end
 254
 255   defp http_children(_, _), do: []
 256
 257   defp check_system_commands do
 258     filters = Config.get([Pleroma.Upload, :filters])
 259
 260     check_filter = fn filter, command_required ->
 261       with true <- filter in filters,
 262            false <- Pleroma.Utils.command_available?(command_required) do
 263         Logger.error(
 264           "#{filter} is specified in list of Pleroma.Upload filters, but the #{command_required} command is not found"
 265         )
 266       end
 267     end
 268
 269     check_filter.(Pleroma.Upload.Filters.Exiftool, "exiftool")
 270     check_filter.(Pleroma.Upload.Filters.Mogrify, "mogrify")
 271     check_filter.(Pleroma.Upload.Filters.Mogrifun, "mogrify")
 272   end
 273 end