git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/user.ex

   1 defmodule Mix.Tasks.Pleroma.User do
   2   use Mix.Task
   3   alias Pleroma.{Repo, User}
   4
   5   @shortdoc "Manages Pleroma users"
   6   @moduledoc """
   7   Manages Pleroma users.
   8
   9   ## Create a new user.
  10
  11       mix pleroma.user new NICKNAME EMAIL [OPTION...]
  12
  13   Options:
  14   - `--name NAME` - the user's name (i.e., "Lain Iwakura")
  15   - `--bio BIO` - the user's bio
  16   - `--password PASSWORD` - the user's password
  17   - `--moderator`/`--no-moderator` - whether the user is a moderator
  18   - `--admin`/`--no-admin` - whether the user is an admin
  19
  20   ## Generate an invite link.
  21
  22      mix pleroma.user invite
  23
  24   ## Delete the user's account.
  25
  26       mix pleroma.user rm NICKNAME
  27
  28   ## Deactivate or activate the user's account.
  29
  30       mix pleroma.user toggle_activated NICKNAME
  31
  32   ## Create a password reset link.
  33
  34       mix pleroma.user reset_password NICKNAME
  35
  36   ## Set the value of the given user's settings.
  37
  38       mix pleroma.user set NICKNAME [OPTION...]
  39
  40   Options:
  41   - `--locked`/`--no-locked` - whether the user's account is locked
  42   - `--moderator`/`--no-moderator` - whether the user is a moderator
  43   - `--admin`/`--no-admin` - whether the user is an admin
  44   """
  45
  46   def run(["new", nickname, email | rest]) do
  47     {options, [], []} =
  48       OptionParser.parse(
  49         rest,
  50         strict: [
  51           name: :string,
  52           bio: :string,
  53           password: :string,
  54           moderator: :boolean,
  55           admin: :boolean
  56         ]
  57       )
  58
  59     name = Keyword.get(options, :name, nickname)
  60     bio = Keyword.get(options, :bio, "")
  61
  62     {password, generated_password?} =
  63       case Keyword.get(options, :password) do
  64         nil ->
  65           {:crypto.strong_rand_bytes(16) |> Base.encode64(), true}
  66
  67         password ->
  68           {password, false}
  69       end
  70
  71     moderator? = Keyword.get(options, :moderator, false)
  72     admin? = Keyword.get(options, :admin, false)
  73
  74     Mix.shell().info("""
  75     A user will be created with the following information:
  76       - nickname: #{nickname}
  77       - email: #{email}
  78       - password: #{
  79       if(generated_password?, do: "[generated; a reset link will be created]", else: password)
  80     }
  81       - name: #{name}
  82       - bio: #{bio}
  83       - moderator: #{if(moderator?, do: "true", else: "false")}
  84       - admin: #{if(admin?, do: "true", else: "false")}
  85     """)
  86
  87     proceed? = Mix.shell().yes?("Continue?")
  88
  89     unless not proceed? do
  90       Mix.Task.run("app.start")
  91
  92       params =
  93         %{
  94           nickname: nickname,
  95           email: email,
  96           password: password,
  97           password_confirmation: password,
  98           name: name,
  99           bio: bio
 100         }
 101         |> IO.inspect()
 102
 103       user = User.register_changeset(%User{}, params)
 104       Repo.insert!(user)
 105
 106       Mix.shell().info("User #{nickname} created")
 107
 108       if moderator? do
 109         run(["set", nickname, "--moderator"])
 110       end
 111
 112       if admin? do
 113         run(["set", nickname, "--admin"])
 114       end
 115
 116       if generated_password? do
 117         run(["reset_password", nickname])
 118       end
 119     else
 120       Mix.shell().info("User will not be created.")
 121     end
 122   end
 123
 124   def run(["rm", nickname]) do
 125     Mix.Task.run("app.start")
 126
 127     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 128       User.delete(user)
 129       Mix.shell().info("User #{nickname} deleted.")
 130     else
 131       _ ->
 132         Mix.shell().error("No local user #{nickname}")
 133     end
 134   end
 135
 136   def run(["toggle_activated", nickname]) do
 137     Mix.Task.run("app.start")
 138
 139     with %User{} = user <- User.get_by_nickname(nickname) do
 140       User.deactivate(user, !user.info["deactivated"])
 141       Mix.shell().info("Activation status of #{nickname}: #{user.info["deactivated"]}")
 142     else
 143       _ ->
 144         Mix.shell().error("No user #{nickname}")
 145     end
 146   end
 147
 148   def run(["reset_password", nickname]) do
 149     Mix.Task.run("app.start")
 150
 151     with %User{local: true} = user <- User.get_by_nickname(nickname),
 152          {:ok, token} <- Pleroma.PasswordResetToken.create_token(user) do
 153       Mix.shell().info("Generated password reset token for #{user.nickname}")
 154
 155       IO.puts(
 156         "URL: #{
 157           Pleroma.Web.Router.Helpers.util_url(
 158             Pleroma.Web.Endpoint,
 159             :show_password_reset,
 160             token.token
 161           )
 162         }"
 163       )
 164     else
 165       _ ->
 166         Mix.shell().error("No local user #{nickname}")
 167     end
 168   end
 169
 170   def run(["unsubscribe", nickname]) do
 171     Mix.Task.run("app.start")
 172
 173     with %User{} = user <- User.get_by_nickname(nickname) do
 174       Mix.shell().info("Deactivating #{user.nickname}")
 175       User.deactivate(user)
 176
 177       {:ok, friends} = User.get_friends(user)
 178
 179       Enum.each(friends, fn friend ->
 180         user = Repo.get(User, user.id)
 181
 182         Mix.shell().info("Unsubscribing #{friend.nickname} from #{user.nickname}")
 183         User.unfollow(user, friend)
 184       end)
 185
 186       :timer.sleep(500)
 187
 188       user = Repo.get(User, user.id)
 189
 190       if length(user.following) == 0 do
 191         Mix.shell().info("Successfully unsubscribed all followers from #{user.nickname}")
 192       end
 193     else
 194       _ ->
 195         Mix.shell().error("No user #{nickname}")
 196     end
 197   end
 198
 199   def run(["set", nickname | rest]) do
 200     Application.ensure_all_started(:pleroma)
 201
 202     {options, [], []} =
 203       OptionParser.parse(
 204         rest,
 205         strict: [
 206           moderator: :boolean,
 207           admin: :boolean,
 208           locked: :boolean
 209         ]
 210       )
 211
 212     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 213       case Keyword.get(options, :moderator) do
 214         nil -> nil
 215         value -> set_moderator(user, value)
 216       end
 217
 218       case Keyword.get(options, :locked) do
 219         nil -> nil
 220         value -> set_locked(user, value)
 221       end
 222
 223       case Keyword.get(options, :admin) do
 224         nil -> nil
 225         value -> set_admin(user, value)
 226       end
 227     else
 228       _ ->
 229         Mix.shell().error("No local user #{nickname}")
 230     end
 231   end
 232
 233   defp set_moderator(user, value) do
 234     info =
 235       user.info
 236       |> Map.put("is_moderator", value)
 237
 238     cng = User.info_changeset(user, %{info: info})
 239     {:ok, user} = User.update_and_set_cache(cng)
 240
 241     Mix.shell().info("Moderator status of #{user.nickname}: #{user.info["is_moderator"]}")
 242   end
 243
 244   defp set_admin(user, value) do
 245     info =
 246       user.info
 247       |> Map.put("is_admin", value)
 248
 249     cng = User.info_changeset(user, %{info: info})
 250     {:ok, user} = User.update_and_set_cache(cng)
 251
 252     Mix.shell().info("Admin status of #{user.nickname}: #{user.info["is_admin"]}")
 253   end
 254
 255   defp set_locked(user, value) do
 256     info =
 257       user.info
 258       |> Map.put("locked", value)
 259
 260     cng = User.info_changeset(user, %{info: info})
 261     user = Repo.update!(cng)
 262
 263     IO.puts("Locked status of #{user.nickname}: #{user.info["locked"]}")
 264   end
 265
 266   def run(["invite"]) do
 267     Mix.Task.run("app.start")
 268
 269     with {:ok, token} <- Pleroma.UserInviteToken.create_token() do
 270       Mix.shell().info("Generated user invite token")
 271
 272       url =
 273         Pleroma.Web.Router.Helpers.redirect_url(
 274           Pleroma.Web.Endpoint,
 275           :registration_page,
 276           token.token
 277         )
 278
 279       IO.puts(url)
 280     else
 281       _ ->
 282         Mix.shell().error("Could not create invite token.")
 283     end
 284   end
 285 end