git.squeep.com Git - akkoma/blob - lib/pleroma/activity/queries.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Activity.Queries do
   6   @moduledoc """
   7   Contains queries for Activity.
   8   """
   9
  10   import Ecto.Query, only: [from: 2, where: 3]
  11
  12   @type query :: Ecto.Queryable.t() | Activity.t()
  13
  14   alias Pleroma.Activity
  15   alias Pleroma.User
  16
  17   @spec by_ap_id(query, String.t()) :: query
  18   def by_ap_id(query \\ Activity, ap_id) do
  19     from(
  20       activity in query,
  21       where: fragment("(?)->>'id' = ?", activity.data, ^to_string(ap_id))
  22     )
  23   end
  24
  25   @spec by_actor(query, String.t()) :: query
  26   def by_actor(query \\ Activity, actor) do
  27     from(
  28       activity in query,
  29       where: fragment("(?)->>'actor' = ?", activity.data, ^actor)
  30     )
  31   end
  32
  33   @spec by_author(query, User.t()) :: query
  34   def by_author(query \\ Activity, %User{ap_id: ap_id}) do
  35     from(a in query, where: a.actor == ^ap_id)
  36   end
  37
  38   def find_by_object_ap_id(activities, object_ap_id) do
  39     Enum.find(
  40       activities,
  41       &(object_ap_id in [is_map(&1.data["object"]) && &1.data["object"]["id"], &1.data["object"]])
  42     )
  43   end
  44
  45   @spec by_object_id(query, String.t() | [String.t()]) :: query
  46   def by_object_id(query \\ Activity, object_id)
  47
  48   def by_object_id(query, object_ids) when is_list(object_ids) do
  49     from(
  50       activity in query,
  51       where:
  52         fragment(
  53           "coalesce((?)->'object'->>'id', (?)->>'object') = ANY(?)",
  54           activity.data,
  55           activity.data,
  56           ^object_ids
  57         )
  58     )
  59   end
  60
  61   def by_object_id(query, object_id) when is_binary(object_id) do
  62     from(activity in query,
  63       where:
  64         fragment(
  65           "coalesce((?)->'object'->>'id', (?)->>'object') = ?",
  66           activity.data,
  67           activity.data,
  68           ^object_id
  69         )
  70     )
  71   end
  72
  73   @spec by_object_in_reply_to_id(query, String.t(), keyword()) :: query
  74   def by_object_in_reply_to_id(query, in_reply_to_id, opts \\ []) do
  75     query =
  76       if opts[:skip_preloading] do
  77         Activity.with_joined_object(query)
  78       else
  79         Activity.with_preloaded_object(query)
  80       end
  81
  82     where(
  83       query,
  84       [activity, object: o],
  85       fragment("(?)->>'inReplyTo' = ?", o.data, ^to_string(in_reply_to_id))
  86     )
  87   end
  88
  89   @spec by_type(query, String.t()) :: query
  90   def by_type(query \\ Activity, activity_type) do
  91     from(
  92       activity in query,
  93       where: fragment("(?)->>'type' = ?", activity.data, ^activity_type)
  94     )
  95   end
  96
  97   @spec exclude_type(query, String.t()) :: query
  98   def exclude_type(query \\ Activity, activity_type) do
  99     from(
 100       activity in query,
 101       where: fragment("(?)->>'type' != ?", activity.data, ^activity_type)
 102     )
 103   end
 104
 105   def exclude_authors(query \\ Activity, actors) do
 106     from(activity in query, where: activity.actor not in ^actors)
 107   end
 108 end