git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/user.ex

   1 defmodule Mix.Tasks.Pleroma.User do
   2   use Mix.Task
   3   import Ecto.Changeset
   4   alias Pleroma.{Repo, User}
   5   alias Mix.Tasks.Pleroma.Common
   6
   7   @shortdoc "Manages Pleroma users"
   8   @moduledoc """
   9   Manages Pleroma users.
  10
  11   ## Create a new user.
  12
  13       mix pleroma.user new NICKNAME EMAIL [OPTION...]
  14
  15   Options:
  16   - `--name NAME` - the user's name (i.e., "Lain Iwakura")
  17   - `--bio BIO` - the user's bio
  18   - `--password PASSWORD` - the user's password
  19   - `--moderator`/`--no-moderator` - whether the user is a moderator
  20   - `--admin`/`--no-admin` - whether the user is an admin
  21
  22   ## Generate an invite link.
  23
  24       mix pleroma.user invite
  25
  26   ## Delete the user's account.
  27
  28       mix pleroma.user rm NICKNAME
  29
  30   ## Deactivate or activate the user's account.
  31
  32       mix pleroma.user toggle_activated NICKNAME
  33
  34   ## Unsubscribe local users from user's account and deactivate it
  35
  36       mix pleroma.user unsubscribe NICKNAME
  37
  38   ## Create a password reset link.
  39
  40       mix pleroma.user reset_password NICKNAME
  41
  42   ## Set the value of the given user's settings.
  43
  44       mix pleroma.user set NICKNAME [OPTION...]
  45
  46   Options:
  47   - `--locked`/`--no-locked` - whether the user's account is locked
  48   - `--moderator`/`--no-moderator` - whether the user is a moderator
  49   - `--admin`/`--no-admin` - whether the user is an admin
  50   """
  51   def run(["new", nickname, email | rest]) do
  52     {options, [], []} =
  53       OptionParser.parse(
  54         rest,
  55         strict: [
  56           name: :string,
  57           bio: :string,
  58           password: :string,
  59           moderator: :boolean,
  60           admin: :boolean
  61         ]
  62       )
  63
  64     name = Keyword.get(options, :name, nickname)
  65     bio = Keyword.get(options, :bio, "")
  66
  67     {password, generated_password?} =
  68       case Keyword.get(options, :password) do
  69         nil ->
  70           {:crypto.strong_rand_bytes(16) |> Base.encode64(), true}
  71
  72         password ->
  73           {password, false}
  74       end
  75
  76     moderator? = Keyword.get(options, :moderator, false)
  77     admin? = Keyword.get(options, :admin, false)
  78
  79     Mix.shell().info("""
  80     A user will be created with the following information:
  81       - nickname: #{nickname}
  82       - email: #{email}
  83       - password: #{
  84       if(generated_password?, do: "[generated; a reset link will be created]", else: password)
  85     }
  86       - name: #{name}
  87       - bio: #{bio}
  88       - moderator: #{if(moderator?, do: "true", else: "false")}
  89       - admin: #{if(admin?, do: "true", else: "false")}
  90     """)
  91
  92     proceed? = Mix.shell().yes?("Continue?")
  93
  94     unless not proceed? do
  95       Common.start_pleroma()
  96
  97       params =
  98         %{
  99           nickname: nickname,
 100           email: email,
 101           password: password,
 102           password_confirmation: password,
 103           name: name,
 104           bio: bio
 105         }
 106         |> IO.inspect()
 107
 108       user = User.register_changeset(%User{}, params)
 109       Repo.insert!(user)
 110
 111       Mix.shell().info("User #{nickname} created")
 112
 113       if moderator? do
 114         run(["set", nickname, "--moderator"])
 115       end
 116
 117       if admin? do
 118         run(["set", nickname, "--admin"])
 119       end
 120
 121       if generated_password? do
 122         run(["reset_password", nickname])
 123       end
 124     else
 125       Mix.shell().info("User will not be created.")
 126     end
 127   end
 128
 129   def run(["rm", nickname]) do
 130     Common.start_pleroma()
 131
 132     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 133       User.delete(user)
 134       Mix.shell().info("User #{nickname} deleted.")
 135     else
 136       _ ->
 137         Mix.shell().error("No local user #{nickname}")
 138     end
 139   end
 140
 141   def run(["toggle_activated", nickname]) do
 142     Common.start_pleroma()
 143
 144     with %User{} = user <- User.get_by_nickname(nickname) do
 145       User.deactivate(user, !user.info["deactivated"])
 146       Mix.shell().info("Activation status of #{nickname}: #{user.info["deactivated"]}")
 147     else
 148       _ ->
 149         Mix.shell().error("No user #{nickname}")
 150     end
 151   end
 152
 153   def run(["reset_password", nickname]) do
 154     Common.start_pleroma()
 155
 156     with %User{local: true} = user <- User.get_by_nickname(nickname),
 157          {:ok, token} <- Pleroma.PasswordResetToken.create_token(user) do
 158       Mix.shell().info("Generated password reset token for #{user.nickname}")
 159
 160       IO.puts(
 161         "URL: #{
 162           Pleroma.Web.Router.Helpers.util_url(
 163             Pleroma.Web.Endpoint,
 164             :show_password_reset,
 165             token.token
 166           )
 167         }"
 168       )
 169     else
 170       _ ->
 171         Mix.shell().error("No local user #{nickname}")
 172     end
 173   end
 174
 175   def run(["unsubscribe", nickname]) do
 176     Common.start_pleroma()
 177
 178     with %User{} = user <- User.get_by_nickname(nickname) do
 179       Mix.shell().info("Deactivating #{user.nickname}")
 180       User.deactivate(user)
 181
 182       {:ok, friends} = User.get_friends(user)
 183
 184       Enum.each(friends, fn friend ->
 185         user = Repo.get(User, user.id)
 186
 187         Mix.shell().info("Unsubscribing #{friend.nickname} from #{user.nickname}")
 188         User.unfollow(user, friend)
 189       end)
 190
 191       :timer.sleep(500)
 192
 193       user = Repo.get(User, user.id)
 194
 195       if length(user.following) == 0 do
 196         Mix.shell().info("Successfully unsubscribed all followers from #{user.nickname}")
 197       end
 198     else
 199       _ ->
 200         Mix.shell().error("No user #{nickname}")
 201     end
 202   end
 203
 204   def run(["set", nickname | rest]) do
 205     Common.start_pleroma()
 206
 207     {options, [], []} =
 208       OptionParser.parse(
 209         rest,
 210         strict: [
 211           moderator: :boolean,
 212           admin: :boolean,
 213           locked: :boolean
 214         ]
 215       )
 216
 217     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 218       case Keyword.get(options, :moderator) do
 219         nil -> nil
 220         value -> set_moderator(user, value)
 221       end
 222
 223       case Keyword.get(options, :locked) do
 224         nil -> nil
 225         value -> set_locked(user, value)
 226       end
 227
 228       case Keyword.get(options, :admin) do
 229         nil -> nil
 230         value -> set_admin(user, value)
 231       end
 232     else
 233       _ ->
 234         Mix.shell().error("No local user #{nickname}")
 235     end
 236   end
 237
 238   def run(["invite"]) do
 239     Common.start_pleroma()
 240
 241     with {:ok, token} <- Pleroma.UserInviteToken.create_token() do
 242       Mix.shell().info("Generated user invite token")
 243
 244       url =
 245         Pleroma.Web.Router.Helpers.redirect_url(
 246           Pleroma.Web.Endpoint,
 247           :registration_page,
 248           token.token
 249         )
 250
 251       IO.puts(url)
 252     else
 253       _ ->
 254         Mix.shell().error("Could not create invite token.")
 255     end
 256   end
 257
 258   defp set_moderator(user, value) do
 259     info_cng = User.Info.admin_api_update(user.info, %{is_moderator: value})
 260
 261     user_cng =
 262       Ecto.Changeset.change(user)
 263       |> put_embed(:info, info_cng)
 264
 265     {:ok, user} = User.update_and_set_cache(user_cng)
 266
 267     Mix.shell().info("Moderator status of #{user.nickname}: #{user.info.is_moderator}")
 268   end
 269
 270   defp set_admin(user, value) do
 271     info_cng = User.Info.admin_api_update(user.info, %{is_admin: value})
 272
 273     user_cng =
 274       Ecto.Changeset.change(user)
 275       |> put_embed(:info, info_cng)
 276
 277     {:ok, user} = User.update_and_set_cache(user_cng)
 278
 279     Mix.shell().info("Admin status of #{user.nickname}: #{user.info.is_moderator}")
 280   end
 281
 282   defp set_locked(user, value) do
 283     info_cng = User.Info.user_upgrade(user.info, %{locked: value})
 284
 285     user_cng =
 286       Ecto.Changeset.change(user)
 287       |> put_embed(:info, info_cng)
 288
 289     {:ok, user} = User.update_and_set_cache(user_cng)
 290
 291     Mix.shell().info("Locked status of #{user.nickname}: #{user.info.locked}")
 292   end
 293 end