git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/user.ex

   1 defmodule Mix.Tasks.Pleroma.User do
   2   use Mix.Task
   3   import Ecto.Changeset
   4   alias Pleroma.{Repo, User}
   5   alias Mix.Tasks.Pleroma.Common
   6
   7   @shortdoc "Manages Pleroma users"
   8   @moduledoc """
   9   Manages Pleroma users.
  10
  11   ## Create a new user.
  12
  13       mix pleroma.user new NICKNAME EMAIL [OPTION...]
  14
  15   Options:
  16   - `--name NAME` - the user's name (i.e., "Lain Iwakura")
  17   - `--bio BIO` - the user's bio
  18   - `--password PASSWORD` - the user's password
  19   - `--moderator`/`--no-moderator` - whether the user is a moderator
  20   - `--admin`/`--no-admin` - whether the user is an admin
  21
  22   ## Generate an invite link.
  23
  24       mix pleroma.user invite
  25
  26   ## Delete the user's account.
  27
  28       mix pleroma.user rm NICKNAME
  29
  30   ## Deactivate or activate the user's account.
  31
  32       mix pleroma.user toggle_activated NICKNAME
  33
  34   ## Unsubscribe local users from user's account and deactivate it
  35
  36       mix pleroma.user unsubscribe NICKNAME
  37
  38   ## Create a password reset link.
  39
  40       mix pleroma.user reset_password NICKNAME
  41
  42   ## Set the value of the given user's settings.
  43
  44       mix pleroma.user set NICKNAME [OPTION...]
  45
  46   Options:
  47   - `--locked`/`--no-locked` - whether the user's account is locked
  48   - `--moderator`/`--no-moderator` - whether the user is a moderator
  49   - `--admin`/`--no-admin` - whether the user is an admin
  50   """
  51   def run(["new", nickname, email | rest]) do
  52     {options, [], []} =
  53       OptionParser.parse(
  54         rest,
  55         strict: [
  56           name: :string,
  57           bio: :string,
  58           password: :string,
  59           moderator: :boolean,
  60           admin: :boolean
  61         ]
  62       )
  63
  64     name = Keyword.get(options, :name, nickname)
  65     bio = Keyword.get(options, :bio, "")
  66
  67     {password, generated_password?} =
  68       case Keyword.get(options, :password) do
  69         nil ->
  70           {:crypto.strong_rand_bytes(16) |> Base.encode64(), true}
  71
  72         password ->
  73           {password, false}
  74       end
  75
  76     moderator? = Keyword.get(options, :moderator, false)
  77     admin? = Keyword.get(options, :admin, false)
  78
  79     Mix.shell().info("""
  80     A user will be created with the following information:
  81       - nickname: #{nickname}
  82       - email: #{email}
  83       - password: #{
  84       if(generated_password?, do: "[generated; a reset link will be created]", else: password)
  85     }
  86       - name: #{name}
  87       - bio: #{bio}
  88       - moderator: #{if(moderator?, do: "true", else: "false")}
  89       - admin: #{if(admin?, do: "true", else: "false")}
  90     """)
  91
  92     proceed? = Mix.shell().yes?("Continue?")
  93
  94     unless not proceed? do
  95       Common.start_pleroma()
  96
  97       params =
  98         %{
  99           nickname: nickname,
 100           email: email,
 101           password: password,
 102           password_confirmation: password,
 103           name: name,
 104           bio: bio
 105         }
 106         |> IO.inspect()
 107
 108       user = User.register_changeset(%User{}, params)
 109       Repo.insert!(user)
 110
 111       Mix.shell().info("User #{nickname} created")
 112
 113       if moderator? do
 114         run(["set", nickname, "--moderator"])
 115       end
 116
 117       if admin? do
 118         run(["set", nickname, "--admin"])
 119       end
 120
 121       if generated_password? do
 122         run(["reset_password", nickname])
 123       end
 124     else
 125       Mix.shell().info("User will not be created.")
 126     end
 127   end
 128
 129   def run(["rm", nickname]) do
 130     Common.start_pleroma()
 131
 132     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 133       User.delete(user)
 134       Mix.shell().info("User #{nickname} deleted.")
 135     else
 136       _ ->
 137         Mix.shell().error("No local user #{nickname}")
 138     end
 139   end
 140
 141   def run(["toggle_activated", nickname]) do
 142     Common.start_pleroma()
 143
 144     with %User{} = user <- User.get_by_nickname(nickname) do
 145       {:ok, user} = User.deactivate(user, !user.info.deactivated)
 146
 147       Mix.shell().info(
 148         "Activation status of #{nickname}: #{if(user.info.deactivated, do: "de", else: "")}activated"
 149       )
 150     else
 151       _ ->
 152         Mix.shell().error("No user #{nickname}")
 153     end
 154   end
 155
 156   def run(["reset_password", nickname]) do
 157     Common.start_pleroma()
 158
 159     with %User{local: true} = user <- User.get_by_nickname(nickname),
 160          {:ok, token} <- Pleroma.PasswordResetToken.create_token(user) do
 161       Mix.shell().info("Generated password reset token for #{user.nickname}")
 162
 163       IO.puts(
 164         "URL: #{
 165           Pleroma.Web.Router.Helpers.util_url(
 166             Pleroma.Web.Endpoint,
 167             :show_password_reset,
 168             token.token
 169           )
 170         }"
 171       )
 172     else
 173       _ ->
 174         Mix.shell().error("No local user #{nickname}")
 175     end
 176   end
 177
 178   def run(["unsubscribe", nickname]) do
 179     Common.start_pleroma()
 180
 181     with %User{} = user <- User.get_by_nickname(nickname) do
 182       Mix.shell().info("Deactivating #{user.nickname}")
 183       User.deactivate(user)
 184
 185       {:ok, friends} = User.get_friends(user)
 186
 187       Enum.each(friends, fn friend ->
 188         user = Repo.get(User, user.id)
 189
 190         Mix.shell().info("Unsubscribing #{friend.nickname} from #{user.nickname}")
 191         User.unfollow(user, friend)
 192       end)
 193
 194       :timer.sleep(500)
 195
 196       user = Repo.get(User, user.id)
 197
 198       if length(user.following) == 0 do
 199         Mix.shell().info("Successfully unsubscribed all followers from #{user.nickname}")
 200       end
 201     else
 202       _ ->
 203         Mix.shell().error("No user #{nickname}")
 204     end
 205   end
 206
 207   def run(["set", nickname | rest]) do
 208     Common.start_pleroma()
 209
 210     {options, [], []} =
 211       OptionParser.parse(
 212         rest,
 213         strict: [
 214           moderator: :boolean,
 215           admin: :boolean,
 216           locked: :boolean
 217         ]
 218       )
 219
 220     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 221       case Keyword.get(options, :moderator) do
 222         nil -> nil
 223         value -> set_moderator(user, value)
 224       end
 225
 226       case Keyword.get(options, :locked) do
 227         nil -> nil
 228         value -> set_locked(user, value)
 229       end
 230
 231       case Keyword.get(options, :admin) do
 232         nil -> nil
 233         value -> set_admin(user, value)
 234       end
 235     else
 236       _ ->
 237         Mix.shell().error("No local user #{nickname}")
 238     end
 239   end
 240
 241   def run(["invite"]) do
 242     Common.start_pleroma()
 243
 244     with {:ok, token} <- Pleroma.UserInviteToken.create_token() do
 245       Mix.shell().info("Generated user invite token")
 246
 247       url =
 248         Pleroma.Web.Router.Helpers.redirect_url(
 249           Pleroma.Web.Endpoint,
 250           :registration_page,
 251           token.token
 252         )
 253
 254       IO.puts(url)
 255     else
 256       _ ->
 257         Mix.shell().error("Could not create invite token.")
 258     end
 259   end
 260
 261   defp set_moderator(user, value) do
 262     info_cng = User.Info.admin_api_update(user.info, %{is_moderator: value})
 263
 264     user_cng =
 265       Ecto.Changeset.change(user)
 266       |> put_embed(:info, info_cng)
 267
 268     {:ok, user} = User.update_and_set_cache(user_cng)
 269
 270     Mix.shell().info("Moderator status of #{user.nickname}: #{user.info.is_moderator}")
 271   end
 272
 273   defp set_admin(user, value) do
 274     info_cng = User.Info.admin_api_update(user.info, %{is_admin: value})
 275
 276     user_cng =
 277       Ecto.Changeset.change(user)
 278       |> put_embed(:info, info_cng)
 279
 280     {:ok, user} = User.update_and_set_cache(user_cng)
 281
 282     Mix.shell().info("Admin status of #{user.nickname}: #{user.info.is_moderator}")
 283   end
 284
 285   defp set_locked(user, value) do
 286     info_cng = User.Info.user_upgrade(user.info, %{locked: value})
 287
 288     user_cng =
 289       Ecto.Changeset.change(user)
 290       |> put_embed(:info, info_cng)
 291
 292     {:ok, user} = User.update_and_set_cache(user_cng)
 293
 294     Mix.shell().info("Locked status of #{user.nickname}: #{user.info.locked}")
 295   end
 296 end