git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Mix.Tasks.Pleroma.User do
   6   use Mix.Task
   7   import Ecto.Changeset
   8   alias Pleroma.{Repo, User}
   9   alias Mix.Tasks.Pleroma.Common
  10
  11   @shortdoc "Manages Pleroma users"
  12   @moduledoc """
  13   Manages Pleroma users.
  14
  15   ## Create a new user.
  16
  17       mix pleroma.user new NICKNAME EMAIL [OPTION...]
  18
  19   Options:
  20   - `--name NAME` - the user's name (i.e., "Lain Iwakura")
  21   - `--bio BIO` - the user's bio
  22   - `--password PASSWORD` - the user's password
  23   - `--moderator`/`--no-moderator` - whether the user is a moderator
  24   - `--admin`/`--no-admin` - whether the user is an admin
  25   - `-y`, `--assume-yes`/`--no-assume-yes` - whether to assume yes to all questions
  26
  27   ## Generate an invite link.
  28
  29       mix pleroma.user invite
  30
  31   ## Delete the user's account.
  32
  33       mix pleroma.user rm NICKNAME
  34
  35   ## Deactivate or activate the user's account.
  36
  37       mix pleroma.user toggle_activated NICKNAME
  38
  39   ## Unsubscribe local users from user's account and deactivate it
  40
  41       mix pleroma.user unsubscribe NICKNAME
  42
  43   ## Create a password reset link.
  44
  45       mix pleroma.user reset_password NICKNAME
  46
  47   ## Set the value of the given user's settings.
  48
  49       mix pleroma.user set NICKNAME [OPTION...]
  50
  51   Options:
  52   - `--locked`/`--no-locked` - whether the user's account is locked
  53   - `--moderator`/`--no-moderator` - whether the user is a moderator
  54   - `--admin`/`--no-admin` - whether the user is an admin
  55   """
  56   def run(["new", nickname, email | rest]) do
  57     {options, [], []} =
  58       OptionParser.parse(
  59         rest,
  60         strict: [
  61           name: :string,
  62           bio: :string,
  63           password: :string,
  64           moderator: :boolean,
  65           admin: :boolean,
  66           assume_yes: :boolean
  67         ],
  68         aliases: [
  69           y: :assume_yes
  70         ]
  71       )
  72
  73     name = Keyword.get(options, :name, nickname)
  74     bio = Keyword.get(options, :bio, "")
  75
  76     {password, generated_password?} =
  77       case Keyword.get(options, :password) do
  78         nil ->
  79           {:crypto.strong_rand_bytes(16) |> Base.encode64(), true}
  80
  81         password ->
  82           {password, false}
  83       end
  84
  85     moderator? = Keyword.get(options, :moderator, false)
  86     admin? = Keyword.get(options, :admin, false)
  87     assume_yes? = Keyword.get(options, :assume_yes, false)
  88
  89     Mix.shell().info("""
  90     A user will be created with the following information:
  91       - nickname: #{nickname}
  92       - email: #{email}
  93       - password: #{
  94       if(generated_password?, do: "[generated; a reset link will be created]", else: password)
  95     }
  96       - name: #{name}
  97       - bio: #{bio}
  98       - moderator: #{if(moderator?, do: "true", else: "false")}
  99       - admin: #{if(admin?, do: "true", else: "false")}
 100     """)
 101
 102     proceed? = assume_yes? or Mix.shell().yes?("Continue?")
 103
 104     unless not proceed? do
 105       Common.start_pleroma()
 106
 107       params = %{
 108         nickname: nickname,
 109         email: email,
 110         password: password,
 111         password_confirmation: password,
 112         name: name,
 113         bio: bio
 114       }
 115
 116       changeset = User.register_changeset(%User{}, params, confirmed: true)
 117       {:ok, _user} = User.register(changeset)
 118
 119       Mix.shell().info("User #{nickname} created")
 120
 121       if moderator? do
 122         run(["set", nickname, "--moderator"])
 123       end
 124
 125       if admin? do
 126         run(["set", nickname, "--admin"])
 127       end
 128
 129       if generated_password? do
 130         run(["reset_password", nickname])
 131       end
 132     else
 133       Mix.shell().info("User will not be created.")
 134     end
 135   end
 136
 137   def run(["rm", nickname]) do
 138     Common.start_pleroma()
 139
 140     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 141       User.delete(user)
 142       Mix.shell().info("User #{nickname} deleted.")
 143     else
 144       _ ->
 145         Mix.shell().error("No local user #{nickname}")
 146     end
 147   end
 148
 149   def run(["toggle_activated", nickname]) do
 150     Common.start_pleroma()
 151
 152     with %User{} = user <- User.get_by_nickname(nickname) do
 153       {:ok, user} = User.deactivate(user, !user.info.deactivated)
 154
 155       Mix.shell().info(
 156         "Activation status of #{nickname}: #{if(user.info.deactivated, do: "de", else: "")}activated"
 157       )
 158     else
 159       _ ->
 160         Mix.shell().error("No user #{nickname}")
 161     end
 162   end
 163
 164   def run(["reset_password", nickname]) do
 165     Common.start_pleroma()
 166
 167     with %User{local: true} = user <- User.get_by_nickname(nickname),
 168          {:ok, token} <- Pleroma.PasswordResetToken.create_token(user) do
 169       Mix.shell().info("Generated password reset token for #{user.nickname}")
 170
 171       IO.puts(
 172         "URL: #{
 173           Pleroma.Web.Router.Helpers.util_url(
 174             Pleroma.Web.Endpoint,
 175             :show_password_reset,
 176             token.token
 177           )
 178         }"
 179       )
 180     else
 181       _ ->
 182         Mix.shell().error("No local user #{nickname}")
 183     end
 184   end
 185
 186   def run(["unsubscribe", nickname]) do
 187     Common.start_pleroma()
 188
 189     with %User{} = user <- User.get_by_nickname(nickname) do
 190       Mix.shell().info("Deactivating #{user.nickname}")
 191       User.deactivate(user)
 192
 193       {:ok, friends} = User.get_friends(user)
 194
 195       Enum.each(friends, fn friend ->
 196         user = Repo.get(User, user.id)
 197
 198         Mix.shell().info("Unsubscribing #{friend.nickname} from #{user.nickname}")
 199         User.unfollow(user, friend)
 200       end)
 201
 202       :timer.sleep(500)
 203
 204       user = Repo.get(User, user.id)
 205
 206       if length(user.following) == 0 do
 207         Mix.shell().info("Successfully unsubscribed all followers from #{user.nickname}")
 208       end
 209     else
 210       _ ->
 211         Mix.shell().error("No user #{nickname}")
 212     end
 213   end
 214
 215   def run(["set", nickname | rest]) do
 216     Common.start_pleroma()
 217
 218     {options, [], []} =
 219       OptionParser.parse(
 220         rest,
 221         strict: [
 222           moderator: :boolean,
 223           admin: :boolean,
 224           locked: :boolean
 225         ]
 226       )
 227
 228     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 229       user =
 230         case Keyword.get(options, :moderator) do
 231           nil -> user
 232           value -> set_moderator(user, value)
 233         end
 234
 235       user =
 236         case Keyword.get(options, :locked) do
 237           nil -> user
 238           value -> set_locked(user, value)
 239         end
 240
 241       _user =
 242         case Keyword.get(options, :admin) do
 243           nil -> user
 244           value -> set_admin(user, value)
 245         end
 246     else
 247       _ ->
 248         Mix.shell().error("No local user #{nickname}")
 249     end
 250   end
 251
 252   def run(["invite"]) do
 253     Common.start_pleroma()
 254
 255     with {:ok, token} <- Pleroma.UserInviteToken.create_token() do
 256       Mix.shell().info("Generated user invite token")
 257
 258       url =
 259         Pleroma.Web.Router.Helpers.redirect_url(
 260           Pleroma.Web.Endpoint,
 261           :registration_page,
 262           token.token
 263         )
 264
 265       IO.puts(url)
 266     else
 267       _ ->
 268         Mix.shell().error("Could not create invite token.")
 269     end
 270   end
 271
 272   defp set_moderator(user, value) do
 273     info_cng = User.Info.admin_api_update(user.info, %{is_moderator: value})
 274
 275     user_cng =
 276       Ecto.Changeset.change(user)
 277       |> put_embed(:info, info_cng)
 278
 279     {:ok, user} = User.update_and_set_cache(user_cng)
 280
 281     Mix.shell().info("Moderator status of #{user.nickname}: #{user.info.is_moderator}")
 282     user
 283   end
 284
 285   defp set_admin(user, value) do
 286     info_cng = User.Info.admin_api_update(user.info, %{is_admin: value})
 287
 288     user_cng =
 289       Ecto.Changeset.change(user)
 290       |> put_embed(:info, info_cng)
 291
 292     {:ok, user} = User.update_and_set_cache(user_cng)
 293
 294     Mix.shell().info("Admin status of #{user.nickname}: #{user.info.is_admin}")
 295     user
 296   end
 297
 298   defp set_locked(user, value) do
 299     info_cng = User.Info.user_upgrade(user.info, %{locked: value})
 300
 301     user_cng =
 302       Ecto.Changeset.change(user)
 303       |> put_embed(:info, info_cng)
 304
 305     {:ok, user} = User.update_and_set_cache(user_cng)
 306
 307     Mix.shell().info("Locked status of #{user.nickname}: #{user.info.locked}")
 308     user
 309   end
 310 end