git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Mix.Tasks.Pleroma.User do
   6   use Mix.Task
   7   import Mix.Pleroma
   8   alias Pleroma.User
   9   alias Pleroma.UserInviteToken
  10   alias Pleroma.Web.OAuth
  11
  12   @shortdoc "Manages Pleroma users"
  13   @moduledoc """
  14   Manages Pleroma users.
  15
  16   ## Create a new user.
  17
  18       mix pleroma.user new NICKNAME EMAIL [OPTION...]
  19
  20   Options:
  21   - `--name NAME` - the user's name (i.e., "Lain Iwakura")
  22   - `--bio BIO` - the user's bio
  23   - `--password PASSWORD` - the user's password
  24   - `--moderator`/`--no-moderator` - whether the user is a moderator
  25   - `--admin`/`--no-admin` - whether the user is an admin
  26   - `-y`, `--assume-yes`/`--no-assume-yes` - whether to assume yes to all questions
  27
  28   ## Generate an invite link.
  29
  30       mix pleroma.user invite [OPTION...]
  31
  32     Options:
  33     - `--expires-at DATE` - last day on which token is active (e.g. "2019-04-05")
  34     - `--max-use NUMBER` - maximum numbers of token uses
  35
  36   ## List generated invites
  37
  38       mix pleroma.user invites
  39
  40   ## Revoke invite
  41
  42       mix pleroma.user revoke_invite TOKEN OR TOKEN_ID
  43
  44   ## Delete the user's account.
  45
  46       mix pleroma.user rm NICKNAME
  47
  48   ## Delete the user's activities.
  49
  50       mix pleroma.user delete_activities NICKNAME
  51
  52   ## Sign user out from all applications (delete user's OAuth tokens and authorizations).
  53
  54       mix pleroma.user sign_out NICKNAME
  55
  56   ## Deactivate or activate the user's account.
  57
  58       mix pleroma.user toggle_activated NICKNAME
  59
  60   ## Unsubscribe local users from user's account and deactivate it
  61
  62       mix pleroma.user unsubscribe NICKNAME
  63
  64   ## Unsubscribe local users from an entire instance and deactivate all accounts
  65
  66       mix pleroma.user unsubscribe_all_from_instance INSTANCE
  67
  68   ## Create a password reset link.
  69
  70       mix pleroma.user reset_password NICKNAME
  71
  72   ## Set the value of the given user's settings.
  73
  74       mix pleroma.user set NICKNAME [OPTION...]
  75
  76   Options:
  77   - `--locked`/`--no-locked` - whether the user's account is locked
  78   - `--moderator`/`--no-moderator` - whether the user is a moderator
  79   - `--admin`/`--no-admin` - whether the user is an admin
  80
  81   ## Add tags to a user.
  82
  83       mix pleroma.user tag NICKNAME TAGS
  84
  85   ## Delete tags from a user.
  86
  87       mix pleroma.user untag NICKNAME TAGS
  88
  89   ## Toggle confirmation of the user's account.
  90
  91       mix pleroma.user toggle_confirmed NICKNAME
  92   """
  93   def run(["new", nickname, email | rest]) do
  94     {options, [], []} =
  95       OptionParser.parse(
  96         rest,
  97         strict: [
  98           name: :string,
  99           bio: :string,
 100           password: :string,
 101           moderator: :boolean,
 102           admin: :boolean,
 103           assume_yes: :boolean
 104         ],
 105         aliases: [
 106           y: :assume_yes
 107         ]
 108       )
 109
 110     name = Keyword.get(options, :name, nickname)
 111     bio = Keyword.get(options, :bio, "")
 112
 113     {password, generated_password?} =
 114       case Keyword.get(options, :password) do
 115         nil ->
 116           {:crypto.strong_rand_bytes(16) |> Base.encode64(), true}
 117
 118         password ->
 119           {password, false}
 120       end
 121
 122     moderator? = Keyword.get(options, :moderator, false)
 123     admin? = Keyword.get(options, :admin, false)
 124     assume_yes? = Keyword.get(options, :assume_yes, false)
 125
 126     shell_info("""
 127     A user will be created with the following information:
 128       - nickname: #{nickname}
 129       - email: #{email}
 130       - password: #{
 131       if(generated_password?, do: "[generated; a reset link will be created]", else: password)
 132     }
 133       - name: #{name}
 134       - bio: #{bio}
 135       - moderator: #{if(moderator?, do: "true", else: "false")}
 136       - admin: #{if(admin?, do: "true", else: "false")}
 137     """)
 138
 139     proceed? = assume_yes? or shell_yes?("Continue?")
 140
 141     if proceed? do
 142       start_pleroma()
 143
 144       params = %{
 145         nickname: nickname,
 146         email: email,
 147         password: password,
 148         password_confirmation: password,
 149         name: name,
 150         bio: bio
 151       }
 152
 153       changeset = User.register_changeset(%User{}, params, need_confirmation: false)
 154       {:ok, _user} = User.register(changeset)
 155
 156       shell_info("User #{nickname} created")
 157
 158       if moderator? do
 159         run(["set", nickname, "--moderator"])
 160       end
 161
 162       if admin? do
 163         run(["set", nickname, "--admin"])
 164       end
 165
 166       if generated_password? do
 167         run(["reset_password", nickname])
 168       end
 169     else
 170       shell_info("User will not be created.")
 171     end
 172   end
 173
 174   def run(["rm", nickname]) do
 175     start_pleroma()
 176
 177     with %User{local: true} = user <- User.get_cached_by_nickname(nickname) do
 178       User.perform(:delete, user)
 179       shell_info("User #{nickname} deleted.")
 180     else
 181       _ ->
 182         shell_error("No local user #{nickname}")
 183     end
 184   end
 185
 186   def run(["toggle_activated", nickname]) do
 187     start_pleroma()
 188
 189     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 190       {:ok, user} = User.deactivate(user, !user.info.deactivated)
 191
 192       shell_info(
 193         "Activation status of #{nickname}: #{if(user.info.deactivated, do: "de", else: "")}activated"
 194       )
 195     else
 196       _ ->
 197         shell_error("No user #{nickname}")
 198     end
 199   end
 200
 201   def run(["reset_password", nickname]) do
 202     start_pleroma()
 203
 204     with %User{local: true} = user <- User.get_cached_by_nickname(nickname),
 205          {:ok, token} <- Pleroma.PasswordResetToken.create_token(user) do
 206       shell_info("Generated password reset token for #{user.nickname}")
 207
 208       IO.puts(
 209         "URL: #{
 210           Pleroma.Web.Router.Helpers.reset_password_url(
 211             Pleroma.Web.Endpoint,
 212             :reset,
 213             token.token
 214           )
 215         }"
 216       )
 217     else
 218       _ ->
 219         shell_error("No local user #{nickname}")
 220     end
 221   end
 222
 223   def run(["unsubscribe", nickname]) do
 224     start_pleroma()
 225
 226     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 227       shell_info("Deactivating #{user.nickname}")
 228       User.deactivate(user)
 229
 230       user
 231       |> User.get_friends()
 232       |> Enum.each(fn friend ->
 233         user = User.get_cached_by_id(user.id)
 234
 235         shell_info("Unsubscribing #{friend.nickname} from #{user.nickname}")
 236         User.unfollow(user, friend)
 237       end)
 238
 239       :timer.sleep(500)
 240
 241       user = User.get_cached_by_id(user.id)
 242
 243       if Enum.empty?(user.following) do
 244         shell_info("Successfully unsubscribed all followers from #{user.nickname}")
 245       end
 246     else
 247       _ ->
 248         shell_error("No user #{nickname}")
 249     end
 250   end
 251
 252   def run(["unsubscribe_all_from_instance", instance]) do
 253     start_pleroma()
 254
 255     Pleroma.User.Query.build(%{nickname: "@#{instance}"})
 256     |> Pleroma.RepoStreamer.chunk_stream(500)
 257     |> Stream.each(fn users ->
 258       users
 259       |> Enum.each(fn user ->
 260         run(["unsubscribe", user.nickname])
 261       end)
 262     end)
 263     |> Stream.run()
 264   end
 265
 266   def run(["set", nickname | rest]) do
 267     start_pleroma()
 268
 269     {options, [], []} =
 270       OptionParser.parse(
 271         rest,
 272         strict: [
 273           moderator: :boolean,
 274           admin: :boolean,
 275           locked: :boolean
 276         ]
 277       )
 278
 279     with %User{local: true} = user <- User.get_cached_by_nickname(nickname) do
 280       user =
 281         case Keyword.get(options, :moderator) do
 282           nil -> user
 283           value -> set_moderator(user, value)
 284         end
 285
 286       user =
 287         case Keyword.get(options, :locked) do
 288           nil -> user
 289           value -> set_locked(user, value)
 290         end
 291
 292       _user =
 293         case Keyword.get(options, :admin) do
 294           nil -> user
 295           value -> set_admin(user, value)
 296         end
 297     else
 298       _ ->
 299         shell_error("No local user #{nickname}")
 300     end
 301   end
 302
 303   def run(["tag", nickname | tags]) do
 304     start_pleroma()
 305
 306     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 307       user = user |> User.tag(tags)
 308
 309       shell_info("Tags of #{user.nickname}: #{inspect(tags)}")
 310     else
 311       _ ->
 312         shell_error("Could not change user tags for #{nickname}")
 313     end
 314   end
 315
 316   def run(["untag", nickname | tags]) do
 317     start_pleroma()
 318
 319     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 320       user = user |> User.untag(tags)
 321
 322       shell_info("Tags of #{user.nickname}: #{inspect(tags)}")
 323     else
 324       _ ->
 325         shell_error("Could not change user tags for #{nickname}")
 326     end
 327   end
 328
 329   def run(["invite" | rest]) do
 330     {options, [], []} =
 331       OptionParser.parse(rest,
 332         strict: [
 333           expires_at: :string,
 334           max_use: :integer
 335         ]
 336       )
 337
 338     options =
 339       options
 340       |> Keyword.update(:expires_at, {:ok, nil}, fn
 341         nil -> {:ok, nil}
 342         val -> Date.from_iso8601(val)
 343       end)
 344       |> Enum.into(%{})
 345
 346     start_pleroma()
 347
 348     with {:ok, val} <- options[:expires_at],
 349          options = Map.put(options, :expires_at, val),
 350          {:ok, invite} <- UserInviteToken.create_invite(options) do
 351       shell_info("Generated user invite token " <> String.replace(invite.invite_type, "_", " "))
 352
 353       url =
 354         Pleroma.Web.Router.Helpers.redirect_url(
 355           Pleroma.Web.Endpoint,
 356           :registration_page,
 357           invite.token
 358         )
 359
 360       IO.puts(url)
 361     else
 362       error ->
 363         shell_error("Could not create invite token: #{inspect(error)}")
 364     end
 365   end
 366
 367   def run(["invites"]) do
 368     start_pleroma()
 369
 370     shell_info("Invites list:")
 371
 372     UserInviteToken.list_invites()
 373     |> Enum.each(fn invite ->
 374       expire_info =
 375         with expires_at when not is_nil(expires_at) <- invite.expires_at do
 376           " | Expires at: #{Date.to_string(expires_at)}"
 377         end
 378
 379       using_info =
 380         with max_use when not is_nil(max_use) <- invite.max_use do
 381           " | Max use: #{max_use}    Left use: #{max_use - invite.uses}"
 382         end
 383
 384       shell_info(
 385         "ID: #{invite.id} | Token: #{invite.token} | Token type: #{invite.invite_type} | Used: #{
 386           invite.used
 387         }#{expire_info}#{using_info}"
 388       )
 389     end)
 390   end
 391
 392   def run(["revoke_invite", token]) do
 393     start_pleroma()
 394
 395     with {:ok, invite} <- UserInviteToken.find_by_token(token),
 396          {:ok, _} <- UserInviteToken.update_invite(invite, %{used: true}) do
 397       shell_info("Invite for token #{token} was revoked.")
 398     else
 399       _ -> shell_error("No invite found with token #{token}")
 400     end
 401   end
 402
 403   def run(["delete_activities", nickname]) do
 404     start_pleroma()
 405
 406     with %User{local: true} = user <- User.get_cached_by_nickname(nickname) do
 407       User.delete_user_activities(user)
 408       shell_info("User #{nickname} statuses deleted.")
 409     else
 410       _ ->
 411         shell_error("No local user #{nickname}")
 412     end
 413   end
 414
 415   def run(["toggle_confirmed", nickname]) do
 416     start_pleroma()
 417
 418     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 419       {:ok, user} = User.toggle_confirmation(user)
 420
 421       message = if user.info.confirmation_pending, do: "needs", else: "doesn't need"
 422
 423       shell_info("#{nickname} #{message} confirmation.")
 424     else
 425       _ ->
 426         shell_error("No local user #{nickname}")
 427     end
 428   end
 429
 430   def run(["sign_out", nickname]) do
 431     start_pleroma()
 432
 433     with %User{local: true} = user <- User.get_cached_by_nickname(nickname) do
 434       OAuth.Token.delete_user_tokens(user)
 435       OAuth.Authorization.delete_user_authorizations(user)
 436
 437       shell_info("#{nickname} signed out from all apps.")
 438     else
 439       _ ->
 440         shell_error("No local user #{nickname}")
 441     end
 442   end
 443
 444   defp set_moderator(user, value) do
 445     {:ok, user} = User.update_info(user, &User.Info.admin_api_update(&1, %{is_moderator: value}))
 446
 447     shell_info("Moderator status of #{user.nickname}: #{user.info.is_moderator}")
 448     user
 449   end
 450
 451   defp set_admin(user, value) do
 452     {:ok, user} = User.update_info(user, &User.Info.admin_api_update(&1, %{is_admin: value}))
 453
 454     shell_info("Admin status of #{user.nickname}: #{user.info.is_admin}")
 455     user
 456   end
 457
 458   defp set_locked(user, value) do
 459     {:ok, user} = User.update_info(user, &User.Info.user_upgrade(&1, %{locked: value}))
 460
 461     shell_info("Locked status of #{user.nickname}: #{user.info.locked}")
 462     user
 463   end
 464 end