git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/instance.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Mix.Tasks.Pleroma.Instance do
   6   use Mix.Task
   7   alias Mix.Tasks.Pleroma.Common
   8
   9   @shortdoc "Manages Pleroma instance"
  10   @moduledoc """
  11   Manages Pleroma instance.
  12
  13   ## Generate a new instance config.
  14
  15     mix pleroma.instance gen [OPTION...]
  16
  17   If any options are left unspecified, you will be prompted interactively
  18
  19   ## Options
  20
  21   - `-f`, `--force` - overwrite any output files
  22   - `-o PATH`, `--output PATH` - the output file for the generated configuration
  23   - `--output-psql PATH` - the output file for the generated PostgreSQL setup
  24   - `--domain DOMAIN` - the domain of your instance
  25   - `--instance-name INSTANCE_NAME` - the name of your instance
  26   - `--admin-email ADMIN_EMAIL` - the email address of the instance admin
  27   - `--dbhost HOSTNAME` - the hostname of the PostgreSQL database to use
  28   - `--dbname DBNAME` - the name of the database to use
  29   - `--dbuser DBUSER` - the user (aka role) to use for the database connection
  30   - `--dbpass DBPASS` - the password to use for the database connection
  31   """
  32
  33   def run(["gen" | rest]) do
  34     {options, [], []} =
  35       OptionParser.parse(
  36         rest,
  37         strict: [
  38           force: :boolean,
  39           output: :string,
  40           output_psql: :string,
  41           domain: :string,
  42           instance_name: :string,
  43           admin_email: :string,
  44           dbhost: :string,
  45           dbname: :string,
  46           dbuser: :string,
  47           dbpass: :string
  48         ],
  49         aliases: [
  50           o: :output,
  51           f: :force
  52         ]
  53       )
  54
  55     paths =
  56       [config_path, psql_path] = [
  57         Keyword.get(options, :output, "config/generated_config.exs"),
  58         Keyword.get(options, :output_psql, "config/setup_db.psql")
  59       ]
  60
  61     will_overwrite = Enum.filter(paths, &File.exists?/1)
  62     proceed? = Enum.empty?(will_overwrite) or Keyword.get(options, :force, false)
  63
  64     unless not proceed? do
  65       [domain, port | _] =
  66         String.split(
  67           Common.get_option(
  68             options,
  69             :domain,
  70             "What domain will your instance use? (e.g pleroma.soykaf.com)"
  71           ),
  72           ":"
  73         ) ++ [443]
  74
  75       name =
  76         Common.get_option(
  77           options,
  78           :name,
  79           "What is the name of your instance? (e.g. Pleroma/Soykaf)"
  80         )
  81
  82       email = Common.get_option(options, :admin_email, "What is your admin email address?")
  83
  84       dbhost =
  85         Common.get_option(options, :dbhost, "What is the hostname of your database?", "localhost")
  86
  87       dbname =
  88         Common.get_option(options, :dbname, "What is the name of your database?", "pleroma_dev")
  89
  90       dbuser =
  91         Common.get_option(
  92           options,
  93           :dbuser,
  94           "What is the user used to connect to your database?",
  95           "pleroma"
  96         )
  97
  98       dbpass =
  99         Common.get_option(
 100           options,
 101           :dbpass,
 102           "What is the password used to connect to your database?",
 103           :crypto.strong_rand_bytes(64) |> Base.encode64() |> binary_part(0, 64),
 104           "autogenerated"
 105         )
 106
 107       secret = :crypto.strong_rand_bytes(64) |> Base.encode64() |> binary_part(0, 64)
 108       {web_push_public_key, web_push_private_key} = :crypto.generate_key(:ecdh, :prime256v1)
 109
 110       result_config =
 111         EEx.eval_file(
 112           "sample_config.eex" |> Path.expand(__DIR__),
 113           domain: domain,
 114           port: port,
 115           email: email,
 116           name: name,
 117           dbhost: dbhost,
 118           dbname: dbname,
 119           dbuser: dbuser,
 120           dbpass: dbpass,
 121           version: Pleroma.Mixfile.project() |> Keyword.get(:version),
 122           secret: secret,
 123           web_push_public_key: Base.url_encode64(web_push_public_key, padding: false),
 124           web_push_private_key: Base.url_encode64(web_push_private_key, padding: false)
 125         )
 126
 127       result_psql =
 128         EEx.eval_file(
 129           "sample_psql.eex" |> Path.expand(__DIR__),
 130           dbname: dbname,
 131           dbuser: dbuser,
 132           dbpass: dbpass
 133         )
 134
 135       Mix.shell().info(
 136         "Writing config to #{config_path}. You should rename it to config/prod.secret.exs or config/dev.secret.exs."
 137       )
 138
 139       File.write(config_path, result_config)
 140       Mix.shell().info("Writing #{psql_path}.")
 141       File.write(psql_path, result_psql)
 142
 143       Mix.shell().info(
 144         "\n" <>
 145           """
 146           To get started:
 147           1. Verify the contents of the generated files.
 148           2. Run `sudo -u postgres psql -f #{Common.escape_sh_path(psql_path)}`.
 149           """ <>
 150           if config_path in ["config/dev.secret.exs", "config/prod.secret.exs"] do
 151             ""
 152           else
 153             "3. Run `mv #{Common.escape_sh_path(config_path)} 'config/prod.secret.exs'`."
 154           end
 155       )
 156     else
 157       Mix.shell().error(
 158         "The task would have overwritten the following files:\n" <>
 159           (Enum.map(paths, &"- #{&1}\n") |> Enum.join("")) <>
 160           "Rerun with `--force` to overwrite them."
 161       )
 162     end
 163   end
 164 end