git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Mix.Tasks.Pleroma.User do
   6   use Mix.Task
   7   import Ecto.Changeset
   8   alias Mix.Tasks.Pleroma.Common
   9   alias Pleroma.User
  10   alias Pleroma.UserInviteToken
  11
  12   @shortdoc "Manages Pleroma users"
  13   @moduledoc """
  14   Manages Pleroma users.
  15
  16   ## Create a new user.
  17
  18       mix pleroma.user new NICKNAME EMAIL [OPTION...]
  19
  20   Options:
  21   - `--name NAME` - the user's name (i.e., "Lain Iwakura")
  22   - `--bio BIO` - the user's bio
  23   - `--password PASSWORD` - the user's password
  24   - `--moderator`/`--no-moderator` - whether the user is a moderator
  25   - `--admin`/`--no-admin` - whether the user is an admin
  26   - `-y`, `--assume-yes`/`--no-assume-yes` - whether to assume yes to all questions
  27
  28   ## Generate an invite link.
  29
  30       mix pleroma.user invite [OPTION...]
  31
  32     Options:
  33     - `--expires_at DATE` - last day on which token is active (e.g. "2019-04-05")
  34     - `--max_use NUMBER` - maximum numbers of token uses
  35
  36   ## List generated invites
  37
  38       mix pleroma.user invites
  39
  40   ## Revoke invite
  41
  42       mix pleroma.user revoke_invite TOKEN OR TOKEN_ID
  43
  44   ## Delete the user's account.
  45
  46       mix pleroma.user rm NICKNAME
  47
  48   ## Delete the user's activities.
  49
  50       mix pleroma.user delete_activities NICKNAME
  51
  52   ## Deactivate or activate the user's account.
  53
  54       mix pleroma.user toggle_activated NICKNAME
  55
  56   ## Unsubscribe local users from user's account and deactivate it
  57
  58       mix pleroma.user unsubscribe NICKNAME
  59
  60   ## Create a password reset link.
  61
  62       mix pleroma.user reset_password NICKNAME
  63
  64   ## Set the value of the given user's settings.
  65
  66       mix pleroma.user set NICKNAME [OPTION...]
  67
  68   Options:
  69   - `--locked`/`--no-locked` - whether the user's account is locked
  70   - `--moderator`/`--no-moderator` - whether the user is a moderator
  71   - `--admin`/`--no-admin` - whether the user is an admin
  72
  73   ## Add tags to a user.
  74
  75       mix pleroma.user tag NICKNAME TAGS
  76
  77   ## Delete tags from a user.
  78
  79       mix pleroma.user untag NICKNAME TAGS
  80
  81   ## Toggle confirmation of the user's account.
  82
  83       mix pleroma.user toggle_confirmed NICKNAME
  84   """
  85   def run(["new", nickname, email | rest]) do
  86     {options, [], []} =
  87       OptionParser.parse(
  88         rest,
  89         strict: [
  90           name: :string,
  91           bio: :string,
  92           password: :string,
  93           moderator: :boolean,
  94           admin: :boolean,
  95           assume_yes: :boolean
  96         ],
  97         aliases: [
  98           y: :assume_yes
  99         ]
 100       )
 101
 102     name = Keyword.get(options, :name, nickname)
 103     bio = Keyword.get(options, :bio, "")
 104
 105     {password, generated_password?} =
 106       case Keyword.get(options, :password) do
 107         nil ->
 108           {:crypto.strong_rand_bytes(16) |> Base.encode64(), true}
 109
 110         password ->
 111           {password, false}
 112       end
 113
 114     moderator? = Keyword.get(options, :moderator, false)
 115     admin? = Keyword.get(options, :admin, false)
 116     assume_yes? = Keyword.get(options, :assume_yes, false)
 117
 118     Mix.shell().info("""
 119     A user will be created with the following information:
 120       - nickname: #{nickname}
 121       - email: #{email}
 122       - password: #{
 123       if(generated_password?, do: "[generated; a reset link will be created]", else: password)
 124     }
 125       - name: #{name}
 126       - bio: #{bio}
 127       - moderator: #{if(moderator?, do: "true", else: "false")}
 128       - admin: #{if(admin?, do: "true", else: "false")}
 129     """)
 130
 131     proceed? = assume_yes? or Mix.shell().yes?("Continue?")
 132
 133     if proceed? do
 134       Common.start_pleroma()
 135
 136       params = %{
 137         nickname: nickname,
 138         email: email,
 139         password: password,
 140         password_confirmation: password,
 141         name: name,
 142         bio: bio
 143       }
 144
 145       changeset = User.register_changeset(%User{}, params, need_confirmation: false)
 146       {:ok, _user} = User.register(changeset)
 147
 148       Mix.shell().info("User #{nickname} created")
 149
 150       if moderator? do
 151         run(["set", nickname, "--moderator"])
 152       end
 153
 154       if admin? do
 155         run(["set", nickname, "--admin"])
 156       end
 157
 158       if generated_password? do
 159         run(["reset_password", nickname])
 160       end
 161     else
 162       Mix.shell().info("User will not be created.")
 163     end
 164   end
 165
 166   def run(["rm", nickname]) do
 167     Common.start_pleroma()
 168
 169     with %User{local: true} = user <- User.get_cached_by_nickname(nickname) do
 170       User.perform(:delete, user)
 171       Mix.shell().info("User #{nickname} deleted.")
 172     else
 173       _ ->
 174         Mix.shell().error("No local user #{nickname}")
 175     end
 176   end
 177
 178   def run(["toggle_activated", nickname]) do
 179     Common.start_pleroma()
 180
 181     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 182       {:ok, user} = User.deactivate(user, !user.info.deactivated)
 183
 184       Mix.shell().info(
 185         "Activation status of #{nickname}: #{if(user.info.deactivated, do: "de", else: "")}activated"
 186       )
 187     else
 188       _ ->
 189         Mix.shell().error("No user #{nickname}")
 190     end
 191   end
 192
 193   def run(["reset_password", nickname]) do
 194     Common.start_pleroma()
 195
 196     with %User{local: true} = user <- User.get_cached_by_nickname(nickname),
 197          {:ok, token} <- Pleroma.PasswordResetToken.create_token(user) do
 198       Mix.shell().info("Generated password reset token for #{user.nickname}")
 199
 200       IO.puts(
 201         "URL: #{
 202           Pleroma.Web.Router.Helpers.util_url(
 203             Pleroma.Web.Endpoint,
 204             :show_password_reset,
 205             token.token
 206           )
 207         }"
 208       )
 209     else
 210       _ ->
 211         Mix.shell().error("No local user #{nickname}")
 212     end
 213   end
 214
 215   def run(["unsubscribe", nickname]) do
 216     Common.start_pleroma()
 217
 218     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 219       Mix.shell().info("Deactivating #{user.nickname}")
 220       User.deactivate(user)
 221
 222       {:ok, friends} = User.get_friends(user)
 223
 224       Enum.each(friends, fn friend ->
 225         user = User.get_cached_by_id(user.id)
 226
 227         Mix.shell().info("Unsubscribing #{friend.nickname} from #{user.nickname}")
 228         User.unfollow(user, friend)
 229       end)
 230
 231       :timer.sleep(500)
 232
 233       user = User.get_cached_by_id(user.id)
 234
 235       if Enum.empty?(user.following) do
 236         Mix.shell().info("Successfully unsubscribed all followers from #{user.nickname}")
 237       end
 238     else
 239       _ ->
 240         Mix.shell().error("No user #{nickname}")
 241     end
 242   end
 243
 244   def run(["set", nickname | rest]) do
 245     Common.start_pleroma()
 246
 247     {options, [], []} =
 248       OptionParser.parse(
 249         rest,
 250         strict: [
 251           moderator: :boolean,
 252           admin: :boolean,
 253           locked: :boolean
 254         ]
 255       )
 256
 257     with %User{local: true} = user <- User.get_cached_by_nickname(nickname) do
 258       user =
 259         case Keyword.get(options, :moderator) do
 260           nil -> user
 261           value -> set_moderator(user, value)
 262         end
 263
 264       user =
 265         case Keyword.get(options, :locked) do
 266           nil -> user
 267           value -> set_locked(user, value)
 268         end
 269
 270       _user =
 271         case Keyword.get(options, :admin) do
 272           nil -> user
 273           value -> set_admin(user, value)
 274         end
 275     else
 276       _ ->
 277         Mix.shell().error("No local user #{nickname}")
 278     end
 279   end
 280
 281   def run(["tag", nickname | tags]) do
 282     Common.start_pleroma()
 283
 284     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 285       user = user |> User.tag(tags)
 286
 287       Mix.shell().info("Tags of #{user.nickname}: #{inspect(tags)}")
 288     else
 289       _ ->
 290         Mix.shell().error("Could not change user tags for #{nickname}")
 291     end
 292   end
 293
 294   def run(["untag", nickname | tags]) do
 295     Common.start_pleroma()
 296
 297     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 298       user = user |> User.untag(tags)
 299
 300       Mix.shell().info("Tags of #{user.nickname}: #{inspect(tags)}")
 301     else
 302       _ ->
 303         Mix.shell().error("Could not change user tags for #{nickname}")
 304     end
 305   end
 306
 307   def run(["invite" | rest]) do
 308     {options, [], []} =
 309       OptionParser.parse(rest,
 310         strict: [
 311           expires_at: :string,
 312           max_use: :integer
 313         ]
 314       )
 315
 316     options =
 317       options
 318       |> Keyword.update(:expires_at, {:ok, nil}, fn
 319         nil -> {:ok, nil}
 320         val -> Date.from_iso8601(val)
 321       end)
 322       |> Enum.into(%{})
 323
 324     Common.start_pleroma()
 325
 326     with {:ok, val} <- options[:expires_at],
 327          options = Map.put(options, :expires_at, val),
 328          {:ok, invite} <- UserInviteToken.create_invite(options) do
 329       Mix.shell().info(
 330         "Generated user invite token " <> String.replace(invite.invite_type, "_", " ")
 331       )
 332
 333       url =
 334         Pleroma.Web.Router.Helpers.redirect_url(
 335           Pleroma.Web.Endpoint,
 336           :registration_page,
 337           invite.token
 338         )
 339
 340       IO.puts(url)
 341     else
 342       error ->
 343         Mix.shell().error("Could not create invite token: #{inspect(error)}")
 344     end
 345   end
 346
 347   def run(["invites"]) do
 348     Common.start_pleroma()
 349
 350     Mix.shell().info("Invites list:")
 351
 352     UserInviteToken.list_invites()
 353     |> Enum.each(fn invite ->
 354       expire_info =
 355         with expires_at when not is_nil(expires_at) <- invite.expires_at do
 356           " | Expires at: #{Date.to_string(expires_at)}"
 357         end
 358
 359       using_info =
 360         with max_use when not is_nil(max_use) <- invite.max_use do
 361           " | Max use: #{max_use}    Left use: #{max_use - invite.uses}"
 362         end
 363
 364       Mix.shell().info(
 365         "ID: #{invite.id} | Token: #{invite.token} | Token type: #{invite.invite_type} | Used: #{
 366           invite.used
 367         }#{expire_info}#{using_info}"
 368       )
 369     end)
 370   end
 371
 372   def run(["revoke_invite", token]) do
 373     Common.start_pleroma()
 374
 375     with {:ok, invite} <- UserInviteToken.find_by_token(token),
 376          {:ok, _} <- UserInviteToken.update_invite(invite, %{used: true}) do
 377       Mix.shell().info("Invite for token #{token} was revoked.")
 378     else
 379       _ -> Mix.shell().error("No invite found with token #{token}")
 380     end
 381   end
 382
 383   def run(["delete_activities", nickname]) do
 384     Common.start_pleroma()
 385
 386     with %User{local: true} = user <- User.get_cached_by_nickname(nickname) do
 387       {:ok, _} = User.delete_user_activities(user)
 388       Mix.shell().info("User #{nickname} statuses deleted.")
 389     else
 390       _ ->
 391         Mix.shell().error("No local user #{nickname}")
 392     end
 393   end
 394
 395   def run(["toggle_confirmed", nickname]) do
 396     Common.start_pleroma()
 397
 398     with %User{} = user <- User.get_cached_by_nickname(nickname) do
 399       {:ok, user} = User.toggle_confirmation(user)
 400
 401       message = if user.info.confirmation_pending, do: "needs", else: "doesn't need"
 402
 403       Mix.shell().info("#{nickname} #{message} confirmation.")
 404     else
 405       _ ->
 406         Mix.shell().error("No local user #{nickname}")
 407     end
 408   end
 409
 410   defp set_moderator(user, value) do
 411     info_cng = User.Info.admin_api_update(user.info, %{is_moderator: value})
 412
 413     user_cng =
 414       Ecto.Changeset.change(user)
 415       |> put_embed(:info, info_cng)
 416
 417     {:ok, user} = User.update_and_set_cache(user_cng)
 418
 419     Mix.shell().info("Moderator status of #{user.nickname}: #{user.info.is_moderator}")
 420     user
 421   end
 422
 423   defp set_admin(user, value) do
 424     info_cng = User.Info.admin_api_update(user.info, %{is_admin: value})
 425
 426     user_cng =
 427       Ecto.Changeset.change(user)
 428       |> put_embed(:info, info_cng)
 429
 430     {:ok, user} = User.update_and_set_cache(user_cng)
 431
 432     Mix.shell().info("Admin status of #{user.nickname}: #{user.info.is_admin}")
 433     user
 434   end
 435
 436   defp set_locked(user, value) do
 437     info_cng = User.Info.user_upgrade(user.info, %{locked: value})
 438
 439     user_cng =
 440       Ecto.Changeset.change(user)
 441       |> put_embed(:info, info_cng)
 442
 443     {:ok, user} = User.update_and_set_cache(user_cng)
 444
 445     Mix.shell().info("Locked status of #{user.nickname}: #{user.info.locked}")
 446     user
 447   end
 448 end