git.squeep.com Git - akkoma/blob - lib/pleroma/activity/queries.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Activity.Queries do
   6   @moduledoc """
   7   Contains queries for Activity.
   8   """
   9
  10   import Ecto.Query, only: [from: 2, where: 3]
  11
  12   @type query :: Ecto.Queryable.t() | Activity.t()
  13
  14   alias Pleroma.Activity
  15   alias Pleroma.User
  16
  17   @spec by_ap_id(query, String.t()) :: query
  18   def by_ap_id(query \\ Activity, ap_id) do
  19     from(
  20       activity in query,
  21       where: fragment("(?)->>'id' = ?", activity.data, ^to_string(ap_id))
  22     )
  23   end
  24
  25   @spec by_actor(query, String.t()) :: query
  26   def by_actor(query \\ Activity, actor) do
  27     from(a in query, where: a.actor == ^actor)
  28   end
  29
  30   @spec by_author(query, User.t()) :: query
  31   def by_author(query \\ Activity, %User{ap_id: ap_id}) do
  32     from(a in query, where: a.actor == ^ap_id)
  33   end
  34
  35   @spec by_object_id(query, String.t() | [String.t()]) :: query
  36   def by_object_id(query \\ Activity, object_id)
  37
  38   def by_object_id(query, object_ids) when is_list(object_ids) do
  39     from(
  40       activity in query,
  41       where:
  42         fragment(
  43           "coalesce((?)->'object'->>'id', (?)->>'object') = ANY(?)",
  44           activity.data,
  45           activity.data,
  46           ^object_ids
  47         )
  48     )
  49   end
  50
  51   def by_object_id(query, object_id) when is_binary(object_id) do
  52     from(activity in query,
  53       where:
  54         fragment(
  55           "coalesce((?)->'object'->>'id', (?)->>'object') = ?",
  56           activity.data,
  57           activity.data,
  58           ^object_id
  59         )
  60     )
  61   end
  62
  63   @spec by_object_in_reply_to_id(query, String.t(), keyword()) :: query
  64   def by_object_in_reply_to_id(query, in_reply_to_id, opts \\ []) do
  65     query =
  66       if opts[:skip_preloading] do
  67         Activity.with_joined_object(query)
  68       else
  69         Activity.with_preloaded_object(query)
  70       end
  71
  72     where(
  73       query,
  74       [activity, object: o],
  75       fragment("(?)->>'inReplyTo' = ?", o.data, ^to_string(in_reply_to_id))
  76     )
  77   end
  78
  79   @spec by_type(query, String.t()) :: query
  80   def by_type(query \\ Activity, activity_type) do
  81     from(
  82       activity in query,
  83       where: fragment("(?)->>'type' = ?", activity.data, ^activity_type)
  84     )
  85   end
  86
  87   @spec exclude_type(query, String.t()) :: query
  88   def exclude_type(query \\ Activity, activity_type) do
  89     from(
  90       activity in query,
  91       where: fragment("(?)->>'type' != ?", activity.data, ^activity_type)
  92     )
  93   end
  94
  95   def exclude_authors(query \\ Activity, actors) do
  96     from(activity in query, where: activity.actor not in ^actors)
  97   end
  98 end