git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/load_testing.ex

   1 defmodule Mix.Tasks.Pleroma.LoadTesting do
   2   use Mix.Task
   3   use Pleroma.LoadTesting.Helper
   4   import Mix.Pleroma
   5   import Pleroma.LoadTesting.Generator
   6   import Pleroma.LoadTesting.Fetcher
   7
   8   @shortdoc "Factory for generation data"
   9   @moduledoc """
  10   Generates data like:
  11   - users
  12   - activities with notifications
  13   - direct messages
  14   - long thread
  15   - non visible posts
  16
  17   ## Generate data
  18       MIX_ENV=benchmark mix pleroma.load_testing --users 20000 --dms 20000 --thread_length 2000
  19       MIX_ENV=benchmark mix pleroma.load_testing -u 20000 -d 20000 -t 2000
  20
  21   Options:
  22   - `--users NUMBER` - number of users to generate. Defaults to: 20000. Alias: `-u`
  23   - `--dms NUMBER` - number of direct messages to generate. Defaults to: 20000. Alias `-d`
  24   - `--thread_length` - number of messages in thread. Defaults to: 2000. ALias `-t`
  25   """
  26
  27   @aliases [u: :users, d: :dms, t: :thread_length]
  28   @switches [
  29     users: :integer,
  30     dms: :integer,
  31     thread_length: :integer
  32   ]
  33   @users_default 20_000
  34   @dms_default 20_000
  35   @thread_length_default 2_000
  36
  37   def run(args) do
  38     start_pleroma()
  39     Pleroma.Config.put([:instance, :skip_thread_containment], true)
  40     {opts, _} = OptionParser.parse!(args, strict: @switches, aliases: @aliases)
  41
  42     users_max = Keyword.get(opts, :users, @users_default)
  43     dms_max = Keyword.get(opts, :dms, @dms_default)
  44     thread_length = Keyword.get(opts, :thread_length, @thread_length_default)
  45
  46     clean_tables()
  47
  48     opts =
  49       Keyword.put(opts, :users_max, users_max)
  50       |> Keyword.put(:dms_max, dms_max)
  51       |> Keyword.put(:thread_length, thread_length)
  52
  53     generate_users(opts)
  54
  55     # main user for queries
  56     IO.puts("Fetching main user...")
  57
  58     {time, user} =
  59       :timer.tc(fn ->
  60         Repo.one(from(u in User, order_by: fragment("RANDOM()"), limit: 1))
  61       end)
  62
  63     IO.puts("Fetching main user take #{to_sec(time)} sec.\n")
  64
  65     IO.puts("Fetching users...")
  66
  67     {time, users} =
  68       :timer.tc(fn ->
  69         Repo.all(
  70           from(u in User,
  71             where: u.id != ^user.id,
  72             order_by: fragment("RANDOM()"),
  73             limit: 10
  74           )
  75         )
  76       end)
  77
  78     IO.puts("Fetching users take #{to_sec(time)} sec.\n")
  79
  80     generate_activities(user, users)
  81
  82     generate_dms(user, users, opts)
  83
  84     {:ok, activity} = generate_long_thread(user, users, opts)
  85
  86     generate_non_visible_message(user, users)
  87
  88     IO.puts("Users in DB: #{Repo.aggregate(from(u in User), :count, :id)}")
  89
  90     IO.puts("Activities in DB: #{Repo.aggregate(from(a in Pleroma.Activity), :count, :id)}")
  91
  92     IO.puts("Objects in DB: #{Repo.aggregate(from(o in Pleroma.Object), :count, :id)}")
  93
  94     IO.puts(
  95       "Notifications in DB: #{Repo.aggregate(from(n in Pleroma.Notification), :count, :id)}"
  96     )
  97
  98     fetch_user(user)
  99     query_timelines(user)
 100     query_notifications(user)
 101     query_dms(user)
 102     query_long_thread(user, activity)
 103     Pleroma.Config.put([:instance, :skip_thread_containment], false)
 104     query_timelines(user)
 105   end
 106
 107   defp clean_tables do
 108     IO.puts("Deleting old data...\n")
 109     Ecto.Adapters.SQL.query!(Repo, "TRUNCATE users CASCADE;")
 110     Ecto.Adapters.SQL.query!(Repo, "TRUNCATE activities CASCADE;")
 111     Ecto.Adapters.SQL.query!(Repo, "TRUNCATE objects CASCADE;")
 112   end
 113 end