git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/user.ex

   1 defmodule Mix.Tasks.Pleroma.User do
   2   use Mix.Task
   3   alias Pleroma.{Repo, User}
   4
   5   @shortdoc "Manages Pleroma users"
   6   @moduledoc """
   7   Manages Pleroma users.
   8
   9   ## Create a new user.
  10
  11       mix pleroma.user new NICKNAME EMAIL [OPTION...]
  12
  13   Options:
  14   - `--name NAME` - the user's name (i.e., "Lain Iwakura")
  15   - `--bio BIO` - the user's bio
  16   - `--password PASSWORD` - the user's password
  17   - `--moderator`/`--no-moderator` - whether the user is a moderator
  18   - `--admin`/`--no-admin` - whether the user is an admin
  19
  20   ## Delete the user's account.
  21
  22       mix pleroma.user rm NICKNAME
  23
  24   ## Deactivate or activate the user's account.
  25
  26       mix pleroma.user toggle_activated NICKNAME
  27
  28   ## Create a password reset link.
  29
  30       mix pleroma.user reset_password NICKNAME
  31
  32   ## Set the value of the given user's settings.
  33
  34       mix pleroma.user set NICKNAME [OPTION...]
  35
  36   Options:
  37   - `--locked`/`--no-locked` - whether the user's account is locked
  38   - `--moderator`/`--no-moderator` - whether the user is a moderator
  39   - `--admin`/`--no-admin` - whether the user is an admin
  40   """
  41
  42   def run(["new", nickname, email | rest]) do
  43     {options, [], []} =
  44       OptionParser.parse(
  45         rest,
  46         strict: [
  47           name: :string,
  48           bio: :string,
  49           password: :string,
  50           moderator: :boolean,
  51           admin: :boolean
  52         ]
  53       )
  54
  55     name = Keyword.get(options, :name, nickname)
  56     bio = Keyword.get(options, :bio, "")
  57
  58     {password, generated_password?} =
  59       case Keyword.get(options, :password) do
  60         nil ->
  61           {:crypto.strong_rand_bytes(16) |> Base.encode64(), true}
  62
  63         password ->
  64           {password, false}
  65       end
  66
  67     moderator? = Keyword.get(options, :moderator, false)
  68     admin? = Keyword.get(options, :admin, false)
  69
  70     Mix.shell().info("""
  71     A user will be created with the following information:
  72       - nickname: #{nickname}
  73       - email: #{email}
  74       - password: #{
  75       if(generated_password?, do: "[generated; a reset link will be created]", else: password)
  76     }
  77       - name: #{name}
  78       - bio: #{bio}
  79       - moderator: #{if(moderator?, do: "true", else: "false")}
  80       - admin: #{if(admin?, do: "true", else: "false")}
  81     """)
  82
  83     proceed? = Mix.shell().yes?("Continue?")
  84
  85     unless not proceed? do
  86       Mix.Task.run("app.start")
  87
  88       params =
  89         %{
  90           nickname: nickname,
  91           email: email,
  92           password: password,
  93           password_confirmation: password,
  94           name: name,
  95           bio: bio
  96         }
  97         |> IO.inspect()
  98
  99       user = User.register_changeset(%User{}, params)
 100       Repo.insert!(user)
 101
 102       Mix.shell().info("User #{nickname} created")
 103
 104       if moderator? do
 105         run(["set", nickname, "--moderator"])
 106       end
 107
 108       if admin? do
 109         run(["set", nickname, "--admin"])
 110       end
 111
 112       if generated_password? do
 113         run(["reset_password", nickname])
 114       end
 115     else
 116       Mix.shell().info("User will not be created.")
 117     end
 118   end
 119
 120   def run(["rm", nickname]) do
 121     Mix.Task.run("app.start")
 122
 123     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 124       User.delete(user)
 125       Mix.shell().info("User #{nickname} deleted.")
 126     else
 127       _ ->
 128         Mix.shell().error("No local user #{nickname}")
 129     end
 130   end
 131
 132   def run(["toggle_activated", nickname]) do
 133     Mix.Task.run("app.start")
 134
 135     with %User{} = user <- User.get_by_nickname(nickname) do
 136       User.deactivate(user, !user.info["deactivated"])
 137       Mix.shell().info("Activation status of #{nickname}: #{user.info["deactivated"]}")
 138     else
 139       _ ->
 140         Mix.shell().error("No user #{nickname}")
 141     end
 142   end
 143
 144   def run(["reset_password", nickname]) do
 145     Mix.Task.run("app.start")
 146
 147     with %User{local: true} = user <- User.get_by_nickname(nickname),
 148          {:ok, token} <- Pleroma.PasswordResetToken.create_token(user) do
 149       Mix.shell().info("Generated password reset token for #{user.nickname}")
 150
 151       IO.puts(
 152         "URL: #{
 153           Pleroma.Web.Router.Helpers.util_url(
 154             Pleroma.Web.Endpoint,
 155             :show_password_reset,
 156             token.token
 157           )
 158         }"
 159       )
 160     else
 161       _ ->
 162         Mix.shell().error("No local user #{nickname}")
 163     end
 164   end
 165
 166   def run(["unsubscribe", nickname]) do
 167     Mix.Task.run("app.start")
 168
 169     with %User{} = user <- User.get_by_nickname(nickname) do
 170       Mix.shell().info("Deactivating #{user.nickname}")
 171       User.deactivate(user)
 172
 173       {:ok, friends} = User.get_friends(user)
 174
 175       Enum.each(friends, fn friend ->
 176         user = Repo.get(User, user.id)
 177
 178         Mix.shell().info("Unsubscribing #{friend.nickname} from #{user.nickname}")
 179         User.unfollow(user, friend)
 180       end)
 181
 182       :timer.sleep(500)
 183
 184       user = Repo.get(User, user.id)
 185
 186       if length(user.following) == 0 do
 187         Mix.shell().info("Successfully unsubscribed all followers from #{user.nickname}")
 188       end
 189     else
 190       _ ->
 191         Mix.shell().error("No user #{nickname}")
 192     end
 193   end
 194
 195   def run(["set", nickname | rest]) do
 196     {options, [], []} =
 197       OptionParser.parse(
 198         rest,
 199         strict: [
 200           moderator: :boolean,
 201           admin: :boolean,
 202           locked: :boolean
 203         ]
 204       )
 205
 206     case Keyword.get(options, :moderator) do
 207       nil -> nil
 208       value -> set_moderator(nickname, value)
 209     end
 210
 211     case Keyword.get(options, :locked) do
 212       nil -> nil
 213       value -> set_locked(nickname, value)
 214     end
 215
 216     case Keyword.get(options, :admin) do
 217       nil -> nil
 218       value -> set_admin(nickname, value)
 219     end
 220   end
 221
 222   defp set_moderator(nickname, value) do
 223     Application.ensure_all_started(:pleroma)
 224
 225     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 226       info =
 227         user.info
 228         |> Map.put("is_moderator", value)
 229
 230       cng = User.info_changeset(user, %{info: info})
 231       {:ok, user} = User.update_and_set_cache(cng)
 232
 233       Mix.shell().info("Moderator status of #{nickname}: #{user.info["is_moderator"]}")
 234     else
 235       _ ->
 236         Mix.shell().error("No local user #{nickname}")
 237     end
 238   end
 239
 240   defp set_admin(nickname, value) do
 241     Application.ensure_all_started(:pleroma)
 242
 243     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 244       info =
 245         user.info
 246         |> Map.put("is_admin", value)
 247
 248       cng = User.info_changeset(user, %{info: info})
 249       {:ok, user} = User.update_and_set_cache(cng)
 250
 251       Mix.shell().info("Admin status of #{nickname}: #{user.info["is_admin"]}")
 252     else
 253       _ ->
 254         Mix.shell().error("No local user #{nickname}")
 255     end
 256   end
 257
 258   defp set_locked(nickname, value) do
 259     Mix.Ecto.ensure_started(Repo, [])
 260
 261     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 262       info =
 263         user.info
 264         |> Map.put("locked", value)
 265
 266       cng = User.info_changeset(user, %{info: info})
 267       user = Repo.update!(cng)
 268
 269       IO.puts("Locked status of #{nickname}: #{user.info["locked"]}")
 270     else
 271       _ ->
 272         IO.puts("No local user #{nickname}")
 273     end
 274   end
 275 end