git.squeep.com Git - akkoma/blob - lib/mix/tasks/pleroma/database.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Mix.Tasks.Pleroma.Database do
   6   alias Mix.Tasks.Pleroma.Common
   7   alias Pleroma.Conversation
   8   alias Pleroma.Object
   9   alias Pleroma.Repo
  10   alias Pleroma.User
  11   require Logger
  12   use Mix.Task
  13
  14   @shortdoc "A collection of database related tasks"
  15   @moduledoc """
  16    A collection of database related tasks
  17
  18    ## Replace embedded objects with their references
  19
  20    Replaces embedded objects with references to them in the `objects` table. Only needs to be ran once. The reason why this is not a migration is because it could significantly increase the database size after being ran, however after this `VACUUM FULL` will be able to reclaim about 20% (really depends on what is in the database, your mileage may vary) of the db size before the migration.
  21
  22        mix pleroma.database remove_embedded_objects
  23
  24     Options:
  25     - `--vacuum` - run `VACUUM FULL` after the embedded objects are replaced with their references
  26
  27   ## Prune old objects from the database
  28
  29       mix pleroma.database prune_objects
  30
  31   ## Create a conversation for all existing DMs. Can be safely re-run.
  32
  33       mix pleroma.database bump_all_conversations
  34
  35   ## Remove duplicated items from following and update followers count for all users
  36
  37       mix pleroma.database update_users_following_followers_counts
  38   """
  39   def run(["remove_embedded_objects" | args]) do
  40     {options, [], []} =
  41       OptionParser.parse(
  42         args,
  43         strict: [
  44           vacuum: :boolean
  45         ]
  46       )
  47
  48     Common.start_pleroma()
  49     Logger.info("Removing embedded objects")
  50
  51     Repo.query!(
  52       "update activities set data = jsonb_set(data, '{object}'::text[], data->'object'->'id') where data->'object'->>'id' is not null;",
  53       [],
  54       timeout: :infinity
  55     )
  56
  57     if Keyword.get(options, :vacuum) do
  58       Logger.info("Runnning VACUUM FULL")
  59
  60       Repo.query!(
  61         "vacuum full;",
  62         [],
  63         timeout: :infinity
  64       )
  65     end
  66   end
  67
  68   def run(["bump_all_conversations"]) do
  69     Common.start_pleroma()
  70     Conversation.bump_for_all_activities()
  71   end
  72
  73   def run(["update_users_following_followers_counts"]) do
  74     Common.start_pleroma()
  75
  76     users = Repo.all(User)
  77     Enum.each(users, &User.remove_duplicated_following/1)
  78     Enum.each(users, &User.update_follower_count/1)
  79   end
  80
  81   def run(["prune_objects" | args]) do
  82     import Ecto.Query
  83
  84     {options, [], []} =
  85       OptionParser.parse(
  86         args,
  87         strict: [
  88           vacuum: :boolean
  89         ]
  90       )
  91
  92     Common.start_pleroma()
  93
  94     deadline = Pleroma.Config.get([:instance, :remote_post_retention_days])
  95
  96     Logger.info("Pruning objects older than #{deadline} days")
  97
  98     time_deadline =
  99       NaiveDateTime.utc_now()
 100       |> NaiveDateTime.add(-(deadline * 86_400))
 101
 102     public = "https://www.w3.org/ns/activitystreams#Public"
 103
 104     from(o in Object,
 105       where: fragment("?->'to' \\? ? OR ?->'cc' \\? ?", o.data, ^public, o.data, ^public),
 106       where: o.inserted_at < ^time_deadline,
 107       where:
 108         fragment("split_part(?->>'actor', '/', 3) != ?", o.data, ^Pleroma.Web.Endpoint.host())
 109     )
 110     |> Repo.delete_all(timeout: :infinity)
 111
 112     if Keyword.get(options, :vacuum) do
 113       Logger.info("Runnning VACUUM FULL")
 114
 115       Repo.query!(
 116         "vacuum full;",
 117         [],
 118         timeout: :infinity
 119       )
 120     end
 121   end
 122 end