git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/user.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Mix.Tasks.Pleroma.User do
   6   use Mix.Task
   7   import Ecto.Changeset
   8   alias Pleroma.{Repo, User}
   9   alias Mix.Tasks.Pleroma.Common
  10
  11   @shortdoc "Manages Pleroma users"
  12   @moduledoc """
  13   Manages Pleroma users.
  14
  15   ## Create a new user.
  16
  17       mix pleroma.user new NICKNAME EMAIL [OPTION...]
  18
  19   Options:
  20   - `--name NAME` - the user's name (i.e., "Lain Iwakura")
  21   - `--bio BIO` - the user's bio
  22   - `--password PASSWORD` - the user's password
  23   - `--moderator`/`--no-moderator` - whether the user is a moderator
  24   - `--admin`/`--no-admin` - whether the user is an admin
  25
  26   ## Generate an invite link.
  27
  28       mix pleroma.user invite
  29
  30   ## Delete the user's account.
  31
  32       mix pleroma.user rm NICKNAME
  33
  34   ## Deactivate or activate the user's account.
  35
  36       mix pleroma.user toggle_activated NICKNAME
  37
  38   ## Unsubscribe local users from user's account and deactivate it
  39
  40       mix pleroma.user unsubscribe NICKNAME
  41
  42   ## Create a password reset link.
  43
  44       mix pleroma.user reset_password NICKNAME
  45
  46   ## Set the value of the given user's settings.
  47
  48       mix pleroma.user set NICKNAME [OPTION...]
  49
  50   Options:
  51   - `--locked`/`--no-locked` - whether the user's account is locked
  52   - `--moderator`/`--no-moderator` - whether the user is a moderator
  53   - `--admin`/`--no-admin` - whether the user is an admin
  54   """
  55   def run(["new", nickname, email | rest]) do
  56     {options, [], []} =
  57       OptionParser.parse(
  58         rest,
  59         strict: [
  60           name: :string,
  61           bio: :string,
  62           password: :string,
  63           moderator: :boolean,
  64           admin: :boolean
  65         ]
  66       )
  67
  68     name = Keyword.get(options, :name, nickname)
  69     bio = Keyword.get(options, :bio, "")
  70
  71     {password, generated_password?} =
  72       case Keyword.get(options, :password) do
  73         nil ->
  74           {:crypto.strong_rand_bytes(16) |> Base.encode64(), true}
  75
  76         password ->
  77           {password, false}
  78       end
  79
  80     moderator? = Keyword.get(options, :moderator, false)
  81     admin? = Keyword.get(options, :admin, false)
  82
  83     Mix.shell().info("""
  84     A user will be created with the following information:
  85       - nickname: #{nickname}
  86       - email: #{email}
  87       - password: #{
  88       if(generated_password?, do: "[generated; a reset link will be created]", else: password)
  89     }
  90       - name: #{name}
  91       - bio: #{bio}
  92       - moderator: #{if(moderator?, do: "true", else: "false")}
  93       - admin: #{if(admin?, do: "true", else: "false")}
  94     """)
  95
  96     proceed? = Mix.shell().yes?("Continue?")
  97
  98     unless not proceed? do
  99       Common.start_pleroma()
 100
 101       params = %{
 102         nickname: nickname,
 103         email: email,
 104         password: password,
 105         password_confirmation: password,
 106         name: name,
 107         bio: bio
 108       }
 109
 110       changeset = User.register_changeset(%User{}, params, confirmed: true)
 111       {:ok, _user} = User.register(changeset)
 112
 113       Mix.shell().info("User #{nickname} created")
 114
 115       if moderator? do
 116         run(["set", nickname, "--moderator"])
 117       end
 118
 119       if admin? do
 120         run(["set", nickname, "--admin"])
 121       end
 122
 123       if generated_password? do
 124         run(["reset_password", nickname])
 125       end
 126     else
 127       Mix.shell().info("User will not be created.")
 128     end
 129   end
 130
 131   def run(["rm", nickname]) do
 132     Common.start_pleroma()
 133
 134     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 135       User.delete(user)
 136       Mix.shell().info("User #{nickname} deleted.")
 137     else
 138       _ ->
 139         Mix.shell().error("No local user #{nickname}")
 140     end
 141   end
 142
 143   def run(["toggle_activated", nickname]) do
 144     Common.start_pleroma()
 145
 146     with %User{} = user <- User.get_by_nickname(nickname) do
 147       {:ok, user} = User.deactivate(user, !user.info.deactivated)
 148
 149       Mix.shell().info(
 150         "Activation status of #{nickname}: #{if(user.info.deactivated, do: "de", else: "")}activated"
 151       )
 152     else
 153       _ ->
 154         Mix.shell().error("No user #{nickname}")
 155     end
 156   end
 157
 158   def run(["reset_password", nickname]) do
 159     Common.start_pleroma()
 160
 161     with %User{local: true} = user <- User.get_by_nickname(nickname),
 162          {:ok, token} <- Pleroma.PasswordResetToken.create_token(user) do
 163       Mix.shell().info("Generated password reset token for #{user.nickname}")
 164
 165       IO.puts(
 166         "URL: #{
 167           Pleroma.Web.Router.Helpers.util_url(
 168             Pleroma.Web.Endpoint,
 169             :show_password_reset,
 170             token.token
 171           )
 172         }"
 173       )
 174     else
 175       _ ->
 176         Mix.shell().error("No local user #{nickname}")
 177     end
 178   end
 179
 180   def run(["unsubscribe", nickname]) do
 181     Common.start_pleroma()
 182
 183     with %User{} = user <- User.get_by_nickname(nickname) do
 184       Mix.shell().info("Deactivating #{user.nickname}")
 185       User.deactivate(user)
 186
 187       {:ok, friends} = User.get_friends(user)
 188
 189       Enum.each(friends, fn friend ->
 190         user = Repo.get(User, user.id)
 191
 192         Mix.shell().info("Unsubscribing #{friend.nickname} from #{user.nickname}")
 193         User.unfollow(user, friend)
 194       end)
 195
 196       :timer.sleep(500)
 197
 198       user = Repo.get(User, user.id)
 199
 200       if length(user.following) == 0 do
 201         Mix.shell().info("Successfully unsubscribed all followers from #{user.nickname}")
 202       end
 203     else
 204       _ ->
 205         Mix.shell().error("No user #{nickname}")
 206     end
 207   end
 208
 209   def run(["set", nickname | rest]) do
 210     Common.start_pleroma()
 211
 212     {options, [], []} =
 213       OptionParser.parse(
 214         rest,
 215         strict: [
 216           moderator: :boolean,
 217           admin: :boolean,
 218           locked: :boolean
 219         ]
 220       )
 221
 222     with %User{local: true} = user <- User.get_by_nickname(nickname) do
 223       user =
 224         case Keyword.get(options, :moderator) do
 225           nil -> user
 226           value -> set_moderator(user, value)
 227         end
 228
 229       user =
 230         case Keyword.get(options, :locked) do
 231           nil -> user
 232           value -> set_locked(user, value)
 233         end
 234
 235       _user =
 236         case Keyword.get(options, :admin) do
 237           nil -> user
 238           value -> set_admin(user, value)
 239         end
 240     else
 241       _ ->
 242         Mix.shell().error("No local user #{nickname}")
 243     end
 244   end
 245
 246   def run(["invite"]) do
 247     Common.start_pleroma()
 248
 249     with {:ok, token} <- Pleroma.UserInviteToken.create_token() do
 250       Mix.shell().info("Generated user invite token")
 251
 252       url =
 253         Pleroma.Web.Router.Helpers.redirect_url(
 254           Pleroma.Web.Endpoint,
 255           :registration_page,
 256           token.token
 257         )
 258
 259       IO.puts(url)
 260     else
 261       _ ->
 262         Mix.shell().error("Could not create invite token.")
 263     end
 264   end
 265
 266   defp set_moderator(user, value) do
 267     info_cng = User.Info.admin_api_update(user.info, %{is_moderator: value})
 268
 269     user_cng =
 270       Ecto.Changeset.change(user)
 271       |> put_embed(:info, info_cng)
 272
 273     {:ok, user} = User.update_and_set_cache(user_cng)
 274
 275     Mix.shell().info("Moderator status of #{user.nickname}: #{user.info.is_moderator}")
 276     user
 277   end
 278
 279   defp set_admin(user, value) do
 280     info_cng = User.Info.admin_api_update(user.info, %{is_admin: value})
 281
 282     user_cng =
 283       Ecto.Changeset.change(user)
 284       |> put_embed(:info, info_cng)
 285
 286     {:ok, user} = User.update_and_set_cache(user_cng)
 287
 288     Mix.shell().info("Admin status of #{user.nickname}: #{user.info.is_admin}")
 289     user
 290   end
 291
 292   defp set_locked(user, value) do
 293     info_cng = User.Info.user_upgrade(user.info, %{locked: value})
 294
 295     user_cng =
 296       Ecto.Changeset.change(user)
 297       |> put_embed(:info, info_cng)
 298
 299     {:ok, user} = User.update_and_set_cache(user_cng)
 300
 301     Mix.shell().info("Locked status of #{user.nickname}: #{user.info.locked}")
 302     user
 303   end
 304 end