git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Mix.Tasks.Pleroma.User do
   6   use Mix.Task
   7   import Ecto.Changeset
   8   alias Pleroma.Repo
   9   alias Pleroma.User
  10   alias Mix.Tasks.Pleroma.Common
  11
  12   @shortdoc "Manages Pleroma users"
  13   @moduledoc """
  14   Manages Pleroma users.
  15
  16   ## Create a new user.
  17
  18       mix pleroma.user new NICKNAME EMAIL [OPTION...]
  19
  20   Options:
  21   - `--name NAME` - the user's name (i.e., "Lain Iwakura")
  22   - `--bio BIO` - the user's bio
  23   - `--password PASSWORD` - the user's password
  24   - `--moderator`/`--no-moderator` - whether the user is a moderator
  25   - `--admin`/`--no-admin` - whether the user is an admin
  26   - `-y`, `--assume-yes`/`--no-assume-yes` - whether to assume yes to all questions
  27
  28   ## Generate an invite link.
  29
  30       mix pleroma.user invite
  31
  32   ## Delete the user's account.
  33
  34       mix pleroma.user rm NICKNAME
  35
  36   ## Deactivate or activate the user's account.
  37
  38       mix pleroma.user toggle_activated NICKNAME
  39
  40   ## Disable or enable the user's account.
  41
  42       mix pleroma.user toggle_disabled NICKNAME
  43
  44   ## Unsubscribe local users from user's account and deactivate it
  45
  46       mix pleroma.user unsubscribe NICKNAME
  47
  48   ## Create a password reset link.
  49
  50       mix pleroma.user reset_password NICKNAME
  51
  52   ## Set the value of the given user's settings.
  53
  54       mix pleroma.user set NICKNAME [OPTION...]
  55
  56   Options:
  57   - `--locked`/`--no-locked` - whether the user's account is locked
  58   - `--moderator`/`--no-moderator` - whether the user is a moderator
  59   - `--admin`/`--no-admin` - whether the user is an admin
  60
  61   ## Add tags to a user.
  62
  63       mix pleroma.user tag NICKNAME TAGS
  64
  65   ## Delete tags from a user.
  66
  67       mix pleroma.user untag NICKNAME TAGS
  68   """
  69   def run(["new", nickname, email | rest]) do
  70     {options, [], []} =
  71       OptionParser.parse(
  72         rest,
  73         strict: [
  74           name: :string,
  75           bio: :string,
  76           password: :string,
  77           moderator: :boolean,
  78           admin: :boolean,
  79           assume_yes: :boolean
  80         ],
  81         aliases: [
  82           y: :assume_yes
  83         ]
  84       )
  85
  86     name = Keyword.get(options, :name, nickname)
  87     bio = Keyword.get(options, :bio, "")
  88
  89     {password, generated_password?} =
  90       case Keyword.get(options, :password) do
  91         nil ->
  92           {:crypto.strong_rand_bytes(16) |> Base.encode64(), true}
  93
  94         password ->
  95           {password, false}
  96       end
  97
  98     moderator? = Keyword.get(options, :moderator, false)
  99     admin? = Keyword.get(options, :admin, false)
 100     assume_yes? = Keyword.get(options, :assume_yes, false)
 101
 102     Mix.shell().info("""
 103     A user will be created with the following information:
 104       - nickname: #{nickname}
 105       - email: #{email}
 106       - password: #{
 107       if(generated_password?, do: "[generated; a reset link will be created]", else: password)
 108     }
 109       - name: #{name}
 110       - bio: #{bio}
 111       - moderator: #{if(moderator?, do: "true", else: "false")}
 112       - admin: #{if(admin?, do: "true", else: "false")}
 113     """)
 114
 115     proceed? = assume_yes? or Mix.shell().yes?("Continue?")
 116
 117     unless not proceed? do
 118       Common.start_pleroma()
 119
 120       params = %{
 121         nickname: nickname,
 122         email: email,
 123         password: password,
 124         password_confirmation: password,
 125         name: name,
 126         bio: bio
 127       }
 128
 129       changeset = User.register_changeset(%User{}, params, confirmed: true)
 130       {:ok, _user} = User.register(changeset)
 131
 132       Mix.shell().info("User #{nickname} created")
 133
 134       if moderator? do
 135         run(["set", nickname, "--moderator"])
 136       end
 137
 138       if admin? do
 139         run(["set", nickname, "--admin"])
 140       end
 141
 142       if generated_password? do
 143         run(["reset_password", nickname])
 144       end
 145     else
 146       Mix.shell().info("User will not be created.")
 147     end
 148   end
 149
 150   def run(["rm", nickname]) do
 151     Common.start_pleroma()
 152
 153     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 154       User.delete(user)
 155       Mix.shell().info("User #{nickname} deleted.")
 156     else
 157       _ ->
 158         Mix.shell().error("No local user #{nickname}")
 159     end
 160   end
 161
 162   def run(["toggle_activated", nickname]) do
 163     Common.start_pleroma()
 164
 165     with %User{} = user <- User.get_by_nickname(nickname) do
 166       {:ok, user} = User.deactivate(user, !user.info.deactivated)
 167
 168       Mix.shell().info(
 169         "Activation status of #{nickname}: #{if(user.info.deactivated, do: "de", else: "")}activated"
 170       )
 171     else
 172       _ ->
 173         Mix.shell().error("No user #{nickname}")
 174     end
 175   end
 176
 177   def run(["toggle_disabled", nickname]) do
 178     Common.start_pleroma()
 179
 180     case User.get_by_nickname(nickname) do
 181       %User{} = user ->
 182         {:ok, user} = User.disable(user, !user.info.disabled)
 183         status = if(user.info.disabled, do: "ON", else: "OFF")
 184         Mix.shell().info("Disabled status of #{nickname}: #{status}")
 185
 186       _ ->
 187         Mix.shell().error("No user #{nickname}")
 188     end
 189   end
 190
 191   def run(["reset_password", nickname]) do
 192     Common.start_pleroma()
 193
 194     with %User{local: true} = user <- User.get_by_nickname(nickname),
 195          {:ok, token} <- Pleroma.PasswordResetToken.create_token(user) do
 196       Mix.shell().info("Generated password reset token for #{user.nickname}")
 197
 198       IO.puts(
 199         "URL: #{
 200           Pleroma.Web.Router.Helpers.util_url(
 201             Pleroma.Web.Endpoint,
 202             :show_password_reset,
 203             token.token
 204           )
 205         }"
 206       )
 207     else
 208       _ ->
 209         Mix.shell().error("No local user #{nickname}")
 210     end
 211   end
 212
 213   def run(["unsubscribe", nickname]) do
 214     Common.start_pleroma()
 215
 216     with %User{} = user <- User.get_by_nickname(nickname) do
 217       Mix.shell().info("Deactivating #{user.nickname}")
 218       User.deactivate(user)
 219
 220       {:ok, friends} = User.get_friends(user)
 221
 222       Enum.each(friends, fn friend ->
 223         user = Repo.get(User, user.id)
 224
 225         Mix.shell().info("Unsubscribing #{friend.nickname} from #{user.nickname}")
 226         User.unfollow(user, friend)
 227       end)
 228
 229       :timer.sleep(500)
 230
 231       user = Repo.get(User, user.id)
 232
 233       if Enum.empty?(user.following) do
 234         Mix.shell().info("Successfully unsubscribed all followers from #{user.nickname}")
 235       end
 236     else
 237       _ ->
 238         Mix.shell().error("No user #{nickname}")
 239     end
 240   end
 241
 242   def run(["set", nickname | rest]) do
 243     Common.start_pleroma()
 244
 245     {options, [], []} =
 246       OptionParser.parse(
 247         rest,
 248         strict: [
 249           moderator: :boolean,
 250           admin: :boolean,
 251           locked: :boolean
 252         ]
 253       )
 254
 255     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 256       user =
 257         case Keyword.get(options, :moderator) do
 258           nil -> user
 259           value -> set_moderator(user, value)
 260         end
 261
 262       user =
 263         case Keyword.get(options, :locked) do
 264           nil -> user
 265           value -> set_locked(user, value)
 266         end
 267
 268       _user =
 269         case Keyword.get(options, :admin) do
 270           nil -> user
 271           value -> set_admin(user, value)
 272         end
 273     else
 274       _ ->
 275         Mix.shell().error("No local user #{nickname}")
 276     end
 277   end
 278
 279   def run(["tag", nickname | tags]) do
 280     Common.start_pleroma()
 281
 282     with %User{} = user <- User.get_by_nickname(nickname) do
 283       user = user |> User.tag(tags)
 284
 285       Mix.shell().info("Tags of #{user.nickname}: #{inspect(tags)}")
 286     else
 287       _ ->
 288         Mix.shell().error("Could not change user tags for #{nickname}")
 289     end
 290   end
 291
 292   def run(["untag", nickname | tags]) do
 293     Common.start_pleroma()
 294
 295     with %User{} = user <- User.get_by_nickname(nickname) do
 296       user = user |> User.untag(tags)
 297
 298       Mix.shell().info("Tags of #{user.nickname}: #{inspect(tags)}")
 299     else
 300       _ ->
 301         Mix.shell().error("Could not change user tags for #{nickname}")
 302     end
 303   end
 304
 305   def run(["invite"]) do
 306     Common.start_pleroma()
 307
 308     with {:ok, token} <- Pleroma.UserInviteToken.create_token() do
 309       Mix.shell().info("Generated user invite token")
 310
 311       url =
 312         Pleroma.Web.Router.Helpers.redirect_url(
 313           Pleroma.Web.Endpoint,
 314           :registration_page,
 315           token.token
 316         )
 317
 318       IO.puts(url)
 319     else
 320       _ ->
 321         Mix.shell().error("Could not create invite token.")
 322     end
 323   end
 324
 325   defp set_moderator(user, value) do
 326     info_cng = User.Info.admin_api_update(user.info, %{is_moderator: value})
 327
 328     user_cng =
 329       Ecto.Changeset.change(user)
 330       |> put_embed(:info, info_cng)
 331
 332     {:ok, user} = User.update_and_set_cache(user_cng)
 333
 334     Mix.shell().info("Moderator status of #{user.nickname}: #{user.info.is_moderator}")
 335     user
 336   end
 337
 338   defp set_admin(user, value) do
 339     info_cng = User.Info.admin_api_update(user.info, %{is_admin: value})
 340
 341     user_cng =
 342       Ecto.Changeset.change(user)
 343       |> put_embed(:info, info_cng)
 344
 345     {:ok, user} = User.update_and_set_cache(user_cng)
 346
 347     Mix.shell().info("Admin status of #{user.nickname}: #{user.info.is_admin}")
 348     user
 349   end
 350
 351   defp set_locked(user, value) do
 352     info_cng = User.Info.user_upgrade(user.info, %{locked: value})
 353
 354     user_cng =
 355       Ecto.Changeset.change(user)
 356       |> put_embed(:info, info_cng)
 357
 358     {:ok, user} = User.update_and_set_cache(user_cng)
 359
 360     Mix.shell().info("Locked status of #{user.nickname}: #{user.info.locked}")
 361     user
 362   end
 363 end