git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Mix.Tasks.Pleroma.User do
   6   use Mix.Task
   7   import Ecto.Changeset
   8   alias Mix.Tasks.Pleroma.Common
   9   alias Pleroma.User
  10   alias Pleroma.UserInviteToken
  11
  12   @shortdoc "Manages Pleroma users"
  13   @moduledoc """
  14   Manages Pleroma users.
  15
  16   ## Create a new user.
  17
  18       mix pleroma.user new NICKNAME EMAIL [OPTION...]
  19
  20   Options:
  21   - `--name NAME` - the user's name (i.e., "Lain Iwakura")
  22   - `--bio BIO` - the user's bio
  23   - `--password PASSWORD` - the user's password
  24   - `--moderator`/`--no-moderator` - whether the user is a moderator
  25   - `--admin`/`--no-admin` - whether the user is an admin
  26   - `-y`, `--assume-yes`/`--no-assume-yes` - whether to assume yes to all questions
  27
  28   ## Generate an invite link.
  29
  30       mix pleroma.user invite [OPTION...]
  31
  32     Options:
  33     - `--expires_at DATE` - last day on which token is active (e.g. "2019-04-05")
  34     - `--max_use NUMBER` - maximum numbers of token uses
  35
  36   ## List generated invites
  37
  38       mix pleroma.user invites
  39
  40   ## Revoke invite
  41
  42       mix pleroma.user revoke_invite TOKEN OR TOKEN_ID
  43
  44   ## Delete the user's account.
  45
  46       mix pleroma.user rm NICKNAME
  47
  48   ## Delete the user's activities.
  49
  50       mix pleroma.user delete_activities NICKNAME
  51
  52   ## Deactivate or activate the user's account.
  53
  54       mix pleroma.user toggle_activated NICKNAME
  55
  56   ## Disable or enable the user's account.
  57
  58       mix pleroma.user toggle_disabled NICKNAME
  59
  60   ## Unsubscribe local users from user's account and deactivate it
  61
  62       mix pleroma.user unsubscribe NICKNAME
  63
  64   ## Create a password reset link.
  65
  66       mix pleroma.user reset_password NICKNAME
  67
  68   ## Set the value of the given user's settings.
  69
  70       mix pleroma.user set NICKNAME [OPTION...]
  71
  72   Options:
  73   - `--locked`/`--no-locked` - whether the user's account is locked
  74   - `--moderator`/`--no-moderator` - whether the user is a moderator
  75   - `--admin`/`--no-admin` - whether the user is an admin
  76
  77   ## Add tags to a user.
  78
  79       mix pleroma.user tag NICKNAME TAGS
  80
  81   ## Delete tags from a user.
  82
  83       mix pleroma.user untag NICKNAME TAGS
  84   """
  85   def run(["new", nickname, email | rest]) do
  86     {options, [], []} =
  87       OptionParser.parse(
  88         rest,
  89         strict: [
  90           name: :string,
  91           bio: :string,
  92           password: :string,
  93           moderator: :boolean,
  94           admin: :boolean,
  95           assume_yes: :boolean
  96         ],
  97         aliases: [
  98           y: :assume_yes
  99         ]
 100       )
 101
 102     name = Keyword.get(options, :name, nickname)
 103     bio = Keyword.get(options, :bio, "")
 104
 105     {password, generated_password?} =
 106       case Keyword.get(options, :password) do
 107         nil ->
 108           {:crypto.strong_rand_bytes(16) |> Base.encode64(), true}
 109
 110         password ->
 111           {password, false}
 112       end
 113
 114     moderator? = Keyword.get(options, :moderator, false)
 115     admin? = Keyword.get(options, :admin, false)
 116     assume_yes? = Keyword.get(options, :assume_yes, false)
 117
 118     Mix.shell().info("""
 119     A user will be created with the following information:
 120       - nickname: #{nickname}
 121       - email: #{email}
 122       - password: #{
 123       if(generated_password?, do: "[generated; a reset link will be created]", else: password)
 124     }
 125       - name: #{name}
 126       - bio: #{bio}
 127       - moderator: #{if(moderator?, do: "true", else: "false")}
 128       - admin: #{if(admin?, do: "true", else: "false")}
 129     """)
 130
 131     proceed? = assume_yes? or Mix.shell().yes?("Continue?")
 132
 133     unless not proceed? do
 134       Common.start_pleroma()
 135
 136       params = %{
 137         nickname: nickname,
 138         email: email,
 139         password: password,
 140         password_confirmation: password,
 141         name: name,
 142         bio: bio
 143       }
 144
 145       changeset = User.register_changeset(%User{}, params, confirmed: true)
 146       {:ok, _user} = User.register(changeset)
 147
 148       Mix.shell().info("User #{nickname} created")
 149
 150       if moderator? do
 151         run(["set", nickname, "--moderator"])
 152       end
 153
 154       if admin? do
 155         run(["set", nickname, "--admin"])
 156       end
 157
 158       if generated_password? do
 159         run(["reset_password", nickname])
 160       end
 161     else
 162       Mix.shell().info("User will not be created.")
 163     end
 164   end
 165
 166   def run(["rm", nickname]) do
 167     Common.start_pleroma()
 168
 169     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 170       User.delete(user)
 171       Mix.shell().info("User #{nickname} deleted.")
 172     else
 173       _ ->
 174         Mix.shell().error("No local user #{nickname}")
 175     end
 176   end
 177
 178   def run(["toggle_activated", nickname]) do
 179     Common.start_pleroma()
 180
 181     with %User{} = user <- User.get_by_nickname(nickname) do
 182       {:ok, user} = User.deactivate(user, !user.info.deactivated)
 183
 184       Mix.shell().info(
 185         "Activation status of #{nickname}: #{if(user.info.deactivated, do: "de", else: "")}activated"
 186       )
 187     else
 188       _ ->
 189         Mix.shell().error("No user #{nickname}")
 190     end
 191   end
 192
 193   def run(["toggle_disabled", nickname]) do
 194     Common.start_pleroma()
 195
 196     case User.get_by_nickname(nickname) do
 197       %User{} = user ->
 198         {:ok, user} = User.disable(user, !user.info.disabled)
 199         status = if(user.info.disabled, do: "ON", else: "OFF")
 200         Mix.shell().info("Disabled status of #{nickname}: #{status}")
 201
 202       _ ->
 203         Mix.shell().error("No user #{nickname}")
 204     end
 205   end
 206
 207   def run(["reset_password", nickname]) do
 208     Common.start_pleroma()
 209
 210     with %User{local: true} = user <- User.get_by_nickname(nickname),
 211          {:ok, token} <- Pleroma.PasswordResetToken.create_token(user) do
 212       Mix.shell().info("Generated password reset token for #{user.nickname}")
 213
 214       IO.puts(
 215         "URL: #{
 216           Pleroma.Web.Router.Helpers.util_url(
 217             Pleroma.Web.Endpoint,
 218             :show_password_reset,
 219             token.token
 220           )
 221         }"
 222       )
 223     else
 224       _ ->
 225         Mix.shell().error("No local user #{nickname}")
 226     end
 227   end
 228
 229   def run(["unsubscribe", nickname]) do
 230     Common.start_pleroma()
 231
 232     with %User{} = user <- User.get_by_nickname(nickname) do
 233       Mix.shell().info("Deactivating #{user.nickname}")
 234       User.deactivate(user)
 235
 236       {:ok, friends} = User.get_friends(user)
 237
 238       Enum.each(friends, fn friend ->
 239         user = User.get_by_id(user.id)
 240
 241         Mix.shell().info("Unsubscribing #{friend.nickname} from #{user.nickname}")
 242         User.unfollow(user, friend)
 243       end)
 244
 245       :timer.sleep(500)
 246
 247       user = User.get_by_id(user.id)
 248
 249       if Enum.empty?(user.following) do
 250         Mix.shell().info("Successfully unsubscribed all followers from #{user.nickname}")
 251       end
 252     else
 253       _ ->
 254         Mix.shell().error("No user #{nickname}")
 255     end
 256   end
 257
 258   def run(["set", nickname | rest]) do
 259     Common.start_pleroma()
 260
 261     {options, [], []} =
 262       OptionParser.parse(
 263         rest,
 264         strict: [
 265           moderator: :boolean,
 266           admin: :boolean,
 267           locked: :boolean
 268         ]
 269       )
 270
 271     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 272       user =
 273         case Keyword.get(options, :moderator) do
 274           nil -> user
 275           value -> set_moderator(user, value)
 276         end
 277
 278       user =
 279         case Keyword.get(options, :locked) do
 280           nil -> user
 281           value -> set_locked(user, value)
 282         end
 283
 284       _user =
 285         case Keyword.get(options, :admin) do
 286           nil -> user
 287           value -> set_admin(user, value)
 288         end
 289     else
 290       _ ->
 291         Mix.shell().error("No local user #{nickname}")
 292     end
 293   end
 294
 295   def run(["tag", nickname | tags]) do
 296     Common.start_pleroma()
 297
 298     with %User{} = user <- User.get_by_nickname(nickname) do
 299       user = user |> User.tag(tags)
 300
 301       Mix.shell().info("Tags of #{user.nickname}: #{inspect(tags)}")
 302     else
 303       _ ->
 304         Mix.shell().error("Could not change user tags for #{nickname}")
 305     end
 306   end
 307
 308   def run(["untag", nickname | tags]) do
 309     Common.start_pleroma()
 310
 311     with %User{} = user <- User.get_by_nickname(nickname) do
 312       user = user |> User.untag(tags)
 313
 314       Mix.shell().info("Tags of #{user.nickname}: #{inspect(tags)}")
 315     else
 316       _ ->
 317         Mix.shell().error("Could not change user tags for #{nickname}")
 318     end
 319   end
 320
 321   def run(["invite" | rest]) do
 322     {options, [], []} =
 323       OptionParser.parse(rest,
 324         strict: [
 325           expires_at: :string,
 326           max_use: :integer
 327         ]
 328       )
 329
 330     options =
 331       options
 332       |> Keyword.update(:expires_at, {:ok, nil}, fn
 333         nil -> {:ok, nil}
 334         val -> Date.from_iso8601(val)
 335       end)
 336       |> Enum.into(%{})
 337
 338     Common.start_pleroma()
 339
 340     with {:ok, val} <- options[:expires_at],
 341          options = Map.put(options, :expires_at, val),
 342          {:ok, invite} <- UserInviteToken.create_invite(options) do
 343       Mix.shell().info(
 344         "Generated user invite token " <> String.replace(invite.invite_type, "_", " ")
 345       )
 346
 347       url =
 348         Pleroma.Web.Router.Helpers.redirect_url(
 349           Pleroma.Web.Endpoint,
 350           :registration_page,
 351           invite.token
 352         )
 353
 354       IO.puts(url)
 355     else
 356       error ->
 357         Mix.shell().error("Could not create invite token: #{inspect(error)}")
 358     end
 359   end
 360
 361   def run(["invites"]) do
 362     Common.start_pleroma()
 363
 364     Mix.shell().info("Invites list:")
 365
 366     UserInviteToken.list_invites()
 367     |> Enum.each(fn invite ->
 368       expire_info =
 369         with expires_at when not is_nil(expires_at) <- invite.expires_at do
 370           " | Expires at: #{Date.to_string(expires_at)}"
 371         end
 372
 373       using_info =
 374         with max_use when not is_nil(max_use) <- invite.max_use do
 375           " | Max use: #{max_use}    Left use: #{max_use - invite.uses}"
 376         end
 377
 378       Mix.shell().info(
 379         "ID: #{invite.id} | Token: #{invite.token} | Token type: #{invite.invite_type} | Used: #{
 380           invite.used
 381         }#{expire_info}#{using_info}"
 382       )
 383     end)
 384   end
 385
 386   def run(["revoke_invite", token]) do
 387     Common.start_pleroma()
 388
 389     with {:ok, invite} <- UserInviteToken.find_by_token(token),
 390          {:ok, _} <- UserInviteToken.update_invite(invite, %{used: true}) do
 391       Mix.shell().info("Invite for token #{token} was revoked.")
 392     else
 393       _ -> Mix.shell().error("No invite found with token #{token}")
 394     end
 395   end
 396
 397   def run(["delete_activities", nickname]) do
 398     Common.start_pleroma()
 399
 400     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 401       User.delete_user_activities(user)
 402       Mix.shell().info("User #{nickname} statuses deleted.")
 403     else
 404       _ ->
 405         Mix.shell().error("No local user #{nickname}")
 406     end
 407   end
 408
 409   defp set_moderator(user, value) do
 410     info_cng = User.Info.admin_api_update(user.info, %{is_moderator: value})
 411
 412     user_cng =
 413       Ecto.Changeset.change(user)
 414       |> put_embed(:info, info_cng)
 415
 416     {:ok, user} = User.update_and_set_cache(user_cng)
 417
 418     Mix.shell().info("Moderator status of #{user.nickname}: #{user.info.is_moderator}")
 419     user
 420   end
 421
 422   defp set_admin(user, value) do
 423     info_cng = User.Info.admin_api_update(user.info, %{is_admin: value})
 424
 425     user_cng =
 426       Ecto.Changeset.change(user)
 427       |> put_embed(:info, info_cng)
 428
 429     {:ok, user} = User.update_and_set_cache(user_cng)
 430
 431     Mix.shell().info("Admin status of #{user.nickname}: #{user.info.is_admin}")
 432     user
 433   end
 434
 435   defp set_locked(user, value) do
 436     info_cng = User.Info.user_upgrade(user.info, %{locked: value})
 437
 438     user_cng =
 439       Ecto.Changeset.change(user)
 440       |> put_embed(:info, info_cng)
 441
 442     {:ok, user} = User.update_and_set_cache(user_cng)
 443
 444     Mix.shell().info("Locked status of #{user.nickname}: #{user.info.locked}")
 445     user
 446   end
 447 end