git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/user.ex

   1 defmodule Mix.Tasks.Pleroma.User do
   2   use Mix.Task
   3   import Ecto.Changeset
   4   alias Pleroma.{Repo, User}
   5   alias Mix.Tasks.Pleroma.Common
   6
   7   @shortdoc "Manages Pleroma users"
   8   @moduledoc """
   9   Manages Pleroma users.
  10
  11   ## Create a new user.
  12
  13       mix pleroma.user new NICKNAME EMAIL [OPTION...]
  14
  15   Options:
  16   - `--name NAME` - the user's name (i.e., "Lain Iwakura")
  17   - `--bio BIO` - the user's bio
  18   - `--password PASSWORD` - the user's password
  19   - `--moderator`/`--no-moderator` - whether the user is a moderator
  20   - `--admin`/`--no-admin` - whether the user is an admin
  21
  22   ## Generate an invite link.
  23
  24       mix pleroma.user invite
  25
  26   ## Delete the user's account.
  27
  28       mix pleroma.user rm NICKNAME
  29
  30   ## Deactivate or activate the user's account.
  31
  32       mix pleroma.user toggle_activated NICKNAME
  33
  34   ## Unsubscribe local users from user's account and deactivate it
  35
  36       mix pleroma.user unsubscribe NICKNAME
  37
  38   ## Create a password reset link.
  39
  40       mix pleroma.user reset_password NICKNAME
  41
  42   ## Set the value of the given user's settings.
  43
  44       mix pleroma.user set NICKNAME [OPTION...]
  45
  46   Options:
  47   - `--locked`/`--no-locked` - whether the user's account is locked
  48   - `--moderator`/`--no-moderator` - whether the user is a moderator
  49   - `--admin`/`--no-admin` - whether the user is an admin
  50   """
  51   def run(["new", nickname, email | rest]) do
  52     {options, [], []} =
  53       OptionParser.parse(
  54         rest,
  55         strict: [
  56           name: :string,
  57           bio: :string,
  58           password: :string,
  59           moderator: :boolean,
  60           admin: :boolean
  61         ]
  62       )
  63
  64     name = Keyword.get(options, :name, nickname)
  65     bio = Keyword.get(options, :bio, "")
  66
  67     {password, generated_password?} =
  68       case Keyword.get(options, :password) do
  69         nil ->
  70           {:crypto.strong_rand_bytes(16) |> Base.encode64(), true}
  71
  72         password ->
  73           {password, false}
  74       end
  75
  76     moderator? = Keyword.get(options, :moderator, false)
  77     admin? = Keyword.get(options, :admin, false)
  78
  79     Mix.shell().info("""
  80     A user will be created with the following information:
  81       - nickname: #{nickname}
  82       - email: #{email}
  83       - password: #{
  84       if(generated_password?, do: "[generated; a reset link will be created]", else: password)
  85     }
  86       - name: #{name}
  87       - bio: #{bio}
  88       - moderator: #{if(moderator?, do: "true", else: "false")}
  89       - admin: #{if(admin?, do: "true", else: "false")}
  90     """)
  91
  92     proceed? = Mix.shell().yes?("Continue?")
  93
  94     unless not proceed? do
  95       Common.start_pleroma()
  96
  97       params = %{
  98         nickname: nickname,
  99         email: email,
 100         password: password,
 101         password_confirmation: password,
 102         name: name,
 103         bio: bio
 104       }
 105
 106       user = User.register_changeset(%User{}, params)
 107       Repo.insert!(user)
 108
 109       Mix.shell().info("User #{nickname} created")
 110
 111       if moderator? do
 112         run(["set", nickname, "--moderator"])
 113       end
 114
 115       if admin? do
 116         run(["set", nickname, "--admin"])
 117       end
 118
 119       if generated_password? do
 120         run(["reset_password", nickname])
 121       end
 122     else
 123       Mix.shell().info("User will not be created.")
 124     end
 125   end
 126
 127   def run(["rm", nickname]) do
 128     Common.start_pleroma()
 129
 130     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 131       User.delete(user)
 132       Mix.shell().info("User #{nickname} deleted.")
 133     else
 134       _ ->
 135         Mix.shell().error("No local user #{nickname}")
 136     end
 137   end
 138
 139   def run(["toggle_activated", nickname]) do
 140     Common.start_pleroma()
 141
 142     with %User{} = user <- User.get_by_nickname(nickname) do
 143       {:ok, user} = User.deactivate(user, !user.info.deactivated)
 144
 145       Mix.shell().info(
 146         "Activation status of #{nickname}: #{if(user.info.deactivated, do: "de", else: "")}activated"
 147       )
 148     else
 149       _ ->
 150         Mix.shell().error("No user #{nickname}")
 151     end
 152   end
 153
 154   def run(["reset_password", nickname]) do
 155     Common.start_pleroma()
 156
 157     with %User{local: true} = user <- User.get_by_nickname(nickname),
 158          {:ok, token} <- Pleroma.PasswordResetToken.create_token(user) do
 159       Mix.shell().info("Generated password reset token for #{user.nickname}")
 160
 161       IO.puts(
 162         "URL: #{
 163           Pleroma.Web.Router.Helpers.util_url(
 164             Pleroma.Web.Endpoint,
 165             :show_password_reset,
 166             token.token
 167           )
 168         }"
 169       )
 170     else
 171       _ ->
 172         Mix.shell().error("No local user #{nickname}")
 173     end
 174   end
 175
 176   def run(["unsubscribe", nickname]) do
 177     Common.start_pleroma()
 178
 179     with %User{} = user <- User.get_by_nickname(nickname) do
 180       Mix.shell().info("Deactivating #{user.nickname}")
 181       User.deactivate(user)
 182
 183       {:ok, friends} = User.get_friends(user)
 184
 185       Enum.each(friends, fn friend ->
 186         user = Repo.get(User, user.id)
 187
 188         Mix.shell().info("Unsubscribing #{friend.nickname} from #{user.nickname}")
 189         User.unfollow(user, friend)
 190       end)
 191
 192       :timer.sleep(500)
 193
 194       user = Repo.get(User, user.id)
 195
 196       if length(user.following) == 0 do
 197         Mix.shell().info("Successfully unsubscribed all followers from #{user.nickname}")
 198       end
 199     else
 200       _ ->
 201         Mix.shell().error("No user #{nickname}")
 202     end
 203   end
 204
 205   def run(["set", nickname | rest]) do
 206     Common.start_pleroma()
 207
 208     {options, [], []} =
 209       OptionParser.parse(
 210         rest,
 211         strict: [
 212           moderator: :boolean,
 213           admin: :boolean,
 214           locked: :boolean
 215         ]
 216       )
 217
 218     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 219       user =
 220         case Keyword.get(options, :moderator) do
 221           nil -> user
 222           value -> set_moderator(user, value)
 223         end
 224
 225       user =
 226         case Keyword.get(options, :locked) do
 227           nil -> user
 228           value -> set_locked(user, value)
 229         end
 230
 231       _user =
 232         case Keyword.get(options, :admin) do
 233           nil -> user
 234           value -> set_admin(user, value)
 235         end
 236     else
 237       _ ->
 238         Mix.shell().error("No local user #{nickname}")
 239     end
 240   end
 241
 242   def run(["invite"]) do
 243     Common.start_pleroma()
 244
 245     with {:ok, token} <- Pleroma.UserInviteToken.create_token() do
 246       Mix.shell().info("Generated user invite token")
 247
 248       url =
 249         Pleroma.Web.Router.Helpers.redirect_url(
 250           Pleroma.Web.Endpoint,
 251           :registration_page,
 252           token.token
 253         )
 254
 255       IO.puts(url)
 256     else
 257       _ ->
 258         Mix.shell().error("Could not create invite token.")
 259     end
 260   end
 261
 262   defp set_moderator(user, value) do
 263     info_cng = User.Info.admin_api_update(user.info, %{is_moderator: value})
 264
 265     user_cng =
 266       Ecto.Changeset.change(user)
 267       |> put_embed(:info, info_cng)
 268
 269     {:ok, user} = User.update_and_set_cache(user_cng)
 270
 271     Mix.shell().info("Moderator status of #{user.nickname}: #{user.info.is_moderator}")
 272     user
 273   end
 274
 275   defp set_admin(user, value) do
 276     info_cng = User.Info.admin_api_update(user.info, %{is_admin: value})
 277
 278     user_cng =
 279       Ecto.Changeset.change(user)
 280       |> put_embed(:info, info_cng)
 281
 282     {:ok, user} = User.update_and_set_cache(user_cng)
 283
 284     Mix.shell().info("Admin status of #{user.nickname}: #{user.info.is_admin}")
 285     user
 286   end
 287
 288   defp set_locked(user, value) do
 289     info_cng = User.Info.user_upgrade(user.info, %{locked: value})
 290
 291     user_cng =
 292       Ecto.Changeset.change(user)
 293       |> put_embed(:info, info_cng)
 294
 295     {:ok, user} = User.update_and_set_cache(user_cng)
 296
 297     Mix.shell().info("Locked status of #{user.nickname}: #{user.info.locked}")
 298     user
 299   end
 300 end