git.squeep.com Git - akkoma/blob - lib/pleroma/activity.ex

   1 defmodule Pleroma.Activity do
   2   use Ecto.Schema
   3   alias Pleroma.{Repo, Activity, Notification, Object}
   4   import Ecto.{Query, Changeset}
   5
   6   schema "activities" do
   7     field(:data, :map)
   8     field(:local, :boolean, default: true)
   9     field(:actor, :string)
  10     field(:recipients, {:array, :string})
  11     has_many(:notifications, Notification, on_delete: :delete_all)
  12
  13     timestamps()
  14   end
  15
  16   def get_by_ap_id(ap_id) do
  17     Repo.one(
  18       from(
  19         activity in Activity,
  20         where: fragment("(?)->>'id' = ?", activity.data, ^to_string(ap_id))
  21       )
  22     )
  23   end
  24
  25   def change(struct, params \\ %{}) do
  26     struct
  27     |> cast(params, [:data])
  28     |> validate_required([:data])
  29     |> unique_constraint(:ap_id, name: :activities_unique_apid_index)
  30   end
  31
  32   # TODO:
  33   # Go through these and fix them everywhere.
  34   # Wrong name, only returns create activities
  35   def all_by_object_ap_id_q(ap_id) do
  36     from(
  37       activity in Activity,
  38       where:
  39         fragment(
  40           "coalesce((?)->'object'->>'id', (?)->>'object') = ?",
  41           activity.data,
  42           activity.data,
  43           ^to_string(ap_id)
  44         ),
  45       where: fragment("(?)->>'type' = 'Create'", activity.data)
  46     )
  47   end
  48
  49   # Wrong name, returns all.
  50   def all_non_create_by_object_ap_id_q(ap_id) do
  51     from(
  52       activity in Activity,
  53       where:
  54         fragment(
  55           "coalesce((?)->'object'->>'id', (?)->>'object') = ?",
  56           activity.data,
  57           activity.data,
  58           ^to_string(ap_id)
  59         )
  60     )
  61   end
  62
  63   # Wrong name plz fix thx
  64   def all_by_object_ap_id(ap_id) do
  65     Repo.all(all_by_object_ap_id_q(ap_id))
  66   end
  67
  68   def create_activity_by_object_id_query(ap_ids) do
  69     from(
  70       activity in Activity,
  71       where:
  72         fragment(
  73           "coalesce((?)->'object'->>'id', (?)->>'object') = ANY(?)",
  74           activity.data,
  75           activity.data,
  76           ^ap_ids
  77         ),
  78       where: fragment("(?)->>'type' = 'Create'", activity.data)
  79     )
  80   end
  81
  82   def get_create_activity_by_object_ap_id(ap_id) when is_binary(ap_id) do
  83     create_activity_by_object_id_query([ap_id])
  84     |> Repo.one()
  85   end
  86
  87   def get_create_activity_by_object_ap_id(_), do: nil
  88
  89   def normalize(obj) when is_map(obj), do: normalize(obj["id"])
  90   def normalize(ap_id) when is_binary(ap_id), do: get_by_ap_id(ap_id)
  91   def normalize(_), do: nil
  92
  93   defp get_in_reply_to_activity_from_object(%Object{data: %{"inReplyTo" => ap_id}}) do
  94     get_create_activity_by_object_ap_id(ap_id)
  95   end
  96
  97   defp get_in_reply_to_activity_from_object(_), do: nil
  98
  99   def get_in_reply_to_activity(%Activity{data: %{"object" => object}}) do
 100     get_in_reply_to_activity_from_object(Object.normalize(object))
 101   end
 102 end