git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Mix.Tasks.Pleroma.User do
   6   use Mix.Task
   7   import Ecto.Changeset
   8   alias Mix.Tasks.Pleroma.Common
   9   alias Pleroma.Repo
  10   alias Pleroma.User
  11
  12   @shortdoc "Manages Pleroma users"
  13   @moduledoc """
  14   Manages Pleroma users.
  15
  16   ## Create a new user.
  17
  18       mix pleroma.user new NICKNAME EMAIL [OPTION...]
  19
  20   Options:
  21   - `--name NAME` - the user's name (i.e., "Lain Iwakura")
  22   - `--bio BIO` - the user's bio
  23   - `--password PASSWORD` - the user's password
  24   - `--moderator`/`--no-moderator` - whether the user is a moderator
  25   - `--admin`/`--no-admin` - whether the user is an admin
  26   - `-y`, `--assume-yes`/`--no-assume-yes` - whether to assume yes to all questions
  27
  28   ## Generate an invite link.
  29
  30       mix pleroma.user invite
  31
  32   ## Delete the user's account.
  33
  34       mix pleroma.user rm NICKNAME
  35
  36   ## Deactivate or activate the user's account.
  37
  38       mix pleroma.user toggle_activated NICKNAME
  39
  40   ## Unsubscribe local users from user's account and deactivate it
  41
  42       mix pleroma.user unsubscribe NICKNAME
  43
  44   ## Create a password reset link.
  45
  46       mix pleroma.user reset_password NICKNAME
  47
  48   ## Set the value of the given user's settings.
  49
  50       mix pleroma.user set NICKNAME [OPTION...]
  51
  52   Options:
  53   - `--locked`/`--no-locked` - whether the user's account is locked
  54   - `--moderator`/`--no-moderator` - whether the user is a moderator
  55   - `--admin`/`--no-admin` - whether the user is an admin
  56
  57   ## Add tags to a user.
  58
  59       mix pleroma.user tag NICKNAME TAGS
  60
  61   ## Delete tags from a user.
  62
  63       mix pleroma.user untag NICKNAME TAGS
  64   """
  65   def run(["new", nickname, email | rest]) do
  66     {options, [], []} =
  67       OptionParser.parse(
  68         rest,
  69         strict: [
  70           name: :string,
  71           bio: :string,
  72           password: :string,
  73           moderator: :boolean,
  74           admin: :boolean,
  75           assume_yes: :boolean
  76         ],
  77         aliases: [
  78           y: :assume_yes
  79         ]
  80       )
  81
  82     name = Keyword.get(options, :name, nickname)
  83     bio = Keyword.get(options, :bio, "")
  84
  85     {password, generated_password?} =
  86       case Keyword.get(options, :password) do
  87         nil ->
  88           {:crypto.strong_rand_bytes(16) |> Base.encode64(), true}
  89
  90         password ->
  91           {password, false}
  92       end
  93
  94     moderator? = Keyword.get(options, :moderator, false)
  95     admin? = Keyword.get(options, :admin, false)
  96     assume_yes? = Keyword.get(options, :assume_yes, false)
  97
  98     Mix.shell().info("""
  99     A user will be created with the following information:
 100       - nickname: #{nickname}
 101       - email: #{email}
 102       - password: #{
 103       if(generated_password?, do: "[generated; a reset link will be created]", else: password)
 104     }
 105       - name: #{name}
 106       - bio: #{bio}
 107       - moderator: #{if(moderator?, do: "true", else: "false")}
 108       - admin: #{if(admin?, do: "true", else: "false")}
 109     """)
 110
 111     proceed? = assume_yes? or Mix.shell().yes?("Continue?")
 112
 113     unless not proceed? do
 114       Common.start_pleroma()
 115
 116       params = %{
 117         nickname: nickname,
 118         email: email,
 119         password: password,
 120         password_confirmation: password,
 121         name: name,
 122         bio: bio
 123       }
 124
 125       changeset = User.register_changeset(%User{}, params, confirmed: true)
 126       {:ok, _user} = User.register(changeset)
 127
 128       Mix.shell().info("User #{nickname} created")
 129
 130       if moderator? do
 131         run(["set", nickname, "--moderator"])
 132       end
 133
 134       if admin? do
 135         run(["set", nickname, "--admin"])
 136       end
 137
 138       if generated_password? do
 139         run(["reset_password", nickname])
 140       end
 141     else
 142       Mix.shell().info("User will not be created.")
 143     end
 144   end
 145
 146   def run(["rm", nickname]) do
 147     Common.start_pleroma()
 148
 149     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 150       User.delete(user)
 151       Mix.shell().info("User #{nickname} deleted.")
 152     else
 153       _ ->
 154         Mix.shell().error("No local user #{nickname}")
 155     end
 156   end
 157
 158   def run(["toggle_activated", nickname]) do
 159     Common.start_pleroma()
 160
 161     with %User{} = user <- User.get_by_nickname(nickname) do
 162       {:ok, user} = User.deactivate(user, !user.info.deactivated)
 163
 164       Mix.shell().info(
 165         "Activation status of #{nickname}: #{if(user.info.deactivated, do: "de", else: "")}activated"
 166       )
 167     else
 168       _ ->
 169         Mix.shell().error("No user #{nickname}")
 170     end
 171   end
 172
 173   def run(["reset_password", nickname]) do
 174     Common.start_pleroma()
 175
 176     with %User{local: true} = user <- User.get_by_nickname(nickname),
 177          {:ok, token} <- Pleroma.PasswordResetToken.create_token(user) do
 178       Mix.shell().info("Generated password reset token for #{user.nickname}")
 179
 180       IO.puts(
 181         "URL: #{
 182           Pleroma.Web.Router.Helpers.util_url(
 183             Pleroma.Web.Endpoint,
 184             :show_password_reset,
 185             token.token
 186           )
 187         }"
 188       )
 189     else
 190       _ ->
 191         Mix.shell().error("No local user #{nickname}")
 192     end
 193   end
 194
 195   def run(["unsubscribe", nickname]) do
 196     Common.start_pleroma()
 197
 198     with %User{} = user <- User.get_by_nickname(nickname) do
 199       Mix.shell().info("Deactivating #{user.nickname}")
 200       User.deactivate(user)
 201
 202       {:ok, friends} = User.get_friends(user)
 203
 204       Enum.each(friends, fn friend ->
 205         user = Repo.get(User, user.id)
 206
 207         Mix.shell().info("Unsubscribing #{friend.nickname} from #{user.nickname}")
 208         User.unfollow(user, friend)
 209       end)
 210
 211       :timer.sleep(500)
 212
 213       user = Repo.get(User, user.id)
 214
 215       if Enum.empty?(user.following) do
 216         Mix.shell().info("Successfully unsubscribed all followers from #{user.nickname}")
 217       end
 218     else
 219       _ ->
 220         Mix.shell().error("No user #{nickname}")
 221     end
 222   end
 223
 224   def run(["set", nickname | rest]) do
 225     Common.start_pleroma()
 226
 227     {options, [], []} =
 228       OptionParser.parse(
 229         rest,
 230         strict: [
 231           moderator: :boolean,
 232           admin: :boolean,
 233           locked: :boolean
 234         ]
 235       )
 236
 237     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 238       user =
 239         case Keyword.get(options, :moderator) do
 240           nil -> user
 241           value -> set_moderator(user, value)
 242         end
 243
 244       user =
 245         case Keyword.get(options, :locked) do
 246           nil -> user
 247           value -> set_locked(user, value)
 248         end
 249
 250       _user =
 251         case Keyword.get(options, :admin) do
 252           nil -> user
 253           value -> set_admin(user, value)
 254         end
 255     else
 256       _ ->
 257         Mix.shell().error("No local user #{nickname}")
 258     end
 259   end
 260
 261   def run(["tag", nickname | tags]) do
 262     Common.start_pleroma()
 263
 264     with %User{} = user <- User.get_by_nickname(nickname) do
 265       user = user |> User.tag(tags)
 266
 267       Mix.shell().info("Tags of #{user.nickname}: #{inspect(tags)}")
 268     else
 269       _ ->
 270         Mix.shell().error("Could not change user tags for #{nickname}")
 271     end
 272   end
 273
 274   def run(["untag", nickname | tags]) do
 275     Common.start_pleroma()
 276
 277     with %User{} = user <- User.get_by_nickname(nickname) do
 278       user = user |> User.untag(tags)
 279
 280       Mix.shell().info("Tags of #{user.nickname}: #{inspect(tags)}")
 281     else
 282       _ ->
 283         Mix.shell().error("Could not change user tags for #{nickname}")
 284     end
 285   end
 286
 287   def run(["invite"]) do
 288     Common.start_pleroma()
 289
 290     with {:ok, token} <- Pleroma.UserInviteToken.create_token() do
 291       Mix.shell().info("Generated user invite token")
 292
 293       url =
 294         Pleroma.Web.Router.Helpers.redirect_url(
 295           Pleroma.Web.Endpoint,
 296           :registration_page,
 297           token.token
 298         )
 299
 300       IO.puts(url)
 301     else
 302       _ ->
 303         Mix.shell().error("Could not create invite token.")
 304     end
 305   end
 306
 307   defp set_moderator(user, value) do
 308     info_cng = User.Info.admin_api_update(user.info, %{is_moderator: value})
 309
 310     user_cng =
 311       Ecto.Changeset.change(user)
 312       |> put_embed(:info, info_cng)
 313
 314     {:ok, user} = User.update_and_set_cache(user_cng)
 315
 316     Mix.shell().info("Moderator status of #{user.nickname}: #{user.info.is_moderator}")
 317     user
 318   end
 319
 320   defp set_admin(user, value) do
 321     info_cng = User.Info.admin_api_update(user.info, %{is_admin: value})
 322
 323     user_cng =
 324       Ecto.Changeset.change(user)
 325       |> put_embed(:info, info_cng)
 326
 327     {:ok, user} = User.update_and_set_cache(user_cng)
 328
 329     Mix.shell().info("Admin status of #{user.nickname}: #{user.info.is_admin}")
 330     user
 331   end
 332
 333   defp set_locked(user, value) do
 334     info_cng = User.Info.user_upgrade(user.info, %{locked: value})
 335
 336     user_cng =
 337       Ecto.Changeset.change(user)
 338       |> put_embed(:info, info_cng)
 339
 340     {:ok, user} = User.update_and_set_cache(user_cng)
 341
 342     Mix.shell().info("Locked status of #{user.nickname}: #{user.info.locked}")
 343     user
 344   end
 345 end