git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Mix.Tasks.Pleroma.User do
   6   use Mix.Task
   7   import Ecto.Changeset
   8   alias Pleroma.{Repo, User}
   9   alias Mix.Tasks.Pleroma.Common
  10
  11   @shortdoc "Manages Pleroma users"
  12   @moduledoc """
  13   Manages Pleroma users.
  14
  15   ## Create a new user.
  16
  17       mix pleroma.user new NICKNAME EMAIL [OPTION...]
  18
  19   Options:
  20   - `--name NAME` - the user's name (i.e., "Lain Iwakura")
  21   - `--bio BIO` - the user's bio
  22   - `--password PASSWORD` - the user's password
  23   - `--moderator`/`--no-moderator` - whether the user is a moderator
  24   - `--admin`/`--no-admin` - whether the user is an admin
  25   - `-y`, `--assume-yes`/`--no-assume-yes` - whether to assume yes to all questions
  26
  27   ## Generate an invite link.
  28
  29       mix pleroma.user invite
  30
  31   ## Delete the user's account.
  32
  33       mix pleroma.user rm NICKNAME
  34
  35   ## Deactivate or activate the user's account.
  36
  37       mix pleroma.user toggle_activated NICKNAME
  38
  39   ## Unsubscribe local users from user's account and deactivate it
  40
  41       mix pleroma.user unsubscribe NICKNAME
  42
  43   ## Create a password reset link.
  44
  45       mix pleroma.user reset_password NICKNAME
  46
  47   ## Set the value of the given user's settings.
  48
  49       mix pleroma.user set NICKNAME [OPTION...]
  50
  51   Options:
  52   - `--locked`/`--no-locked` - whether the user's account is locked
  53   - `--moderator`/`--no-moderator` - whether the user is a moderator
  54   - `--admin`/`--no-admin` - whether the user is an admin
  55
  56   ## Add tags to a user.
  57
  58       mix pleroma.user tag NICKNAME TAGS
  59
  60   ## Delete tags from a user.
  61
  62       mix pleroma.user untag NICKNAME TAGS
  63   """
  64   def run(["new", nickname, email | rest]) do
  65     {options, [], []} =
  66       OptionParser.parse(
  67         rest,
  68         strict: [
  69           name: :string,
  70           bio: :string,
  71           password: :string,
  72           moderator: :boolean,
  73           admin: :boolean,
  74           assume_yes: :boolean
  75         ],
  76         aliases: [
  77           y: :assume_yes
  78         ]
  79       )
  80
  81     name = Keyword.get(options, :name, nickname)
  82     bio = Keyword.get(options, :bio, "")
  83
  84     {password, generated_password?} =
  85       case Keyword.get(options, :password) do
  86         nil ->
  87           {:crypto.strong_rand_bytes(16) |> Base.encode64(), true}
  88
  89         password ->
  90           {password, false}
  91       end
  92
  93     moderator? = Keyword.get(options, :moderator, false)
  94     admin? = Keyword.get(options, :admin, false)
  95     assume_yes? = Keyword.get(options, :assume_yes, false)
  96
  97     Mix.shell().info("""
  98     A user will be created with the following information:
  99       - nickname: #{nickname}
 100       - email: #{email}
 101       - password: #{
 102       if(generated_password?, do: "[generated; a reset link will be created]", else: password)
 103     }
 104       - name: #{name}
 105       - bio: #{bio}
 106       - moderator: #{if(moderator?, do: "true", else: "false")}
 107       - admin: #{if(admin?, do: "true", else: "false")}
 108     """)
 109
 110     proceed? = assume_yes? or Mix.shell().yes?("Continue?")
 111
 112     unless not proceed? do
 113       Common.start_pleroma()
 114
 115       params = %{
 116         nickname: nickname,
 117         email: email,
 118         password: password,
 119         password_confirmation: password,
 120         name: name,
 121         bio: bio
 122       }
 123
 124       changeset = User.register_changeset(%User{}, params, confirmed: true)
 125       {:ok, _user} = User.register(changeset)
 126
 127       Mix.shell().info("User #{nickname} created")
 128
 129       if moderator? do
 130         run(["set", nickname, "--moderator"])
 131       end
 132
 133       if admin? do
 134         run(["set", nickname, "--admin"])
 135       end
 136
 137       if generated_password? do
 138         run(["reset_password", nickname])
 139       end
 140     else
 141       Mix.shell().info("User will not be created.")
 142     end
 143   end
 144
 145   def run(["rm", nickname]) do
 146     Common.start_pleroma()
 147
 148     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 149       User.delete(user)
 150       Mix.shell().info("User #{nickname} deleted.")
 151     else
 152       _ ->
 153         Mix.shell().error("No local user #{nickname}")
 154     end
 155   end
 156
 157   def run(["toggle_activated", nickname]) do
 158     Common.start_pleroma()
 159
 160     with %User{} = user <- User.get_by_nickname(nickname) do
 161       {:ok, user} = User.deactivate(user, !user.info.deactivated)
 162
 163       Mix.shell().info(
 164         "Activation status of #{nickname}: #{if(user.info.deactivated, do: "de", else: "")}activated"
 165       )
 166     else
 167       _ ->
 168         Mix.shell().error("No user #{nickname}")
 169     end
 170   end
 171
 172   def run(["reset_password", nickname]) do
 173     Common.start_pleroma()
 174
 175     with %User{local: true} = user <- User.get_by_nickname(nickname),
 176          {:ok, token} <- Pleroma.PasswordResetToken.create_token(user) do
 177       Mix.shell().info("Generated password reset token for #{user.nickname}")
 178
 179       IO.puts(
 180         "URL: #{
 181           Pleroma.Web.Router.Helpers.util_url(
 182             Pleroma.Web.Endpoint,
 183             :show_password_reset,
 184             token.token
 185           )
 186         }"
 187       )
 188     else
 189       _ ->
 190         Mix.shell().error("No local user #{nickname}")
 191     end
 192   end
 193
 194   def run(["unsubscribe", nickname]) do
 195     Common.start_pleroma()
 196
 197     with %User{} = user <- User.get_by_nickname(nickname) do
 198       Mix.shell().info("Deactivating #{user.nickname}")
 199       User.deactivate(user)
 200
 201       {:ok, friends} = User.get_friends(user)
 202
 203       Enum.each(friends, fn friend ->
 204         user = Repo.get(User, user.id)
 205
 206         Mix.shell().info("Unsubscribing #{friend.nickname} from #{user.nickname}")
 207         User.unfollow(user, friend)
 208       end)
 209
 210       :timer.sleep(500)
 211
 212       user = Repo.get(User, user.id)
 213
 214       if length(user.following) == 0 do
 215         Mix.shell().info("Successfully unsubscribed all followers from #{user.nickname}")
 216       end
 217     else
 218       _ ->
 219         Mix.shell().error("No user #{nickname}")
 220     end
 221   end
 222
 223   def run(["set", nickname | rest]) do
 224     Common.start_pleroma()
 225
 226     {options, [], []} =
 227       OptionParser.parse(
 228         rest,
 229         strict: [
 230           moderator: :boolean,
 231           admin: :boolean,
 232           locked: :boolean
 233         ]
 234       )
 235
 236     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 237       user =
 238         case Keyword.get(options, :moderator) do
 239           nil -> user
 240           value -> set_moderator(user, value)
 241         end
 242
 243       user =
 244         case Keyword.get(options, :locked) do
 245           nil -> user
 246           value -> set_locked(user, value)
 247         end
 248
 249       _user =
 250         case Keyword.get(options, :admin) do
 251           nil -> user
 252           value -> set_admin(user, value)
 253         end
 254     else
 255       _ ->
 256         Mix.shell().error("No local user #{nickname}")
 257     end
 258   end
 259
 260   def run(["tag", nickname | tags]) do
 261     Common.start_pleroma()
 262
 263     with %User{} = user <- User.get_by_nickname(nickname) do
 264       user = user |> User.tag(tags)
 265
 266       Mix.shell().info("Tags of #{user.nickname}: #{inspect(tags)}")
 267     else
 268       _ ->
 269         Mix.shell().error("Could not change user tags for #{nickname}")
 270     end
 271   end
 272
 273   def run(["untag", nickname | tags]) do
 274     Common.start_pleroma()
 275
 276     with %User{} = user <- User.get_by_nickname(nickname) do
 277       user = user |> User.untag(tags)
 278
 279       Mix.shell().info("Tags of #{user.nickname}: #{inspect(tags)}")
 280     else
 281       _ ->
 282         Mix.shell().error("Could not change user tags for #{nickname}")
 283     end
 284   end
 285
 286   def run(["invite"]) do
 287     Common.start_pleroma()
 288
 289     with {:ok, token} <- Pleroma.UserInviteToken.create_token() do
 290       Mix.shell().info("Generated user invite token")
 291
 292       url =
 293         Pleroma.Web.Router.Helpers.redirect_url(
 294           Pleroma.Web.Endpoint,
 295           :registration_page,
 296           token.token
 297         )
 298
 299       IO.puts(url)
 300     else
 301       _ ->
 302         Mix.shell().error("Could not create invite token.")
 303     end
 304   end
 305
 306   defp set_moderator(user, value) do
 307     info_cng = User.Info.admin_api_update(user.info, %{is_moderator: value})
 308
 309     user_cng =
 310       Ecto.Changeset.change(user)
 311       |> put_embed(:info, info_cng)
 312
 313     {:ok, user} = User.update_and_set_cache(user_cng)
 314
 315     Mix.shell().info("Moderator status of #{user.nickname}: #{user.info.is_moderator}")
 316     user
 317   end
 318
 319   defp set_admin(user, value) do
 320     info_cng = User.Info.admin_api_update(user.info, %{is_admin: value})
 321
 322     user_cng =
 323       Ecto.Changeset.change(user)
 324       |> put_embed(:info, info_cng)
 325
 326     {:ok, user} = User.update_and_set_cache(user_cng)
 327
 328     Mix.shell().info("Admin status of #{user.nickname}: #{user.info.is_admin}")
 329     user
 330   end
 331
 332   defp set_locked(user, value) do
 333     info_cng = User.Info.user_upgrade(user.info, %{locked: value})
 334
 335     user_cng =
 336       Ecto.Changeset.change(user)
 337       |> put_embed(:info, info_cng)
 338
 339     {:ok, user} = User.update_and_set_cache(user_cng)
 340
 341     Mix.shell().info("Locked status of #{user.nickname}: #{user.info.locked}")
 342     user
 343   end
 344 end